/[gentoo-x86]/sci-libs/gsl/gsl-1.15.ebuild
Gentoo

Contents of /sci-libs/gsl/gsl-1.15.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.9 - (show annotations) (download)
Mon Aug 3 23:04:24 2015 UTC (4 years, 5 months ago) by mrueg
Branch: MAIN
CVS Tags: HEAD
Changes since 1.8: +1 -1 lines
FILE REMOVED
Remove old.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key )

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sci-libs/gsl/gsl-1.15.ebuild,v 1.8 2015/04/29 06:35:06 patrick Exp $
4
5 EAPI=4
6
7 inherit eutils flag-o-matic autotools toolchain-funcs
8
9 DESCRIPTION="The GNU Scientific Library"
10 HOMEPAGE="http://www.gnu.org/software/gsl/"
11 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
12
13 LICENSE="GPL-3"
14 SLOT="0"
15 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x86-solaris"
16 IUSE="cblas-external static-libs"
17
18 RDEPEND="cblas-external? ( virtual/cblas )"
19 DEPEND="${RDEPEND}
20 app-eselect/eselect-cblas
21 virtual/pkgconfig"
22
23 DOCS=( AUTHORS BUGS ChangeLog NEWS README THANKS TODO )
24
25 pkg_pretend() {
26 # prevent to use external cblas from a previously installed gsl
27 local current_lib
28 if use cblas-external; then
29 current_lib=$(eselect cblas show | cut -d' ' -f2)
30 if [[ ${current_lib} == gsl ]]; then
31 ewarn "USE flag cblas-external is set: linking gsl with an external cblas."
32 ewarn "However the current selected external cblas is gsl."
33 ewarn "Please install and/or eselect another cblas"
34 die "Circular gsl dependency"
35 fi
36 fi
37 }
38
39 src_prepare() {
40 ESELECT_PROF="gsl"
41
42 # bug 349005
43 [[ $(tc-getCC)$ == *gcc* ]] && \
44 [[ $(tc-getCC)$ != *apple* ]] && \
45 [[ $(gcc-major-version)$(gcc-minor-version) -eq 44 ]] \
46 && filter-mfpmath sse
47 filter-flags -ffast-math
48
49 epatch "${FILESDIR}"/${P}-cblas.patch
50 eautoreconf
51
52 cp "${FILESDIR}"/eselect.cblas.gsl "${T}"/
53 sed -i -e "s:/usr:${EPREFIX}/usr:" "${T}"/eselect.cblas.gsl || die
54 if [[ ${CHOST} == *-darwin* ]] ; then
55 sed -i -e 's/\.so\([\.0-9]\+\)\?/\1.dylib/g' \
56 "${T}"/eselect.cblas.gsl || die
57 fi
58 }
59
60 src_configure() {
61 if use cblas-external; then
62 export CBLAS_LIBS="$($(tc-getPKG_CONFIG) --libs cblas)"
63 export CBLAS_CFLAGS="$($(tc-getPKG_CONFIG) --cflags cblas)"
64 fi
65 econf \
66 --enable-shared \
67 $(use_with cblas-external cblas) \
68 $(use_enable static-libs static)
69 }
70
71 src_install() {
72 default
73
74 find "${ED}" -name '*.la' -exec rm -f {} +
75
76 # take care of pkgconfig file for cblas implementation.
77 sed -e "s/@LIBDIR@/$(get_libdir)/" \
78 -e "s/@PV@/${PV}/" \
79 -e "/^prefix=/s:=:=${EPREFIX}:" \
80 -e "/^libdir=/s:=:=${EPREFIX}:" \
81 "${FILESDIR}"/cblas.pc.in > cblas.pc \
82 || die "sed cblas.pc failed"
83 insinto /usr/$(get_libdir)/blas/gsl
84 doins cblas.pc || die "installing cblas.pc failed"
85 eselect cblas add $(get_libdir) "${T}"/eselect.cblas.gsl \
86 ${ESELECT_PROF}
87 }
88
89 pkg_postinst() {
90 local p=cblas
91 local current_lib=$(eselect ${p} show | cut -d' ' -f2)
92 if [[ ${current_lib} == ${ESELECT_PROF} || -z ${current_lib} ]]; then
93 # work around eselect bug #189942
94 local configfile="${EROOT}"/etc/env.d/${p}/$(get_libdir)/config
95 [[ -e ${configfile} ]] && rm -f ${configfile}
96 eselect ${p} set ${ESELECT_PROF}
97 elog "${p} has been eselected to ${ESELECT_PROF}"
98 else
99 elog "Current eselected ${p} is ${current_lib}"
100 elog "To use ${p} ${ESELECT_PROF} implementation, you have to issue (as root):"
101 elog "\t eselect ${p} set ${ESELECT_PROF}"
102 fi
103 }
104
105 src_test() {
106 emake -j1 check || die
107 }

  ViewVC Help
Powered by ViewVC 1.1.20