/[gentoo-x86]/net-misc/nx/nx-3.5.0.27.ebuild
Gentoo

Contents of /net-misc/nx/nx-3.5.0.27.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Wed Feb 18 17:19:38 2015 UTC (4 years, 6 months ago) by voyageur
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +1 -1 lines
FILE REMOVED
Missing build dependency on x11-libs/libfontenc, thanks everyone in bug #536058. Remove some versions

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key C74525F2)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.5.0.27.ebuild,v 1.3 2014/08/22 08:20:03 voyageur Exp $
4
5 EAPI=5
6 inherit autotools eutils multilib readme.gentoo
7
8 DESCRIPTION="NX compression technology core libraries"
9 HOMEPAGE="http://www.x2go.org/doku.php/wiki:libs:nx-libs"
10
11 SRC_URI="http://code.x2go.org/releases/source/nx-libs/nx-libs-${PV}-full.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~ppc ~x86"
16 IUSE="elibc_glibc"
17
18 RDEPEND="elibc_glibc? ( || ( net-libs/libtirpc <sys-libs/glibc-2.14 ) )
19 media-libs/freetype:2
20 >=media-libs/libpng-1.2.8
21 >=sys-libs/zlib-1.2.3
22 virtual/jpeg"
23
24 DEPEND="${RDEPEND}
25 x11-misc/gccmakedep
26 x11-misc/imake
27 x11-proto/inputproto"
28
29 S=${WORKDIR}/nx-libs-${PV}
30
31 DOC_CONTENTS="If you get problems with rendering gtk+ apps, enable the xlib-xcb
32 useflag on x11-libs/cairo."
33
34 src_prepare() {
35 # For nxcl/qtnx
36 cd "${S}"/nxproxy
37 epatch "${FILESDIR}"/${PN}-3.2.0-nxproxy_read_from_stdin.patch
38
39 cd "${S}"
40 epatch "${FILESDIR}"/${P}-jpeg-9a.patch #481360
41 # -fPIC
42 epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
43 # Drop force -O3, set AR/RANLIB and
44 # run autoreconf in all neeed folders
45 epatch "${FILESDIR}"/${PN}-3.5.0.17-cflags_ar_ranlib.patch
46 for i in nxcomp nxcompext nxcompshad nxproxy; do
47 cd "${S}"/${i}
48 eautoreconf ${i}
49 cd "${S}"
50 done
51
52 # From xorg-x11-6.9.0-r3.ebuild
53 cd "${S}/nx-X11"
54 HOSTCONF="config/cf/host.def"
55 echo "#define CcCmd $(tc-getCC)" >> ${HOSTCONF}
56 echo "#define OptimizedCDebugFlags ${CFLAGS} GccAliasingArgs" >> ${HOSTCONF}
57 echo "#define OptimizedCplusplusDebugFlags ${CXXFLAGS} GccAliasingArgs" >> ${HOSTCONF}
58 # Respect LDFLAGS
59 echo "#define ExtraLoadFlags ${LDFLAGS}" >> ${HOSTCONF}
60 echo "#define SharedLibraryLoadFlags -shared ${LDFLAGS}" >> ${HOSTCONF}
61 }
62
63 src_configure() {
64 cd "${S}"/nxproxy
65 econf
66 }
67
68 src_compile() {
69 cd "${S}/nx-X11"
70 FAST=1 emake World WORLDOPTS="" MAKE="make" \
71 AR="$(tc-getAR) clq" RANLIB="$(tc-getRANLIB)" \
72 CC="$(tc-getCC)" CXX="$(tc-getCXX)"
73
74 cd "${S}"/nxproxy
75 emake
76 }
77
78 src_install() {
79 NX_ROOT=/usr/$(get_libdir)/NX
80
81 for x in nxagent nxauth nxproxy; do
82 make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
83 die " $x wrapper creation failed"
84 done
85
86 into ${NX_ROOT}
87 dobin "${S}"/nx-X11/programs/Xserver/nxagent
88 dobin "${S}"/nx-X11/programs/nxauth/nxauth
89 dobin "${S}"/nxproxy/nxproxy
90
91 for lib in X11 Xau Xcomposite Xdamage Xdmcp Xext Xfixes Xinerama Xpm Xrandr Xrender Xtst;
92 do
93 dolib.so "${S}"/nx-X11/lib/${lib}/libNX_${lib}.so*
94 done
95
96 dolib.so "${S}"/nxcomp/libXcomp.so*
97 dolib.so "${S}"/nxcompext/libXcompext.so*
98 dolib.so "${S}"/nxcompshad/libXcompshad.so*
99
100 insinto /etc/nxagent
101 newins etc/keystrokes.cfg keystroke.cfg
102 doicon nx-X11/programs/Xserver/hw/nxagent/x2go.xpm
103
104 readme.gentoo_create_doc
105 }

  ViewVC Help
Powered by ViewVC 1.1.20