/[gentoo-x86]/net-misc/flexget/flexget-1.2.141.ebuild
Gentoo

Contents of /net-misc/flexget/flexget-1.2.141.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Apr 8 18:04:50 2015 UTC (4 years, 8 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +3 -3 lines
Drop old Python implementations

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/flexget/flexget-1.2.141.ebuild,v 1.2 2014/07/06 12:55:43 mgorny Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python2_7 )
8
9 inherit distutils-r1 eutils
10
11 if [[ ${PV} != 9999 ]]; then
12 MY_P="FlexGet-${PV}"
13 SRC_URI="http://download.flexget.com/${MY_P}.tar.gz
14 http://download.flexget.com/archive/${MY_P}.tar.gz"
15 KEYWORDS="~amd64 ~x86"
16 else
17 inherit git-r3
18 EGIT_REPO_URI="git://github.com/Flexget/Flexget.git
19 https://github.com/Flexget/Flexget.git"
20 fi
21
22 DESCRIPTION="Multipurpose automation tool for content like torrents, nzbs, podcasts, comics"
23 HOMEPAGE="http://flexget.com/"
24
25 LICENSE="MIT"
26 SLOT="0"
27 IUSE="test transmission"
28
29 DEPEND="
30 >=dev-python/feedparser-5.1.3[${PYTHON_USEDEP}]
31 >=dev-python/sqlalchemy-0.7.5[${PYTHON_USEDEP}]
32 <dev-python/sqlalchemy-0.9.99
33 dev-python/pyyaml[${PYTHON_USEDEP}]
34 >=dev-python/beautifulsoup-4.1:4[${PYTHON_USEDEP}]
35 <dev-python/beautifulsoup-4.4:4[${PYTHON_USEDEP}]
36 !=dev-python/beautifulsoup-4.2.0
37 >=dev-python/html5lib-0.11[${PYTHON_USEDEP}]
38 dev-python/PyRSS2Gen[${PYTHON_USEDEP}]
39 dev-python/pynzb[${PYTHON_USEDEP}]
40 dev-python/progressbar[${PYTHON_USEDEP}]
41 dev-python/rpyc[${PYTHON_USEDEP}]
42 dev-python/jinja[${PYTHON_USEDEP}]
43 >=dev-python/requests-1.0[${PYTHON_USEDEP}]
44 <dev-python/requests-2.99[${PYTHON_USEDEP}]
45 =dev-python/python-dateutil-2.1*[${PYTHON_USEDEP}]
46 >=dev-python/jsonschema-2.0[${PYTHON_USEDEP}]
47 dev-python/python-tvrage[${PYTHON_USEDEP}]
48 dev-python/tmdb3[${PYTHON_USEDEP}]
49 dev-python/setuptools[${PYTHON_USEDEP}]
50 "
51 RDEPEND="${DEPEND}
52 transmission? ( dev-python/transmissionrpc[${PYTHON_USEDEP}] )
53 "
54 DEPEND+=" test? ( dev-python/nose[${PYTHON_USEDEP}] )"
55
56 if [[ ${PV} == 9999 ]]; then
57 DEPEND+=" dev-python/paver[${PYTHON_USEDEP}]"
58 else
59 S="${WORKDIR}/${MY_P}"
60 fi
61
62 python_prepare_all() {
63 # Prevent setup from grabbing nose from pypi
64 sed -e /setup_requires/d -i pavement.py || die
65
66 distutils-r1_python_prepare_all
67 }
68
69 python_test() {
70 cp -lr tests setup.cfg "${BUILD_DIR}" || die
71 run_in_build_dir nosetests -v --attr=!online > "${T}/tests-${EPYTHON}.log" \
72 || die "Tests fail with ${EPYTHON}"
73 }

  ViewVC Help
Powered by ViewVC 1.1.20