/[gentoo-x86]/net-misc/tor/tor-0.2.5.10-r1.ebuild
Gentoo

Contents of /net-misc/tor/tor-0.2.5.10-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Thu Nov 20 14:41:41 2014 UTC (5 years ago) by blueness
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Revert last commit, bug #529212

(Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.5.10-r1.ebuild,v 1.1 2014/11/17 00:52:16 blueness Exp $
4
5 EAPI="5"
6
7 inherit eutils flag-o-matic readme.gentoo systemd toolchain-funcs versionator user
8
9 MY_PV="$(replace_version_separator 4 -)"
10 MY_PF="${PN}-${MY_PV}"
11 DESCRIPTION="Anonymizing overlay network for TCP"
12 HOMEPAGE="http://www.torproject.org/"
13 SRC_URI="https://www.torproject.org/dist/${MY_PF}.tar.gz
14 https://archive.torproject.org/tor-package-archive/${MY_PF}.tar.gz"
15 S="${WORKDIR}/${MY_PF}"
16
17 LICENSE="BSD GPL-2"
18 SLOT="0"
19 KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
20 IUSE="-bufferevents +ecc nat-pmp seccomp selinux stats tor-hardening transparent-proxy threads test upnp web"
21
22 DEPEND="dev-libs/openssl
23 sys-libs/zlib
24 dev-libs/libevent
25 bufferevents? ( dev-libs/libevent[ssl] )
26 nat-pmp? ( net-libs/libnatpmp )
27 seccomp? ( sys-libs/libseccomp )
28 upnp? ( net-libs/miniupnpc )"
29 RDEPEND="${DEPEND}
30 selinux? ( sec-policy/selinux-tor )"
31
32 pkg_setup() {
33 enewgroup tor
34 enewuser tor -1 -1 /var/lib/tor tor
35 }
36
37 src_prepare() {
38 epatch "${FILESDIR}"/${PN}-0.2.3.14_alpha-torrc.sample.patch
39 }
40
41 src_configure() {
42 # Upstream isn't sure of all the user provided CFLAGS that
43 # will break tor, but does recommend against -fstrict-aliasing.
44 # We'll filter-flags them here as we encounter them.
45 filter-flags -fstrict-aliasing
46
47 econf \
48 --disable-buf-freelists \
49 --enable-asciidoc \
50 --docdir=/usr/share/doc/${PF} \
51 $(use_enable stats instrument-downloads) \
52 $(use_enable bufferevents) \
53 $(use_enable ecc curve25519) \
54 $(use_enable nat-pmp) \
55 $(use_enable seccomp) \
56 $(use_enable tor-hardening gcc-hardening) \
57 $(use_enable tor-hardening linker-hardening) \
58 $(use_enable transparent-proxy transparent) \
59 $(use_enable threads) \
60 $(use_enable upnp) \
61 $(use_enable web tor2web-mode) \
62 $(use_enable test unittests) \
63 $(use_enable test coverage)
64 }
65
66 src_install() {
67 readme.gentoo_create_doc
68
69 newconfd "${FILESDIR}"/tor.confd tor
70 newinitd "${FILESDIR}"/tor.initd-r7 tor
71 systemd_dounit "contrib/dist/${PN}.service"
72 systemd_dotmpfilesd "${FILESDIR}/${PN}.conf"
73
74 emake DESTDIR="${D}" install
75
76 keepdir /var/lib/tor
77
78 dodoc README ChangeLog ReleaseNotes doc/HACKING
79
80 fperms 750 /var/lib/tor
81 fowners tor:tor /var/lib/tor
82
83 insinto /etc/tor/
84 newins "${FILESDIR}"/torrc-r1 torrc
85 }
86
87 pkg_postinst() {
88 readme.gentoo_pkg_postinst
89
90 if [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -eq 8 && $(gcc-micro-version) -ge 1 ]] ; then
91 ewarn "Due to a bug in >=gcc-4.8.1, compiling ${P} with -Os leads to an infinite"
92 ewarn "loop. See:"
93 ewarn
94 ewarn " https://trac.torproject.org/projects/tor/ticket/10259"
95 ewarn " http://gcc.gnu.org/bugzilla/show_bug.cgi?id=59358"
96 ewarn
97 fi
98 }

  ViewVC Help
Powered by ViewVC 1.1.20