/[gentoo-x86]/sys-power/pm-utils/pm-utils-1.4.1-r6.ebuild
Gentoo

Contents of /sys-power/pm-utils/pm-utils-1.4.1-r6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.6 - (show annotations) (download)
Sat Nov 8 18:56:02 2014 UTC (5 years, 3 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.5: +2 -2 lines
ia64 stable wrt #520110

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/sys-power/pm-utils/pm-utils-1.4.1-r6.ebuild,v 1.5 2014/09/26 11:40:37 klausman Exp $
4
5 EAPI=5
6 inherit eutils multilib
7
8 DESCRIPTION="Suspend and hibernation utilities"
9 HOMEPAGE="http://pm-utils.freedesktop.org/"
10 SRC_URI="http://pm-utils.freedesktop.org/releases/${P}.tar.gz"
11
12 LICENSE="GPL-2"
13 SLOT="0"
14 KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sparc x86"
15 IUSE="alsa debug ntp video_cards_intel video_cards_radeon"
16
17 vbetool="!video_cards_intel? ( sys-apps/vbetool )"
18 RDEPEND="!<app-laptop/laptop-mode-tools-1.55-r1
19 !sys-power/powermgmt-base[-pm-utils(+)]
20 sys-apps/dbus
21 >=sys-apps/util-linux-2.13
22 sys-power/pm-quirks
23 alsa? ( media-sound/alsa-utils )
24 ntp? ( || ( net-misc/ntp net-misc/openntpd ) )
25 amd64? ( ${vbetool} )
26 x86? ( ${vbetool} )
27 video_cards_radeon? ( app-laptop/radeontool )"
28 DEPEND="${RDEPEND}"
29
30 DOCS="AUTHORS ChangeLog NEWS pm/HOWTO* README* TODO"
31
32 src_prepare() {
33 local ignore="01grub"
34 use ntp || ignore+=" 90clock"
35
36 use debug && echo 'PM_DEBUG="true"' > "${T}"/gentoo
37 echo "HOOK_BLACKLIST=\"${ignore}\"" >> "${T}"/gentoo
38
39 epatch \
40 "${FILESDIR}"/${PV}-bluetooth-sync.patch \
41 "${FILESDIR}"/${PV}-disable-sata-alpm.patch \
42 "${FILESDIR}"/${PV}-fix-intel-audio-powersave-hook.patch \
43 "${FILESDIR}"/${PV}-logging-append.patch \
44 "${FILESDIR}"/${PV}-fix-alpm-typo.patch \
45 "${FILESDIR}"/${PV}-inhibit-on-right-status.patch \
46 "${FILESDIR}"/${PV}-ignore-led-failure.patch \
47 "${FILESDIR}"/${PV}-run-hook-logging.patch \
48 "${FILESDIR}"/${PV}-suspend-hybrid.patch \
49 "${FILESDIR}"/${PV}-uswsusp-hibernate-mode.patch \
50 "${FILESDIR}"/${PV}-xfs_buffer_arguments.patch
51 }
52
53 src_configure() {
54 econf --disable-doc
55 }
56
57 src_install() {
58 default
59 doman man/*.{1,8}
60
61 # Remove duplicate documentation install
62 rm -r "${ED}"/usr/share/doc/${PN}
63
64 insinto /etc/pm/config.d
65 doins "${T}"/gentoo
66
67 insinto /etc/logrotate.d
68 newins "${FILESDIR}"/${PN}.logrotate ${PN} #408091
69
70 exeinto /usr/$(get_libdir)/${PN}/sleep.d
71 doexe "${FILESDIR}"/sleep.d/50unload_alx
72
73 exeinto /usr/$(get_libdir)/${PN}/power.d
74 doexe "${FILESDIR}"/power.d/{pci_devices,usb_bluetooth}
75
76 # No longer required with current networkmanager (rm -f from debian/rules)
77 rm -f "${ED}"/usr/$(get_libdir)/${PN}/sleep.d/55NetworkManager
78
79 # No longer required with current kernels (rm -f from debian/rules)
80 rm -f "${ED}"/usr/$(get_libdir)/${PN}/sleep.d/49bluetooth
81
82 # Punt HAL related file wrt #401257 (rm -f from debian/rules)
83 rm -f "${ED}"/usr/$(get_libdir)/${PN}/power.d/hal-cd-polling
84
85 # Punt hooks which have shown to not reduce, or even increase power usage
86 # (rm -f from debian rules)
87 rm -f "${ED}"/usr/$(get_libdir)/${PN}/power.d/{journal-commit,readahead}
88
89 # Remove hooks which are not stable enough yet (rm -f from debian/rules)
90 rm -f "${ED}"/usr/$(get_libdir)/${PN}/power.d/harddrive
91
92 # Change to executable (chmod +x from debian/rules)
93 fperms +x /usr/$(get_libdir)/${PN}/defaults
94 }

  ViewVC Help
Powered by ViewVC 1.1.20