/[gentoo-x86]/www-apps/davical/davical-1.1.0-r1.ebuild
Gentoo

Contents of /www-apps/davical/davical-1.1.0-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat May 2 03:12:18 2015 UTC (5 years, 2 months ago) by grknight
Branch: MAIN
CVS Tags: HEAD
Revbump to update EAPI, fix DEPEND and eliminate the unnecessary re-building of the documentation which is present in the archive

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0xD1F781EFF9F4A3B6)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: $
4
5 EAPI=5
6
7 inherit depend.php webapp
8
9 DESCRIPTION="A CalDAV and CardDAV Server"
10 HOMEPAGE="http://davical.org/"
11 SRC_URI="http://debian.mcmillan.net.nz/packages/${PN}/${P}.tar.gz"
12
13 LICENSE="GPL-2"
14 KEYWORDS="~amd64 ~x86"
15 IUSE="doc"
16
17 DEPEND="
18 >=dev-php/awl-0.51
19 sys-devel/gettext
20 "
21 RDEPEND="app-admin/pwgen
22 dev-lang/php:*[calendar,curl,pdo,postgres,xml]
23 dev-perl/DBI
24 dev-perl/DBD-Pg
25 dev-perl/yaml
26 >=dev-php/awl-0.51
27 www-servers/apache"
28
29 need_php5
30 need_httpd
31
32 src_prepare() {
33 epatch "${FILESDIR}/awl_location.patch"
34 epatch "${FILESDIR}/inc_path.patch"
35 }
36
37 src_compile() {
38 emake built-po
39 }
40
41 src_install() {
42 webapp_src_preinst
43
44 dodoc-php INSTALL README debian/README.Debian \
45 testing/README.regression_tests TODO debian/changelog
46
47 einfo "Installing web files"
48 insinto "${MY_HTDOCSDIR}"
49 doins -r htdocs/* htdocs/.htaccess
50
51 einfo "Installing main files and i18n"
52 insinto "${MY_HOSTROOTDIR}/${PN}"
53 doins -r inc locale
54 rm "${D}/${MY_HOSTROOTDIR}/${PN}/inc/always.php.in" || die
55
56 einfo "Installing sql files"
57 insinto "${MY_SQLSCRIPTSDIR}"
58 doins -r dba/*
59
60 if use doc ; then
61 einfo "Installing documentation"
62 dohtml -r docs/api/ docs/website/
63 fi
64
65 insinto /etc/${PN}
66 doins config/* "${FILESDIR}/vhost-example"
67
68 webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"
69 webapp_src_install
70
71 fperms +x "${MY_SQLSCRIPTSDIR}/create-database.sh"
72 fperms +x "${MY_SQLSCRIPTSDIR}/update-davical-database"
73 }

  ViewVC Help
Powered by ViewVC 1.1.20