/[gentoo-x86]/sci-mathematics/flint/flint-2.4.4.ebuild
Gentoo

Contents of /sci-mathematics/flint/flint-2.4.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Jul 30 19:40:12 2014 UTC (6 years, 4 months ago) by hasufell
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +1 -1 lines
FILE REMOVED
fix deps wrt #518500

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key BDEED020)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sci-mathematics/flint/flint-2.4.4.ebuild,v 1.2 2014/07/02 11:10:57 hasufell Exp $
4
5 EAPI="5"
6
7 inherit eutils multilib toolchain-funcs
8
9 DESCRIPTION="Fast Library for Number Theory"
10 HOMEPAGE="http://www.flintlib.org/"
11 SRC_URI="http://www.flintlib.org/${P}.tar.gz"
12
13 RESTRICT="mirror"
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="doc gc ntl static-libs test"
18
19 RDEPEND="dev-libs/gmp
20 dev-libs/mpfr
21 gc? ( dev-libs/boehm-gc )
22 ntl? ( dev-libs/ntl )"
23 DEPEND="${RDEPEND}
24 doc? ( app-text/texlive-core )"
25
26 src_prepare() {
27 epatch "${FILESDIR}"/${PN}-2.4.3-libdir.patch \
28 "${FILESDIR}"/${PN}-2.4.3-whitespaces.patch \
29 "${FILESDIR}"/${PN}-2.4.3-cflags-ldflags.patch \
30 "${FILESDIR}"/${PN}-2.4.4-test.patch
31 }
32
33 src_configure() {
34 ./configure \
35 --prefix="${EPREFIX}/usr" \
36 --with-gmp="${EPREFIX}/usr" \
37 --with-mpfr="${EPREFIX}/usr" \
38 $(usex ntl "--with-ntl=${EPREFIX}/usr" "") \
39 $(use_enable static-libs static) \
40 $(usex gc "--with-gc=${EPREFIX}/usr" "") \
41 CC=$(tc-getCC) \
42 CXX=$(tc-getCXX) \
43 AR=$(tc-getAR) \
44 || die
45 }
46
47 src_compile() {
48 emake verbose
49
50 if use doc ; then
51 emake -C doc/latex
52 fi
53 }
54
55 src_test() {
56 emake AT= QUIET_CC= QUIET_CXX= QUIET_AR= check
57 }
58
59 src_install() {
60 emake DESTDIR="${D}" LIBDIR="$(get_libdir)" install
61 einstalldocs
62 use doc && dodoc doc/latex/flint-manual.pdf
63 }

  ViewVC Help
Powered by ViewVC 1.1.20