/[gentoo-x86]/net-misc/rygel/rygel-0.22.2.ebuild
Gentoo

Contents of /net-misc/rygel/rygel-0.22.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Tue Dec 23 23:17:14 2014 UTC (4 years, 8 months ago) by eva
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +1 -1 lines
FILE REMOVED
Version bump for Gnome 3.14. Clean up old revision.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key C6085806)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.22.2.ebuild,v 1.3 2014/07/23 15:24:09 ago Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7
8 inherit gnome2 virtualx
9
10 DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
11 HOMEPAGE="https://wiki.gnome.org/Projects/Rygel"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="amd64 x86"
16 IUSE="X nls +sqlite tracker test transcode"
17
18 # The deps for tracker? and transcode? are just the earliest available
19 # version at the time of writing this ebuild
20 RDEPEND="
21 >=dev-libs/glib-2.34:2
22 >=dev-libs/libgee-0.8:0.8
23 >=dev-libs/libxml2-2.7:2
24 >=media-libs/gupnp-dlna-0.9.4:2.0
25 media-libs/gstreamer:1.0
26 media-libs/gst-plugins-base:1.0
27 media-plugins/gst-plugins-soup:1.0
28 >=net-libs/gssdp-0.13
29 >=net-libs/gupnp-0.19
30 >=net-libs/gupnp-av-0.12.4
31 >=net-libs/libsoup-2.44:2.4
32 >=sys-apps/util-linux-2.20
33 x11-misc/shared-mime-info
34 sqlite? (
35 >=dev-db/sqlite-3.5:3
36 dev-libs/libunistring
37 )
38 tracker? ( >=app-misc/tracker-0.16:= )
39 transcode? (
40 media-libs/gst-plugins-bad:1.0
41 media-plugins/gst-plugins-twolame:1.0
42 media-plugins/gst-plugins-libav:1.0
43 )
44 X? ( >=x11-libs/gtk+-3:3 )
45 "
46 DEPEND="${RDEPEND}
47 dev-util/gtk-doc-am
48 >=dev-util/intltool-0.40
49 sys-devel/gettext
50 virtual/pkgconfig
51 "
52 # Maintainer only
53 # >=dev-lang/vala-0.22
54 # dev-libs/libxslt
55
56 src_prepare() {
57 # runs gst-plugins-scanner on run with triggers sandbox violation
58 # trying to open dri
59 sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
60 -e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
61 -i tests/Makefile.in || die
62
63 gnome2_src_prepare
64 }
65
66 src_configure() {
67 # We defined xsltproc because man pages are provided by upstream
68 # and we do not want to regenerate them automagically.
69 gnome2_src_configure \
70 XSLTPROC=$(type -P false) \
71 --enable-gst-launch-plugin \
72 --enable-mediathek-plugin \
73 --with-media-engine=gstreamer \
74 $(use_enable nls) \
75 $(use_enable sqlite media-export-plugin) \
76 $(use_enable test tests) \
77 $(use_enable tracker tracker-plugin) \
78 $(use_with X ui)
79 }
80
81 src_install() {
82 gnome2_src_install
83 # Autostart file is not placed correctly, bug #402745
84 insinto /etc/xdg/autostart
85 doins "${D}"/usr/share/applications/rygel.desktop
86 rm "${D}"/usr/share/applications/rygel.desktop
87 }

  ViewVC Help
Powered by ViewVC 1.1.20