/[gentoo-x86]/sys-apps/proot/proot-3.2.2-r1.ebuild
Gentoo

Contents of /sys-apps/proot/proot-3.2.2-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sat Apr 26 06:59:16 2014 UTC (5 years, 9 months ago) by pinkbyte
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Stable on amd64 and x86, wrt bug #508394

(Portage version: 2.2.9-r1/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/proot-3.2.2-r1.ebuild,v 1.1 2014/03/11 08:13:00 pinkbyte Exp $
4
5 EAPI=5
6 MY_PN="PRoot"
7
8 inherit eutils pax-utils toolchain-funcs
9
10 DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
11 HOMEPAGE="http://proot.me"
12 SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="amd64 x86"
17 IUSE="care test"
18
19 RDEPEND="care? ( app-arch/libarchive:0= )
20 sys-libs/talloc"
21 DEPEND="${RDEPEND}
22 care? ( dev-libs/uthash )
23 test? ( dev-util/valgrind )"
24
25 # Breaks sandbox
26 RESTRICT="test"
27
28 S="${WORKDIR}/${MY_PN}-${PV}"
29
30 src_prepare() {
31 epatch "${FILESDIR}/${PN}-3.2.1-makefile.patch" \
32 "${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch" \
33 "${FILESDIR}/${P}-build-care.patch"
34 epatch_user
35 }
36
37 src_compile() {
38 # build the proot and care targets
39 emake -C src V=1 \
40 CC="$(tc-getCC)" \
41 CHECK_VERSION="true" \
42 CAREBUILDENV="ok" \
43 proot $(usex care "care" "" "" "")
44 }
45
46 src_install() {
47 if use care; then
48 # Workaround for bug #493416
49 pax-mark -Emp src/care
50 dobin src/care
51 fi
52 # Workaround for bug #493416
53 pax-mark -Emp src/proot
54
55 dobin src/proot
56 doman doc/proot.1
57 dodoc doc/*.txt doc/articles/*
58 }
59
60 src_test() {
61 emake -C tests -j1 CC="$(tc-getCC)"
62 }
63
64 pkg_postinst() {
65 if use care; then
66 elog "You have enabled 'care' USE flag, that builds and installs"
67 elog "dynamically linked care binary."
68 elog "Upstream does NOT support such way of building CARE,"
69 elog "it provides only prebuilt binaries."
70 elog "CARE also has known problems on hardened systems"
71 elog "Please do NOT file bugs about them to http://bugs.gentoo.org"
72 fi
73 }

  ViewVC Help
Powered by ViewVC 1.1.20