/[gentoo-x86]/net-misc/teamviewer/teamviewer-9.0.32150.ebuild
Gentoo

Contents of /net-misc/teamviewer/teamviewer-9.0.32150.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Thu Jun 18 08:35:17 2015 UTC (4 years, 5 months ago) by np-hardass
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
Version bump to 10.0.41499 and drop 10.0.36281.  Resolves bug #544222 and #542728

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 18F89C67)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/teamviewer/teamviewer-9.0.32150.ebuild,v 1.2 2015/06/14 18:36:29 ulm Exp $
4
5 EAPI=5
6
7 inherit eutils gnome2-utils systemd unpacker
8
9 # Major version
10 MV=${PV/\.*}
11 MY_PN=${PN}${MV}
12 DESCRIPTION="All-In-One Solution for Remote Access and Support over the Internet"
13 HOMEPAGE="http://www.teamviewer.com"
14 SRC_URI="http://www.teamviewer.com/download/version_${MV}x/teamviewer_linux.deb -> ${P}.deb"
15
16 LICENSE="TeamViewer !system-wine? ( LGPL-2.1 )"
17 SLOT=${MV}
18 KEYWORDS="~amd64 ~x86"
19 IUSE="system-wine"
20
21 RESTRICT="mirror"
22
23 RDEPEND="
24 app-shells/bash
25 x11-misc/xdg-utils
26 !system-wine? (
27 media-libs/alsa-lib[abi_x86_32(-)]
28 media-libs/freetype[abi_x86_32(-)]
29 sys-libs/zlib[abi_x86_32(-)]
30 x11-libs/libX11[abi_x86_32(-)]
31 x11-libs/libXau[abi_x86_32(-)]
32 x11-libs/libXdamage[abi_x86_32(-)]
33 x11-libs/libXext[abi_x86_32(-)]
34 x11-libs/libXfixes[abi_x86_32(-)]
35 x11-libs/libXrandr[abi_x86_32(-)]
36 x11-libs/libXrender[abi_x86_32(-)]
37 x11-libs/libSM[abi_x86_32(-)]
38 x11-libs/libXtst[abi_x86_32(-)]
39 )
40 system-wine? ( app-emulation/wine )"
41
42 QA_PREBUILT="opt/teamviewer${MV}/*"
43
44 S=${WORKDIR}/opt/teamviewer${MV}/tv_bin
45
46 make_winewrapper() {
47 cat << EOF > "${T}/${MY_PN}"
48 #!/bin/sh
49 export WINEDLLPATH=/opt/${MY_PN}
50 exec wine "/opt/${MY_PN}/TeamViewer.exe" "\$@"
51 EOF
52 chmod go+rx "${T}/${MY_PN}"
53 exeinto /opt/bin
54 doexe "${T}/${MY_PN}"
55 }
56
57 src_prepare() {
58 epatch "${FILESDIR}"/${P}-gentoo.patch
59
60 sed \
61 -e "s#@TVV@#${MV}/tv_bin#g" \
62 "${FILESDIR}"/${PN}d${MV}.init > "${T}"/${PN}d${MV} || die
63 }
64
65 src_install () {
66 if use system-wine ; then
67 make_winewrapper
68 exeinto /opt/${MY_PN}
69 doexe wine/drive_c/TeamViewer/*
70 else
71 # install scripts and .reg
72 insinto /opt/${MY_PN}/tv_bin
73 doins -r *
74
75 exeinto /opt/${MY_PN}/tv_bin
76 doexe TeamViewer_Desktop
77 exeinto /opt/${MY_PN}/tv_bin/script
78 doexe script/teamviewer script/tvw_{aux,config,exec,extra,main,profile}
79
80 dosym /opt/${MY_PN}/tv_bin/script/${PN} /opt/bin/${MY_PN}
81
82 # fix permissions
83 fperms 755 /opt/${MY_PN}/tv_bin/wine/bin/wine{,-preloader,server}
84 fperms 755 /opt/${MY_PN}/tv_bin/wine/drive_c/TeamViewer/TeamViewer.exe
85 find "${D}"/opt/${MY_PN} -type f -name "*.so*" -execdir chmod 755 '{}' \;
86 fi
87
88 # install daemon binary
89 exeinto /opt/${MY_PN}/tv_bin
90 doexe ${PN}d
91
92 # set up logdir
93 keepdir /var/log/${MY_PN}
94 dosym /var/log/${MY_PN} /opt/${MY_PN}/logfiles
95
96 # set up config dir
97 keepdir /etc/${MY_PN}
98 dosym /etc/${MY_PN} /opt/${MY_PN}/config
99
100 doinitd "${T}"/${PN}d${MV}
101 systemd_newunit script/${PN}d.service ${PN}d${MV}.service
102
103 newicon -s 48 desktop/${PN}.png ${MY_PN}.png
104 dodoc ../doc/linux_FAQ_{EN,DE}.txt
105 make_desktop_entry ${MY_PN} TeamViewer ${MY_PN}
106 }
107
108 pkg_preinst() {
109 gnome2_icon_savelist
110 }
111
112 pkg_postinst() {
113 gnome2_icon_cache_update
114
115 if use system-wine ; then
116 echo
117 eerror "IMPORTANT NOTICE!"
118 elog "Using ${PN} with system wine is not supported and experimental."
119 elog "Do not report gentoo bugs while using this version."
120 echo
121 fi
122
123 eerror "STARTUP NOTICE:"
124 elog "You cannot start the daemon via \"teamviewer --daemon start\"."
125 elog "Instead use the provided gentoo initscript:"
126 elog " /etc/init.d/${PN}d${MV} start"
127 elog
128 elog "Logs are written to \"/var/log/teamviewer${MV}\""
129 }
130
131 pkg_postrm() {
132 gnome2_icon_cache_update
133 }

  ViewVC Help
Powered by ViewVC 1.1.20