/[gentoo-x86]/net-misc/putty/putty-0.63-r1.ebuild
Gentoo

Contents of /net-misc/putty/putty-0.63-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.7 - (show annotations) (download)
Sat Jan 18 20:04:21 2014 UTC (5 years, 8 months ago) by ago
Branch: MAIN
Changes since 1.6: +3 -3 lines
Stable for alpha, wrt bug #494408

(Portage version: 2.2.7/cvs/Linux x86_64, RepoMan options: --include-arches="alpha", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/putty/putty-0.63-r1.ebuild,v 1.6 2013/12/24 12:53:06 ago Exp $
4
5 EAPI=5
6
7 inherit autotools eutils gnome2-utils toolchain-funcs versionator
8
9 DESCRIPTION="A Free Telnet/SSH Client"
10 HOMEPAGE="http://www.chiark.greenend.org.uk/~sgtatham/putty/"
11 SRC_URI="
12 http://the.earth.li/~sgtatham/${PN}/latest/${P}.tar.gz
13 http://dev.gentoo.org/~jer/${PN}-icons.tar.bz2"
14 LICENSE="MIT"
15
16 SLOT="0"
17 KEYWORDS="alpha amd64 hppa ppc sparc x86"
18 IUSE="doc +gtk ipv6 kerberos"
19
20 RDEPEND="
21 !net-misc/pssh
22 kerberos? ( virtual/krb5 )
23 gtk? ( x11-libs/gdk-pixbuf
24 x11-libs/gtk+:2
25 x11-libs/libX11
26 x11-libs/pango
27 dev-libs/glib )
28 "
29 DEPEND="
30 ${RDEPEND}
31 dev-lang/perl
32 virtual/pkgconfig
33 "
34
35 src_prepare() {
36 cd "${S}"/unix || die
37 sed -i \
38 -e '/AM_PATH_GTK(/d' \
39 -e 's|-Wall -Werror||g' \
40 configure.ac || die
41
42 eautoreconf
43 }
44
45 src_configure() {
46 cd "${S}"/unix || die
47 econf \
48 $(use_with kerberos gssapi) \
49 $(use_with gtk)
50 }
51
52 src_compile() {
53 cd "${S}"/unix || die
54 emake AR=$(tc-getAR) $(usex ipv6 '' COMPAT=-DNO_IPV6)
55 }
56
57 src_install() {
58 dodoc doc/puttydoc.txt
59
60 if use doc; then
61 dohtml doc/*.html
62 fi
63
64 cd "${S}"/unix || die
65 default
66
67 if use gtk ; then
68 for i in 16 22 24 32 48 64 128 256; do
69 newicon -s ${i} "${WORKDIR}"/${PN}-icons/${PN}-${i}.png ${PN}.png
70 done
71
72 # install desktop file provided by Gustav Schaffter in #49577
73 make_desktop_entry ${PN} PuTTY ${PN} Network
74 fi
75 }
76
77 pkg_preinst() {
78 use gtk && gnome2_icon_savelist
79 }
80
81 pkg_postinst() {
82 use gtk && gnome2_icon_cache_update
83 }
84
85 pkg_postrm() {
86 use gtk && gnome2_icon_cache_update
87 }

  ViewVC Help
Powered by ViewVC 1.1.20