/[gentoo-x86]/sys-libs/libapparmor/libapparmor-2.8.4.ebuild
Gentoo

Contents of /sys-libs/libapparmor/libapparmor-2.8.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Sun Nov 9 21:52:31 2014 UTC (5 years, 2 months ago) by dilfridge
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +2 -2 lines
Replace perlinfo with perl_set_version

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-libs/libapparmor/libapparmor-2.8.4.ebuild,v 1.1 2014/10/15 15:33:29 kensington Exp $
4
5 EAPI=5
6
7 AUTOTOOLS_AUTORECONF=1
8 DISTUTILS_OPTIONAL=1
9 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
10 GENTOO_DEPEND_ON_PERL="no"
11
12 inherit autotools-utils distutils-r1 perl-module versionator
13
14 DESCRIPTION="Library to support AppArmor userspace utilities"
15 HOMEPAGE="http://apparmor.net/"
16 SRC_URI="http://launchpad.net/apparmor/$(get_version_component_range 1-2)/${PV}/+download/apparmor-${PV}.tar.gz"
17
18 LICENSE="LGPL-2.1"
19 SLOT="0"
20 KEYWORDS="~amd64 ~x86"
21 IUSE="doc +perl python static-libs"
22
23 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
24
25 RDEPEND="perl? ( dev-lang/perl:= )
26 python? ( ${PYTHON_DEPS} )"
27
28 DEPEND="${RDEPEND}
29 sys-devel/autoconf-archive
30 sys-devel/bison
31 sys-devel/flex
32 doc? ( dev-lang/perl )
33 perl? ( dev-lang/swig )
34 python? ( dev-lang/swig )"
35
36 S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
37
38 src_prepare() {
39 rm -r m4 || die "failed to remove bundled macros"
40
41 autotools-utils_src_prepare
42 use python && distutils-r1_src_prepare
43 }
44
45 src_configure() {
46 local myeconfargs=(
47 $(use_with perl) \
48 $(use_with python)
49 )
50
51 autotools-utils_src_configure
52 }
53
54 src_compile() {
55 autotools-utils_src_compile -C src
56
57 use doc && autotools-utils_src_compile -C doc
58 use perl && autotools-utils_src_compile -C swig/perl
59
60 if use python ; then
61 pushd "${BUILD_DIR}"/swig/python > /dev/null
62 emake libapparmor_wrap.c
63 distutils-r1_src_compile
64 popd > /dev/null
65 fi
66 }
67
68 src_install() {
69 autotools-utils_src_install -C src
70 use doc && autotools-utils_src_install -C doc
71
72 if use perl ; then
73 autotools-utils_src_install -C swig/perl
74 perl_set_version
75 insinto "${VENDOR_ARCH}"
76 doins "${BUILD_DIR}"/swig/perl/LibAppArmor.pm
77 fi
78
79 if use python ; then
80 pushd "${BUILD_DIR}"/swig/python > /dev/null
81 distutils-r1_src_install
82 popd > /dev/null
83 fi
84 }

  ViewVC Help
Powered by ViewVC 1.1.20