/[gentoo-x86]/sys-apps/proot/proot-5.1.0.ebuild
Gentoo

Contents of /sys-apps/proot/proot-5.1.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Thu Jan 15 18:10:54 2015 UTC (5 years ago) by pinkbyte
Branch: MAIN
CVS Tags: HEAD
Version bump, wrt bug #530926, thanks to Joakim Tjernlund <Joakim.Tjernlund AT transmode.se>

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-apps/proot/proot-4.0.1.ebuild,v 1.1 2014/09/02 07:07:02 pinkbyte Exp $
4
5 EAPI=5
6 MY_PN="PRoot"
7
8 inherit eutils toolchain-funcs
9
10 DESCRIPTION="User-space implementation of chroot, mount --bind, and binfmt_misc"
11 HOMEPAGE="http://proot.me"
12 SRC_URI="https://github.com/cedric-vincent/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="~amd64 ~x86"
17 IUSE="care test"
18
19 RDEPEND="care? ( app-arch/libarchive:0= )
20 sys-libs/talloc"
21 DEPEND="${RDEPEND}
22 care? ( dev-libs/uthash )
23 test? ( dev-util/valgrind )"
24
25 # Breaks sandbox
26 RESTRICT="test"
27
28 S="${WORKDIR}/${MY_PN}-${PV}"
29
30 src_prepare() {
31 epatch "${FILESDIR}/${PN}-3.2.1-makefile.patch" \
32 "${FILESDIR}/${PN}-2.3.1-lib-paths-fix.patch"
33 epatch_user
34 }
35
36 src_compile() {
37 # build the proot and care targets
38 emake -C src V=1 \
39 CC="$(tc-getCC)" \
40 CHECK_VERSION="true" \
41 CAREBUILDENV="ok" \
42 proot $(use care && echo "care")
43 }
44
45 src_install() {
46 if use care; then
47 dobin src/care
48 dodoc doc/care/*.txt
49 fi
50 dobin src/proot
51 newman doc/proot/man.1 proot.1
52 dodoc doc/proot/*.txt
53 dodoc -r doc/articles
54 }
55
56 src_test() {
57 emake -C tests -j1 CC="$(tc-getCC)"
58 }
59
60 pkg_postinst() {
61 if use care; then
62 elog "You have enabled 'care' USE flag, that builds and installs"
63 elog "dynamically linked care binary."
64 elog "Upstream does NOT support such way of building CARE,"
65 elog "it provides only prebuilt binaries."
66 elog "CARE also has known problems on hardened systems"
67 elog "Please do NOT file bugs about them to http://bugs.gentoo.org"
68 fi
69 }

  ViewVC Help
Powered by ViewVC 1.1.20