/[gentoo-x86]/net-libs/ortp/ortp-0.23.0.ebuild
Gentoo

Contents of /net-libs/ortp/ortp-0.23.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Tue Aug 4 12:00:33 2015 UTC (5 years, 4 months ago) by zlogene
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +2 -2 lines
ia64 stable wrt bug #535584

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x1BDC0E5AC42EB5D6)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ortp-0.23.0.ebuild,v 1.4 2015/08/02 09:01:16 pacho Exp $
4
5 EAPI=5
6
7 inherit eutils
8
9 DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
10 HOMEPAGE="http://www.linphone.org/"
11 SRC_URI="mirror://nongnu/linphone/${PN}/sources/${P}.tar.gz"
12
13 LICENSE="LGPL-2.1"
14 SLOT="0/9"
15 KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
16 IUSE="debug doc examples ipv6 minimal ntp-timestamp ssl srtp zrtp"
17
18 RDEPEND="ssl? ( dev-libs/openssl:0= )
19 srtp? ( net-libs/libsrtp:0= )
20 zrtp? ( >=net-libs/libzrtpcpp-4.0.0:0= )"
21 DEPEND="${RDEPEND}
22 doc? ( app-doc/doxygen )
23 virtual/pkgconfig"
24
25 REQUIRED_USE="zrtp? ( srtp )"
26
27 src_prepare() {
28 # ${P} is added after ${docdir}
29 if use doc; then
30 sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
31 || die "patching Makefile.in failed"
32 fi
33 }
34
35 src_configure() {
36 local myeconfargs=(
37 # memcheck is for HP-UX only
38 --disable-memcheck
39 # mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
40 --disable-mode64bit
41 # strict adds -Werror, do not want it
42 --disable-strict
43 # they seriously failed to understand AC_ARG_ENABLE...
44 --disable-tests_enabled
45 --enable-fast-install
46 --enable-libtool-lock
47 # this is fine as long as we do not link to polarssl
48 --enable-broken-srtp
49
50 $(use_enable debug)
51 $(use_enable ipv6)
52 $(use_enable minimal perf)
53 $(use_enable ntp-timestamp)
54 $(use_enable ssl ssl-hmac)
55 $(use_enable zrtp)
56
57 --with-srtp=$(usex srtp "${EPREFIX}"/usr none)
58 $(use doc || echo ac_cv_path_DOXYGEN=false)
59 )
60
61 econf "${myeconfargs[@]}"
62 }
63
64 src_install() {
65 emake DESTDIR="${D}" pkgdocdir="${EPREFIX}"/usr/share/doc/${PF} \
66 install
67 dodoc AUTHORS ChangeLog NEWS README TODO
68
69 prune_libtool_files
70
71 if use examples; then
72 insinto /usr/share/doc/${PF}/examples
73 doins src/tests/*.c
74 fi
75 }

  ViewVC Help
Powered by ViewVC 1.1.20