/[gentoo-x86]/net-wireless/blueman/blueman-1.98_p20150105.ebuild
Gentoo

Contents of /net-wireless/blueman/blueman-1.98_p20150105.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat Aug 8 15:42:23 2015 UTC (4 years, 5 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Clean up old. Update HOMEPAGE in the remaining ebuilds.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.98_p20150105.ebuild,v 1.1 2015/01/05 19:50:38 zerochaos Exp $
4
5 EAPI="5"
6
7 PYTHON_COMPAT=( python2_7 )
8 inherit eutils python-single-r1 gnome2-utils autotools
9
10 DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks"
11 HOMEPAGE="https://github.com/blueman-project/blueman"
12
13 if [[ ${PV} == "9999" ]] ; then
14 inherit git-r3
15 EGIT_REPO_URI="https://github.com/${PN}-project/${PN}.git"
16 KEYWORDS=""
17 else
18 #SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
19 SRC_URI="https://dev.gentoo.org/~zerochaos/distfiles/${P}.tar.xz"
20 KEYWORDS="~amd64 ~ppc ~x86"
21 fi
22
23 LICENSE="GPL-3"
24 SLOT="0"
25 IUSE="gconf gnome network nls policykit pulseaudio thunar"
26
27 CDEPEND="dev-libs/glib:2=
28 x11-libs/gtk+:3=
29 x11-libs/startup-notification:=
30 dev-python/dbus-python[${PYTHON_USEDEP}]
31 dev-python/pygobject:3
32 >=net-wireless/bluez-4.61:=
33 ${PYTHON_DEPS}"
34 DEPEND="${CDEPEND}
35 nls? ( dev-util/intltool sys-devel/gettext )
36 virtual/pkgconfig
37 dev-python/cython[${PYTHON_USEDEP}]"
38 RDEPEND="${CDEPEND}
39 >=app-mobilephone/obex-data-server-0.4.4
40 sys-apps/dbus
41 x11-themes/hicolor-icon-theme
42 gconf? ( dev-python/gconf-python[${PYTHON_USEDEP}] )
43 gnome? ( gnome-base/nautilus )
44 network? ( || ( net-dns/dnsmasq
45 net-misc/dhcp
46 >=net-misc/networkmanager-0.8 ) )
47 policykit? ( sys-auth/polkit )
48 pulseaudio? ( media-sound/pulseaudio )
49 !net-wireless/gnome-bluetooth
50 x11-themes/gnome-icon-theme
51 thunar? ( xfce-base/thunar )
52 "
53 # See bug 455320 and https://github.com/blueman-project/blueman/issues/112 for reason for gnome-icon-theme dep
54
55 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
56
57 src_prepare() {
58 sed -i \
59 -e '/^Encoding/d' \
60 data/blueman-manager.desktop.in || die "sed failed"
61
62 epatch \
63 "${FILESDIR}/${PN}-9999-plugins-conf-file.patch" \
64 "${FILESDIR}/${P}-set-codeset-for-gettext-to-UTF-8-always.patch"
65 eautoreconf
66 }
67
68 src_configure() {
69 econf \
70 --disable-static \
71 $(use_enable policykit polkit) \
72 $(use_enable gnome nautilus-sendto) \
73 $(use_enable nls) \
74 $(use_enable thunar thunar-sendto)
75 }
76
77 src_install() {
78 default
79
80 python_fix_shebang "${D}"
81
82 rm "${D}"/$(python_get_sitedir)/*.la || die
83 use gnome && { rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la || die; }
84
85 # Note: Python 3 support would need __pycache__ file removal too
86 use gconf || { rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py* || die; }
87 use policykit || { rm -rf "${D}"/usr/share/polkit-1 || die; }
88 use pulseaudio || { rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py*,plugins/manager/Pulse*.py*} || die; }
89 }
90
91 pkg_preinst() {
92 gnome2_icon_savelist
93 }
94
95 pkg_postinst() {
96 gnome2_icon_cache_update
97 }
98
99 pkg_postrm() {
100 gnome2_icon_cache_update
101 }

  ViewVC Help
Powered by ViewVC 1.1.20