/[gentoo-x86]/net-misc/teamviewer/teamviewer-10.0.41499-r1.ebuild
Gentoo

Contents of /net-misc/teamviewer/teamviewer-10.0.41499-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Tue Jun 30 19:49:11 2015 UTC (4 years, 5 months ago) by np-hardass
Branch: MAIN
CVS Tags: HEAD
Remove PID location edit in systemd service file.  Resolves bug #552564

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 18F89C67)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/teamviewer/teamviewer-10.0.41499.ebuild,v 1.1 2015/06/18 08:35:17 np-hardass Exp $
4
5 EAPI=5
6
7 inherit eutils gnome2-utils systemd unpacker
8
9 # Major version
10 MV=${PV/\.*}
11 MY_PN=${PN}${MV}
12 DESCRIPTION="All-In-One Solution for Remote Access and Support over the Internet"
13 HOMEPAGE="https://www.teamviewer.com"
14 SRC_URI="https://download.teamviewer.com/download/version_${MV}x/${PN}_${PV}_i386.deb"
15
16 IUSE="+system-wine"
17
18 LICENSE="TeamViewer LGPL-2.1" #LGPL for bundled wine
19 SLOT=${MV}
20 KEYWORDS="-* ~amd64 ~x86"
21
22 RESTRICT="bindist mirror"
23
24 RDEPEND="
25 system-wine? ( app-emulation/wine[abi_x86_32(-)] )
26 dev-qt/qtcore:4[abi_x86_32(-)]
27 dev-qt/qtgui:4[abi_x86_32(-)]
28 dev-qt/qtwebkit:4[abi_x86_32(-)]
29 media-libs/alsa-lib[abi_x86_32(-)]
30 x11-libs/libICE[abi_x86_32(-)]
31 x11-libs/libSM[abi_x86_32(-)]
32 x11-libs/libX11[abi_x86_32(-)]
33 x11-libs/libXau[abi_x86_32(-)]
34 x11-libs/libXdamage[abi_x86_32(-)]
35 x11-libs/libXdmcp[abi_x86_32(-)]
36 x11-libs/libXext[abi_x86_32(-)]
37 x11-libs/libXfixes[abi_x86_32(-)]
38 x11-libs/libXrandr[abi_x86_32(-)]
39 x11-libs/libXtst[abi_x86_32(-)]"
40
41 QA_PREBUILT="opt/teamviewer${MV}/*"
42
43 S=${WORKDIR}/opt/teamviewer/tv_bin
44
45 src_prepare() {
46 #epatch "${FILESDIR}/${P}-gentoo.patch"
47 sed \
48 -e "s/@TVV@/${MV}/g" \
49 "${FILESDIR}"/${PN}d.init > "${T}"/init || die
50 sed \
51 -e "s:/opt/teamviewer:/opt/teamviewer${MV}:g" \
52 "script//${PN}d.service" > "${T}/${PN}d.service" || die
53 sed \
54 -e "s/@TVV@/${PV}/g" \
55 -e "s/@TVMV@/${MV}/g" \
56 "${FILESDIR}"/${PN}.sh > "${T}"/sh || die
57 if ! use system-wine; then
58 sed -i "s/native=true/native=false/g" "${T}/sh" || die
59 fi
60 }
61
62 src_install () {
63 local destdir="/opt/${MY_PN}"
64
65 # install wine prefix skeleton and reg keys
66 insinto "${destdir}/wine/drive_c/"
67 doins -r wine/drive_c/TeamViewer/
68 # install bundled wine if necessary
69 if ! use system-wine; then
70 insinto "${destdir}/tv_bin/wine"
71 doins -r wine/{lib,share}
72 exeinto "${destdir}/tv_bin/wine/bin"
73 doexe wine/bin/{wine,wine-preloader,wineserver}
74 fi
75 # fix permissions
76 fperms 755 ${destdir}/wine/drive_c/TeamViewer/TeamViewer.exe
77
78 # install wine wrapper
79 exeinto "/opt/bin"
80 newexe "${T}/sh" "${MY_PN}"
81
82 # install teamviewer linux binaries
83 exeinto "${destdir}/tv_bin"
84 doexe TeamViewer_Desktop TVGuiDelegate TVGuiSlave.32
85 use amd64 && doexe TVGuiSlave.64
86
87 # install daemon binary and scripts
88 exeinto "${destdir}/tv_bin"
89 doexe ${PN}d
90 newinitd "${T}/init" ${PN}d${MV}
91 newconfd "${FILESDIR}/${PN}d.conf" ${PN}d${MV}
92 systemd_newunit "${T}/${PN}d.service" ${PN}d${MV}.service
93
94 # set up logdir
95 keepdir /var/log/${MY_PN}
96 dosym /var/log/${MY_PN} /opt/${MY_PN}/logfiles
97
98 # set up config dir
99 keepdir /etc/${MY_PN}
100 dosym /etc/${MY_PN} /opt/${MY_PN}/config
101
102 newicon -s 48 desktop/${PN}.png ${MY_PN}.png
103 #dodoc ../doc/linux_FAQ_{EN,DE}.txt
104 make_desktop_entry ${MY_PN} "TeamViewer ${MV}" ${MY_PN}
105 }
106
107 pkg_preinst() {
108 gnome2_icon_savelist
109 }
110
111 pkg_postinst() {
112 gnome2_icon_cache_update
113
114 elog "TeamViewer from upstream uses an overly-complicated set of bash"
115 elog "scripts to start the program. This has been simplified for Gentoo"
116 elog "use. Any issues should be reported via bugzilla."
117 if use system-wine; then
118 elog
119 elog "Due to bug #552016, when using system wine, one is not able to"
120 elog "share one's own screen. At this time, this may be remedied by"
121 elog "toggling the system-wine USE flag."
122 fi
123 elog
124 elog "The end-user client requires running the accompanying daemon,"
125 elog "available via init-scripts."
126 }
127
128 pkg_postrm() {
129 gnome2_icon_cache_update
130 }

  ViewVC Help
Powered by ViewVC 1.1.20