/[gentoo-x86]/sys-cluster/galera/galera-25.3.5.ebuild
Gentoo

Contents of /sys-cluster/galera/galera-25.3.5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Fri Oct 31 22:06:10 2014 UTC (6 years, 1 month ago) by grknight
Branch: MAIN
Changes since 1.2: +2 -2 lines
Refine enewuser command and remove bashisms;  Thanks to dcmwai in IRC for feedback

(Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-cluster/galera/galera-25.3.5.ebuild,v 1.2 2014/10/31 20:33:34 grknight Exp $
4
5 EAPI=5
6
7 MY_P="${PN}-${PV}-src"
8
9 inherit scons-utils multilib toolchain-funcs base versionator eutils user
10 DESCRIPTION="Synchronous multi-master replication engine that provides its service through wsrep API"
11 HOMEPAGE="http://www.codership.org/"
12 SRC_URI="https://launchpad.net/${PN}/$(get_version_component_range 2).x/${PV}/+download/${MY_P}.tar.gz"
13 LICENSE="GPL-2 BSD"
14
15 SLOT="0"
16
17 KEYWORDS="~amd64 ~x86"
18 IUSE="garbd ssl test"
19
20 CDEPEND="
21 ssl? ( dev-libs/openssl )
22 >=dev-libs/boost-1.41
23 "
24 DEPEND="${DEPEND}
25 ${CDEPEND}
26 dev-libs/check
27 >=sys-devel/gcc-4.4
28 >=dev-cpp/asio-1.4.8[ssl?]
29 "
30 #Run time only
31 RDEPEND="${CDEPEND}
32 garbd? ( || (
33 net-analyzer/netcat
34 net-analyzer/netcat6
35 net-analyzer/gnu-netcat
36 net-analyzer/openbsd-netcat
37 ) )"
38
39 S="${WORKDIR}/${MY_P}"
40
41 pkg_preinst() {
42 if use garbd ; then
43 enewgroup garbd
44 enewuser garbd -1 -1 -1 garbd
45 fi
46 }
47
48 src_prepare() {
49 # Remove bundled dev-cpp/asio
50 rm -r "${S}/asio" || die
51
52 # Respect {C,LD}FLAGS.
53 epatch "${FILESDIR}/respect-flags.patch"
54
55 #Remove optional garbd daemon
56 if ! use garbd ; then
57 rm -r "${S}/garb" || die
58 fi
59
60 epatch_user
61 }
62
63 src_configure() {
64 tc-export CC CXX
65 # strict_build_flags=0 disables -Werror, -pedantic, -Weffc++,
66 # and -Wold-style-cast
67 myesconsargs=(
68 $(use_scons ssl ssl 1 0)
69 $(use_scons test tests 1 0)
70 strict_build_flags=0
71 )
72 }
73
74 src_compile() {
75 escons --warn=no-missing-sconscript
76 }
77
78 src_install() {
79 dodoc scripts/packages/README scripts/packages/README-MySQL
80 if use garbd ; then
81 dobin garb/garbd
82 newconfd "${FILESDIR}/garb.cnf" garbd
83 newinitd "${FILESDIR}/garb.sh" garbd
84 fi
85 exeinto /usr/$(get_libdir)/${PN}
86 doexe libgalera_smm.so
87 }

  ViewVC Help
Powered by ViewVC 1.1.20