/[gentoo-x86]/net-misc/owncloud-client/owncloud-client-1.8.4.ebuild
Gentoo

Contents of /net-misc/owncloud-client/owncloud-client-1.8.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Mon Aug 3 07:58:27 2015 UTC (4 years, 4 months ago) by voyageur
Branch: MAIN
CVS Tags: HEAD
Version bump, drop some old versions

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 00F7AB331B0F097F)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/owncloud-client/owncloud-client-1.8.3.ebuild,v 1.2 2015/06/26 23:01:36 voyageur Exp $
4
5 EAPI=5
6
7 inherit cmake-utils
8
9 DESCRIPTION="Synchronize files from ownCloud Server with your computer"
10 HOMEPAGE="http://owncloud.org/"
11 SRC_URI="http://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
12
13 LICENSE="CC-BY-3.0 GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="doc nautilus samba +sftp test qt4 +qt5"
17
18 REQUIRED_USE="^^ ( qt4 qt5 )"
19
20 RDEPEND=">=dev-db/sqlite-3.4:3
21 sys-fs/inotify-tools
22 virtual/libiconv
23 nautilus? ( dev-python/nautilus-python )
24 qt4? (
25 dev-libs/qtkeychain[qt4]
26 dev-qt/qtcore:4
27 dev-qt/qtdbus:4
28 dev-qt/qtgui:4
29 dev-qt/qtsql:4
30 dev-qt/qtwebkit:4
31 net-libs/neon[ssl]
32 )
33 qt5? (
34 dev-libs/qtkeychain[qt5]
35 dev-qt/linguist-tools:5
36 dev-qt/qtconcurrent:5
37 dev-qt/qtcore:5
38 dev-qt/qtdbus:5
39 >=dev-qt/qtnetwork-5.4:5
40 dev-qt/qtgui:5
41 dev-qt/qtquickcontrols:5
42 dev-qt/qtsql:5
43 dev-qt/qtwebkit:5[printsupport]
44 )
45 samba? ( >=net-fs/samba-3.5 )
46 sftp? ( >=net-libs/libssh-0.5 )
47 !net-misc/ocsync"
48 DEPEND="${RDEPEND}
49 doc? (
50 dev-python/sphinx
51 dev-texlive/texlive-latexextra
52 virtual/latex-base
53 )
54 test? (
55 dev-util/cmocka
56 qt4? ( dev-qt/qttest:4 )
57 qt5? ( dev-qt/qttest:5 )
58 )"
59
60 S=${WORKDIR}/${P/-}
61
62 src_prepare() {
63 # Keep tests in ${T}
64 sed -i -e "s#\"/tmp#\"${T}#g" test/test*.h || die "sed failed"
65
66 use nautilus || sed -i -e "s/add_subdirectory(nautilus)//" \
67 shell_integration/CMakeLists.txt || die "sed failed"
68 }
69
70 src_configure() {
71 local mycmakeargs=(
72 -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
73 -DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
74 -DWITH_ICONV=ON
75 $(cmake-utils_use_with doc DOC)
76 $(cmake-utils_use test UNIT_TESTING)
77 $(cmake-utils_use_find_package samba Libsmbclient)
78 $(cmake-utils_use_find_package sftp LibSSH)
79 $(cmake-utils_use_build qt4 WITH_QT4)
80 )
81
82 cmake-utils_src_configure
83 }
84
85 src_test() {
86 # 1 test needs an existing ${HOME}/.config directory
87 mkdir "${T}"/.config
88 export HOME="${T}"
89 cmake-utils_src_test
90 }
91
92 pkg_postinst() {
93 if ! use doc ; then
94 elog "Documentation and man pages not installed"
95 elog "Enable doc USE-flag to generate them"
96 fi
97 }

  ViewVC Help
Powered by ViewVC 1.1.20