/[gentoo-x86]/www-apps/wordpress/wordpress-4.2.4.ebuild
Gentoo

Contents of /www-apps/wordpress/wordpress-4.2.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Tue Aug 4 23:32:04 2015 UTC (4 years, 11 months ago) by jmbsvicetto
Branch: MAIN
CVS Tags: HEAD
Bump wordpress to 4.2.4 release and drop vulnerable versions - CVE-2015-{2213,5730,5731,5732,5733,5734}.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key BB0E6E98)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/www-apps/wordpress/wordpress-4.2.2.ebuild,v 1.1 2015/05/08 17:10:33 sping Exp $
4
5 EAPI=5
6
7 inherit webapp
8
9 DESCRIPTION="Wordpress PHP and MySQL based content management system (CMS)"
10 HOMEPAGE="https://wordpress.org/"
11 SRC_URI="https://wordpress.org/${P/_rc/-RC}.tar.gz"
12
13 LICENSE="GPL-2+"
14 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
15
16 RDEPEND="virtual/httpd-php
17 || ( dev-lang/php[mysql] dev-lang/php[mysqli] )"
18
19 S=${WORKDIR}/${PN}
20
21 need_httpd_cgi
22
23 IUSE="+akismet examples +themes vhosts"
24
25 # Override default of SLOT="${PVR}"
26 WEBAPP_MANUAL_SLOT=yes
27 SLOT="${PV}"
28
29 src_install() {
30 webapp_src_preinst
31
32 dohtml readme.html
33 rm readme.html license.txt || die
34
35 if ! use akismet ; then
36 rm -R wp-content/plugins/akismet/ || die
37 fi
38 if ! use examples ; then
39 rm wp-content/plugins/hello.php || die
40 fi
41 if ! use themes ; then
42 rm -R wp-content/themes/*/ || die
43 fi
44
45 [[ -f wp-config.php ]] || cp wp-config-sample.php wp-config.php
46
47 insinto "${MY_HTDOCSDIR}"
48 doins -r .
49
50 webapp_serverowned "${MY_HTDOCSDIR}"/index.php
51 webapp_serverowned "${MY_HTDOCSDIR}"/wp-admin/menu.php
52 webapp_serverowned "${MY_HTDOCSDIR}"
53
54 webapp_configfile "${MY_HTDOCSDIR}"/wp-config.php
55
56 webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
57 webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt
58
59 webapp_src_install
60 }

  ViewVC Help
Powered by ViewVC 1.1.20