/[gentoo-x86]/net-misc/netifrc/netifrc-9999.ebuild
Gentoo

Contents of /net-misc/netifrc/netifrc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.13 - (show annotations) (download)
Sat Apr 25 16:28:24 2015 UTC (4 years, 7 months ago) by floppym
Branch: MAIN
CVS Tags: HEAD
Changes since 1.12: +2 -2 lines
Replace links pointing at git.overlays.gentoo.org.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/netifrc/netifrc-9999.ebuild,v 1.12 2015/03/12 12:24:41 heroxbd Exp $
4
5 EAPI=5
6
7 inherit eutils systemd udev
8
9 DESCRIPTION="Gentoo Network Interface Management Scripts"
10 HOMEPAGE="http://www.gentoo.org/proj/en/base/openrc/"
11
12 if [[ ${PV} == "9999" ]]; then
13 EGIT_REPO_URI="git://anongit.gentoo.org/proj/${PN}.git"
14 #EGIT_REPO_URI="git://github.com/gentoo/netifrc" # Alternate
15 inherit git-r3
16 else
17 SRC_URI="http://dev.gentoo.org/~robbat2/dist/${P}.tar.bz2"
18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
19 fi
20
21 LICENSE="BSD-2"
22 SLOT="0"
23 IUSE=""
24
25 DEPEND="kernel_linux? ( virtual/pkgconfig )
26 !<sys-fs/udev-172"
27 RDEPEND="sys-apps/gentoo-functions"
28
29 src_prepare() {
30 if [[ ${PV} == "9999" ]] ; then
31 local ver="git-${EGIT_VERSION:0:6}"
32 sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/git.mk || die
33 einfo "Producing ChangeLog from Git history"
34 GIT_DIR="${S}/.git" git log >"${S}"/ChangeLog
35 fi
36
37 # Allow user patches to be applied without modifying the ebuild
38 epatch_user
39 }
40
41 src_compile() {
42 MAKE_ARGS="${MAKE_ARGS}
43 UDEVDIR=${EPREFIX}$(get_udevdir)
44 LIBEXECDIR=${EPREFIX}/lib/${PN} PF=${PF}"
45
46 use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
47
48 emake ${MAKE_ARGS} all
49 }
50
51 src_install() {
52 emake ${MAKE_ARGS} DESTDIR="${D}" install
53 dodoc README CREDITS FEATURE-REMOVAL-SCHEDULE STYLE TODO ChangeLog
54
55 # Install the service file
56 LIBEXECDIR=${EPREFIX}/lib/${PN}
57 UNIT_DIR="$(systemd_get_unitdir)"
58 sed "s:@LIBEXECDIR@:${LIBEXECDIR}:" "${S}/systemd/net_at.service.in" > "${T}/net_at.service" || die
59 systemd_newunit "${T}/net_at.service" 'net@.service'
60 dosym "${UNIT_DIR#${EPREFIX}}/net@.service" "${UNIT_DIR#${EPREFIX}}/net@lo.service"
61 }
62
63 pkg_postinst() {
64 if [[ ! -e "${EROOT}"/etc/conf.d/net && -z $REPLACING_VERSIONS ]]; then
65 elog "The network configuration scripts will use dhcp by"
66 elog "default to set up your interfaces."
67 elog "If you need to set up something more complete, see"
68 elog "${EROOT}/usr/share/doc/${P}/README"
69 fi
70 }

  ViewVC Help
Powered by ViewVC 1.1.20