/[gentoo-x86]/net-libs/qmf/qmf-4.0.3.ebuild
Gentoo

Contents of /net-libs/qmf/qmf-4.0.3.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations) (download)
Sun Jun 14 23:29:01 2015 UTC (5 years ago) by pesa
Branch: MAIN
CVS Tags: HEAD
Changes since 1.6: +3 -5 lines
Remove obsolete blocker; delete redundant echo.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0xDADED6B2671CB57D!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/qmf/qmf-4.0.3.ebuild,v 1.6 2015/03/30 15:34:56 pesa Exp $
4
5 EAPI=5
6
7 inherit qt4-r2
8
9 if [[ ${PV} == *9999 ]]; then
10 inherit git-r3
11 EGIT_REPO_URI=(
12 "git://code.qt.io/qt-labs/messagingframework.git"
13 "https://code.qt.io/git/qt-labs/messagingframework.git"
14 )
15 else
16 SRC_URI="http://dev.gentoo.org/~pesa/distfiles/${P}.tar.gz"
17 S=${WORKDIR}/qt-labs-messagingframework
18 fi
19
20 DESCRIPTION="The Qt Messaging Framework"
21 HOMEPAGE="https://code.qt.io/cgit/qt-labs/messagingframework.git/"
22
23 LICENSE="LGPL-2.1"
24 SLOT="0"
25 KEYWORDS="amd64 ~ppc ~ppc64 x86"
26 IUSE="debug doc examples icu test zlib"
27
28 RDEPEND="
29 >=dev-qt/qtcore-4.8:4
30 >=dev-qt/qtgui-4.8:4
31 >=dev-qt/qtsql-4.8:4
32 examples? ( >=dev-qt/qtwebkit-4.8:4 )
33 icu? ( dev-libs/icu:= )
34 zlib? ( sys-libs/zlib )
35 "
36 DEPEND="${RDEPEND}
37 virtual/pkgconfig
38 test? ( >=dev-qt/qttest-4.8:4 )
39 "
40
41 DOCS=( CHANGES )
42 PATCHES=(
43 "${FILESDIR}/${PN}-4.0.2-tests.patch"
44 )
45
46 src_prepare() {
47 qt4-r2_src_prepare
48
49 sed -i -e '/SUBDIRS.*=/s/benchmarks//' messagingframework.pro || die
50
51 if ! use examples; then
52 sed -i -e '/SUBDIRS.*=/s/examples//' messagingframework.pro || die
53 fi
54 if ! use test; then
55 sed -i -e '/SUBDIRS.*=/s/tests//' messagingframework.pro || die
56 fi
57
58 # disable automagic deps
59 if ! use icu; then
60 sed -i -e 's/packagesExist(icu-uc)/false:&/' \
61 src/libraries/qmfclient/qmfclient.pro || die
62 fi
63 if ! use zlib; then
64 sed -i -e 's/packagesExist(zlib)/false:&/' \
65 src/plugins/messageservices/imap/imap.pro || die
66 fi
67
68 # fix libdir
69 find "${S}" -name '*.pro' -type f -print0 | xargs -0 \
70 sed -i -re "s:/lib(/|$):/$(get_libdir)\1:" || die
71 sed -i -e "s:/lib/:/$(get_libdir)/:" \
72 src/libraries/qmfclient/support/qmailnamespace.cpp || die
73 }
74
75 src_configure() {
76 eqmake4 QMF_INSTALL_ROOT="${EPREFIX}/usr"
77 }
78
79 src_test() {
80 cd "${S}"/tests
81
82 export QMF_DATA=${T}
83 local fail=false test=
84 for test in tst_*; do
85 # skip test that requires messageserver to be running
86 [[ ${test} == tst_qmailstorageaction ]] && continue
87
88 if ! LC_ALL=C ./${test}/${test}; then
89 eerror "${test#tst_} test failed!"
90 fail=true
91 fi
92 echo
93 done
94
95 ${fail} && die "some tests have failed!"
96 }
97
98 src_install() {
99 qt4-r2_src_install
100
101 if use doc; then
102 emake docs
103
104 dodoc -r doc/html
105 dodoc doc/html/qmf.qch
106 docompress -x /usr/share/doc/${PF}/qmf.qch
107 fi
108 }

  ViewVC Help
Powered by ViewVC 1.1.20