/[gentoo-x86]/net-wireless/blueman/blueman-1.23-r2.ebuild
Gentoo

Contents of /net-wireless/blueman/blueman-1.23-r2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Sat Aug 8 15:42:23 2015 UTC (4 years, 5 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +2 -2 lines
Clean up old. Update HOMEPAGE in the remaining ebuilds.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.23-r2.ebuild,v 1.4 2015/01/05 19:56:01 zerochaos Exp $
4
5 EAPI="4"
6
7 PYTHON_DEPEND="2:2.7"
8
9 inherit eutils python gnome2-utils
10
11 DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks"
12 HOMEPAGE="https://github.com/blueman-project/blueman"
13 SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
14
15 LICENSE="GPL-3"
16 SLOT="0"
17 KEYWORDS="~amd64 ~ppc ~x86"
18 IUSE="gconf sendto network nls policykit pulseaudio"
19
20 CDEPEND="dev-libs/glib:2
21 >=x11-libs/gtk+-2.12:2
22 x11-libs/startup-notification
23 dev-python/pygobject:2
24 <net-wireless/bluez-5
25 >=net-wireless/bluez-4.21"
26 DEPEND="${CDEPEND}
27 nls? ( dev-util/intltool sys-devel/gettext )
28 virtual/pkgconfig
29 >=dev-python/pyrex-0.9.8"
30 RDEPEND="${CDEPEND}
31 >=app-mobilephone/obex-data-server-0.4.4
32 sys-apps/dbus
33 dev-python/pygtk
34 dev-python/notify-python
35 dev-python/dbus-python
36 x11-themes/hicolor-icon-theme
37 gconf? ( dev-python/gconf-python )
38 sendto? ( gnome-base/nautilus )
39 network? ( || ( net-dns/dnsmasq
40 net-misc/dhcp
41 >=net-misc/networkmanager-0.8 ) )
42 policykit? ( sys-auth/polkit )
43 pulseaudio? ( media-sound/pulseaudio )"
44
45 pkg_setup() {
46 python_set_active_version 2.7
47 python_pkg_setup
48 }
49
50 src_prepare() {
51 # disable pyc compiling
52 ln -sf $(type -P true) py-compile
53
54 sed -i \
55 -e '/^Encoding/d' \
56 data/blueman-manager.desktop.in || die "sed failed"
57
58 epatch \
59 "${FILESDIR}/${P}-plugins-conf-file.patch" \
60 "${FILESDIR}/${P}-fix-broken-status-icon.patch" \
61 "${FILESDIR}/${P}-set-codeset-for-gettext-to-UTF-8-always.patch"
62 }
63
64 src_configure() {
65 econf \
66 --disable-static \
67 $(use_enable policykit polkit) \
68 $(use_enable sendto) \
69 --disable-hal \
70 $(use_enable nls)
71 }
72
73 src_install() {
74 default
75
76 python_convert_shebangs 2.7 "${D}"/usr/bin/blueman-* "${D}/usr/libexec/blueman-mechanism"
77
78 rm "${D}"/$(python_get_sitedir)/*.la
79 use sendto && rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la
80
81 use gconf || rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py
82 use policykit || rm -rf "${D}"/usr/share/polkit-1
83 use pulseaudio || rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py,plugins/applet/Pulse*.py}
84
85 python_need_rebuild
86 }
87
88 pkg_preinst() {
89 gnome2_icon_savelist
90 }
91
92 pkg_postinst() {
93 python_mod_optimize ${PN}
94 gnome2_icon_cache_update
95 }
96
97 pkg_postrm() {
98 python_mod_cleanup ${PN}
99 gnome2_icon_cache_update
100 }

  ViewVC Help
Powered by ViewVC 1.1.20