/[gentoo-x86]/sys-apps/proot/proot-4.0.0.ebuild
Gentoo

Contents of /sys-apps/proot/proot-4.0.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Tue Sep 2 07:07:02 2014 UTC (5 years, 4 months ago) by pinkbyte
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump, wrt bug #520050 with fix for bug #517496. Thanks to Joakim Tjernlund <Joakim.Tjernlund AT transmode.se> for discovering this issues. Drop old version

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/proot-4.0.0.ebuild,v 1.1 2014/07/23 12:46:07 pinkbyte Exp $
4
5 EAPI=5
6 MY_PN="PRoot"
7
8 inherit eutils toolchain-funcs
9
10 DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
11 HOMEPAGE="http://proot.me"
12 SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="care test"
18
19 RDEPEND="care? ( app-arch/libarchive:0= )
20 sys-libs/talloc"
21 DEPEND="${RDEPEND}
22 care? ( dev-libs/uthash )
23 test? ( dev-util/valgrind )"
24
25 # Breaks sandbox
26 RESTRICT="test"
27
28 S="${WORKDIR}/${MY_PN}-${PV}"
29
30 src_prepare() {
31 epatch "${FILESDIR}/${PN}-3.2.1-makefile.patch" \
32 "${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch" \
33 "${FILESDIR}/${PN}-3.2.2-build-care.patch"
34 epatch_user
35 }
36
37 src_compile() {
38 # build the proot and care targets
39 emake -C src V=1 \
40 CC="$(tc-getCC)" \
41 CHECK_VERSION="true" \
42 CAREBUILDENV="ok" \
43 proot $(use care && echo "care")
44 }
45
46 src_install() {
47 use care && dobin src/care
48 dobin src/proot
49 newman doc/proot/man.1 proot.1
50 dodoc doc/proot/*.txt
51 dodoc -r doc/articles
52 }
53
54 src_test() {
55 emake -C tests -j1 CC="$(tc-getCC)"
56 }
57
58 pkg_postinst() {
59 if use care; then
60 elog "You have enabled 'care' USE flag, that builds and installs"
61 elog "dynamically linked care binary."
62 elog "Upstream does NOT support such way of building CARE,"
63 elog "it provides only prebuilt binaries."
64 elog "CARE also has known problems on hardened systems"
65 elog "Please do NOT file bugs about them to http://bugs.gentoo.org"
66 fi
67 }

  ViewVC Help
Powered by ViewVC 1.1.20