/[gentoo-x86]/net-misc/tlsdate/tlsdate-0.0.12-r2.ebuild
Gentoo

Contents of /net-misc/tlsdate/tlsdate-0.0.12-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Fri Mar 6 18:48:11 2015 UTC (4 years, 6 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +2 -2 lines
Add ia64 love.

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/tlsdate/tlsdate-0.0.12-r2.ebuild,v 1.4 2015/02/22 06:26:07 vapier Exp $
4
5 EAPI="4"
6
7 inherit autotools vcs-snapshot user
8
9 DESCRIPTION="Update local time over HTTPS"
10 HOMEPAGE="https://github.com/ioerror/tlsdate"
11 SRC_URI="https://github.com/ioerror/tlsdate/tarball/${P} -> ${P}.tar.gz"
12
13 LICENSE="BSD"
14 SLOT="0"
15 KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~mips ~x86"
16 IUSE="dbus +seccomp static-libs"
17
18 DEPEND="dev-libs/openssl
19 dev-libs/libevent
20 dbus? ( sys-apps/dbus )"
21 RDEPEND="${DEPEND}"
22
23 src_prepare() {
24 # Use the system cert store rather than a custom one specific
25 # to the tlsdate package. #534394
26 sed -i \
27 -e 's:/tlsdate/ca-roots/tlsdate-ca-roots.conf:/ssl/certs/ca-certificates.crt:' \
28 Makefile.am || die
29
30 eautoreconf
31 }
32
33 src_configure() {
34 econf \
35 --disable-silent-rules \
36 $(use_enable dbus) \
37 $(use_enable seccomp seccomp-filter) \
38 --disable-hardened-checks \
39 --without-polarssl \
40 --with-unpriv-user=tlsdate \
41 --with-unpriv-group=tlsdate
42 }
43
44 src_install() {
45 default
46
47 # Use Google servers by default rather than a random German site.
48 # They provide round robin DNS and local servers automatically.
49 sed -i \
50 -e 's:www.ptb.de:www.google.com:' \
51 "${ED}"/etc/tlsdate/tlsdated.conf || die
52
53 # Use the system cert store; see src_prepare. #446426 #534394
54 rm "${ED}"/etc/tlsdate/ca-roots/tlsdate-ca-roots.conf || die
55 rmdir "${ED}"/etc/tlsdate/ca-roots || die
56
57 newinitd "${FILESDIR}"/tlsdated.rc tlsdated
58 newconfd "${FILESDIR}"/tlsdated.confd tlsdated
59 newinitd "${FILESDIR}"/tlsdate.rc tlsdate
60 newconfd "${FILESDIR}"/tlsdate.confd tlsdate
61
62 insinto /etc/dbus-1/system.d/
63 doins dbus/org.torproject.tlsdate.conf
64
65 use static-libs || \
66 find "${ED}"/usr '(' -name '*.la' -o -name '*.a' ')' -delete
67 }
68
69 pkg_preinst() {
70 enewgroup tlsdate 124
71 enewuser tlsdate 124 -1 /dev/null tlsdate
72 }

  ViewVC Help
Powered by ViewVC 1.1.20