/[gentoo-x86]/sci-mathematics/glpk/glpk-4.54.ebuild
Gentoo

Contents of /sci-mathematics/glpk/glpk-4.54.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sun Feb 22 11:51:39 2015 UTC (5 years ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +3 -3 lines
Drop ~alpha because of a number of non-keyworded deps.

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sci-mathematics/glpk/glpk-4.54.ebuild,v 1.2 2014/09/01 16:41:18 mgorny Exp $
4
5 EAPI=5
6
7 AUTOTOOLS_AUTORECONF=1
8
9 inherit eutils flag-o-matic toolchain-funcs autotools-utils
10
11 DESCRIPTION="GNU Linear Programming Kit"
12 LICENSE="GPL-3"
13 HOMEPAGE="http://www.gnu.org/software/glpk/"
14 SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
15
16 SLOT="0/36"
17 IUSE="doc examples gmp odbc mysql static-libs"
18 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
19
20 RDEPEND="
21 sci-libs/amd:0=
22 sci-libs/colamd:=
23 sys-libs/zlib:0=
24 gmp? ( dev-libs/gmp:0= )
25 mysql? ( virtual/mysql )
26 odbc? ( || ( dev-db/libiodbc:0 dev-db/unixODBC:0 ) )"
27 DEPEND="${RDEPEND}
28 virtual/pkgconfig"
29
30 PATCHES=(
31 "${FILESDIR}"/${PN}-4.54-debundle-system-libs.patch
32 )
33
34 src_configure() {
35 local myeconfargs=(
36 $(use_enable mysql)
37 $(use_enable odbc)
38 $(use_with gmp)
39 )
40 if use mysql || use odbc; then
41 myeconfargs+=( --enable-dl )
42 else
43 myeconfargs+=( --disable-dl )
44 fi
45 [[ -z $(type -P odbc-config) ]] && \
46 append-cppflags $($(tc-getPKG_CONFIG) --cflags libiodbc)
47
48 autotools-utils_src_configure
49 }
50
51 src_install() {
52 autotools-utils_src_install
53 if use examples; then
54 insinto /usr/share/doc/${PF}
55 doins -r examples
56 docompress -x /usr/share/doc/${PF}/examples
57 fi
58 use doc && dodoc doc/*.pdf doc/notes/*.pdf doc/*.txt
59 }

  ViewVC Help
Powered by ViewVC 1.1.20