/[gentoo-x86]/net-misc/networkmanager/networkmanager-0.8.1-r6.ebuild
Gentoo

Contents of /net-misc/networkmanager/networkmanager-0.8.1-r6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Tue Aug 23 23:17:09 2011 UTC (8 years, 3 months ago) by nirbheek
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +1 -1 lines
FILE REMOVED
Bump for the 0.9.0 release, go forth and test. Also, remove old ebuilds and unused patches.

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.8.1-r6.ebuild,v 1.4 2011/06/09 01:41:03 sping Exp $
4
5 EAPI="2"
6
7 inherit autotools eutils gnome.org linux-info
8
9 # NetworkManager likes itself with capital letters
10 MY_PN=${PN/networkmanager/NetworkManager}
11 MY_P=${MY_PN}-${PV}
12
13 DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
14 HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
15 SRC_URI="${SRC_URI//${PN}/${MY_PN}}
16 http://dev.gentoo.org/~dagger/files/${PN}-ifnet-540e40f.patch"
17
18 LICENSE="GPL-2"
19 SLOT="0"
20 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
21 IUSE="avahi bluetooth doc nss gnutls dhclient dhcpcd kernel_linux resolvconf connection-sharing"
22
23 RDEPEND=">=sys-apps/dbus-1.2
24 >=dev-libs/dbus-glib-0.75
25 >=net-wireless/wireless-tools-28_pre9
26 || ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-145[extras] )
27 >=dev-libs/glib-2.18
28 >=sys-auth/polkit-0.92
29 >=dev-libs/libnl-1.1
30 >=net-misc/modemmanager-0.2
31 >=net-wireless/wpa_supplicant-0.5.10[dbus]
32 bluetooth? ( net-wireless/bluez )
33 || ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
34 avahi? ( net-dns/avahi[autoipd] )
35 gnutls? (
36 nss? ( >=dev-libs/nss-3.11 )
37 !nss? ( dev-libs/libgcrypt
38 net-libs/gnutls ) )
39 !gnutls? ( >=dev-libs/nss-3.11 )
40 dhclient? (
41 dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
42 !dhcpcd? ( net-misc/dhcp ) )
43 !dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
44 resolvconf? ( net-dns/openresolv )
45 connection-sharing? (
46 net-dns/dnsmasq
47 net-firewall/iptables )"
48
49 DEPEND="${RDEPEND}
50 dev-util/pkgconfig
51 dev-util/intltool
52 >=net-dialup/ppp-2.4.5
53 doc? ( >=dev-util/gtk-doc-1.8 )"
54
55 S=${WORKDIR}/${MY_P}
56
57 sysfs_deprecated_check() {
58 ebegin "Checking for SYSFS_DEPRECATED support"
59
60 if { linux_chkconfig_present SYSFS_DEPRECATED_V2; }; then
61 eerror "Please disable SYSFS_DEPRECATED_V2 support in your kernel config and recompile your kernel"
62 eerror "or NetworkManager will not work correctly."
63 eerror "See http://bugs.gentoo.org/333639 for more info."
64 die "CONFIG_SYSFS_DEPRECATED_V2 support detected!"
65 fi
66 eend $?
67 }
68
69 pkg_setup() {
70 # FIXME. Required by -confchanges.patch, but the patch is invalid as
71 # ConsoleKit and PolicyKit is enough to get authorization.
72 enewgroup plugdev
73
74 if use kernel_linux; then
75 get_version
76 if linux_config_exists; then
77 sysfs_deprecated_check
78 else
79 ewarn "Was unable to determine your kernel .config"
80 ewarn "Please note that if CONFIG_SYSFS_DEPRECATED_V2 is set in your kernel .config, NetworkManager will not work correctly."
81 ewarn "See http://bugs.gentoo.org/333639 for more info."
82 fi
83
84 fi
85 }
86
87 src_prepare() {
88
89 # Gentoo system-plugin
90 epatch "${DISTDIR}/${PN}-ifnet-540e40f.patch"
91
92 # Fix up the dbus conf file to use plugdev group
93 epatch "${FILESDIR}/${P}-confchanges.patch"
94
95 # Fix problems with dhcpcd/dhclient (bug #330319)
96 epatch "${FILESDIR}/${P}-dhcp-configure.patch"
97
98 # Backport some important patches
99 epatch "${FILESDIR}/${P}-CVE-2010-1172.patch"
100 epatch "${FILESDIR}/${P}-glib-2.25.12-workaround.patch"
101 epatch "${FILESDIR}/${P}-dhclient3.patch"
102 epatch "${FILESDIR}/${P}-dhclient3-fix.patch"
103
104 eautoreconf
105 }
106
107 src_configure() {
108 ECONF="--disable-more-warnings
109 --localstatedir=/var
110 --with-distro=gentoo
111 --with-dbus-sys-dir=/etc/dbus-1/system.d
112 --with-udev-dir=/etc/udev
113 --with-iptables=/sbin/iptables
114 $(use_enable doc gtk-doc)
115 $(use_with doc docs)
116 $(use_with resolvconf)"
117
118 # default is dhcpcd (if none or both are specified), ISC dchclient otherwise
119 if use dhclient ; then
120 if use dhcpcd ; then
121 ECONF="${ECONF} --with-dhcpcd --without-dhclient"
122 else
123 ECONF="${ECONF} --with-dhclient --without-dhcpcd"
124 fi
125 else
126 ECONF="${ECONF} --with-dhcpcd --without-dhclient"
127 fi
128
129 # default is NSS (if none or both are specified), GnuTLS otherwise
130 if use gnutls ; then
131 if use nss ; then
132 ECONF="${ECONF} --with-crypto=nss"
133 else
134 ECONF="${ECONF} --with-crypto=gnutls"
135 fi
136 else
137 ECONF="${ECONF} --with-crypto=nss"
138 fi
139
140 econf ${ECONF}
141 }
142
143 src_install() {
144 emake DESTDIR="${D}" install || die "emake install failed"
145
146 # Need to keep the /var/run/NetworkManager directory
147 keepdir /var/run/NetworkManager
148
149 # Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
150 keepdir /etc/NetworkManager/dispatcher.d
151
152 dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
153
154 # Add keyfile plugin support
155 keepdir /etc/NetworkManager/system-connections
156 insinto /etc/NetworkManager
157 newins "${FILESDIR}/nm-system-settings.conf-ifnet" nm-system-settings.conf \
158 || die "newins failed"
159 }
160
161 pkg_postinst() {
162 elog "You will need to reload DBus if this is your first time installing"
163 elog "NetworkManager, or if you're upgrading from 0.7 or older."
164 elog ""
165 }

  ViewVC Help
Powered by ViewVC 1.1.20