/[gentoo-x86]/net-misc/chrony/chrony-1.29-r2.ebuild
Gentoo

Contents of /net-misc/chrony/chrony-1.29-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Tue Feb 4 14:59:40 2014 UTC (5 years, 10 months ago) by jer
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump (bug #500258).

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A792A613)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-1.29-r2.ebuild,v 1.1 2013/11/22 15:48:04 jer Exp $
4
5 EAPI=5
6 inherit eutils systemd toolchain-funcs
7
8 DESCRIPTION="NTP client and server programs"
9 HOMEPAGE="http://chrony.tuxfamily.org/"
10 SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.gz"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~sparc ~x86"
15 IUSE="caps ipv6 +readline +rtc selinux"
16
17 RDEPEND="
18 caps? ( sys-libs/libcap )
19 readline? ( >=sys-libs/readline-4.1-r4 )
20 selinux? ( sec-policy/selinux-chronyd )
21 "
22 DEPEND="
23 ${RDEPEND}
24 sys-apps/texinfo
25 "
26
27 S="${WORKDIR}/${P/_/-}"
28
29 src_prepare() {
30 sed -i \
31 -e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
32 -e 's:/var/run:/run:g' \
33 conf.c chrony.texi.in chrony.txt examples/* faq.txt || die
34 }
35
36 src_configure() {
37 tc-export CC
38
39 # not an autotools generated script
40 ./configure \
41 $(usex caps '' --disable-linuxcaps) \
42 $(usex ipv6 '' --disable-ipv6) \
43 $(usex readline '' --disable-readline) \
44 $(usex rtc '' --disable-rtc) \
45 --docdir=/usr/share/doc/${PF} \
46 --infodir=/usr/share/info \
47 --mandir=/usr/share/man \
48 --prefix=/usr \
49 --sysconfdir=/etc/chrony \
50 --without-nss \
51 --without-tomcrypt \
52 ${EXTRA_ECONF} \
53 || die
54 }
55
56 src_compile() {
57 emake all docs
58 }
59
60 src_install() {
61 default
62 rm "${D}"/usr/share/doc/${PF}/COPYING || die
63 doinfo chrony.info*
64
65 newinitd "${FILESDIR}"/chronyd.init chronyd
66 newconfd "${FILESDIR}"/chronyd.conf chronyd
67
68 insinto /etc/${PN}
69 newins examples/chrony.conf.example chrony.conf
70 newins examples/chrony.keys.example chrony.keys
71
72 keepdir /var/{lib,log}/chrony
73
74 insinto /etc/logrotate.d
75 newins "${FILESDIR}"/chrony.logrotate chrony
76
77 systemd_newunit "${FILESDIR}"/chronyd.service-r1 chronyd.service
78 systemd_enable_ntpunit 50-chrony chronyd.service
79 }

  ViewVC Help
Powered by ViewVC 1.1.20