/[gentoo-x86]/www-client/links/links-2.7.ebuild
Gentoo

Contents of /www-client/links/links-2.7.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.11 - (show annotations) (download)
Wed Apr 24 19:35:29 2013 UTC (5 years, 3 months ago) by ssuominen
Branch: MAIN
Changes since 1.10: +11 -5 lines
Remove broken 045e.png from the tarball wrt #466190#c12. Use AC_CONFIG_HEADERS instead of obsolete AM_CONFIG_HEADER wrt #467020 by Alphat-PC

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/www-client/links/links-2.7.ebuild,v 1.10 2012/09/24 18:44:31 armin76 Exp $
4
5 EAPI=5
6 inherit autotools eutils fdo-mime
7
8 DEBIAN_REVISION=2.7-1
9
10 DESCRIPTION="A fast and lightweight web browser running in both graphics and text mode"
11 HOMEPAGE="http://links.twibright.com/"
12 SRC_URI="http://${PN}.twibright.com/download/${P}.tar.bz2
13 mirror://debian/pool/main/${PN:0:1}/${PN}2/${PN}2_${DEBIAN_REVISION}.debian.tar.gz"
14
15 LICENSE="GPL-2"
16 SLOT="2"
17 KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
18 IUSE="bzip2 +deprecated directfb fbcon gpm jpeg livecd lzma ssl suid svga tiff unicode X zlib"
19
20 GRAPHICS_DEPEND="media-libs/libpng:0="
21
22 RDEPEND=">=sys-libs/ncurses-5.7-r7
23 bzip2? ( app-arch/bzip2 )
24 directfb? (
25 ${GRAPHICS_DEPEND}
26 dev-libs/DirectFB
27 )
28 fbcon? ( ${GRAPHICS_DEPEND} )
29 gpm? ( sys-libs/gpm )
30 jpeg? ( virtual/jpeg )
31 livecd? (
32 ${GRAPHICS_DEPEND}
33 sys-libs/gpm
34 virtual/jpeg
35 )
36 lzma? ( app-arch/xz-utils )
37 ssl? ( dev-libs/openssl:0 )
38 svga? (
39 ${GRAPHICS_DEPEND}
40 media-libs/svgalib
41 )
42 tiff? ( media-libs/tiff:0 )
43 X? (
44 ${GRAPHICS_DEPEND}
45 x11-libs/libXext
46 )
47 zlib? ( sys-libs/zlib )"
48
49 DEPEND="${RDEPEND}
50 virtual/pkgconfig
51 fbcon? ( virtual/os-headers )
52 livecd? ( virtual/os-headers )"
53
54 REQUIRED_USE="!livecd? ( fbcon? ( gpm ) )
55 svga? ( suid )"
56
57 DOCS=( AUTHORS BRAILLE_HOWTO ChangeLog KEYS NEWS README SITES )
58
59 src_prepare() {
60 epatch "${WORKDIR}"/debian/patches/verify-ssl-certs-510417.diff
61
62 if use unicode; then
63 pushd intl >/dev/null
64 ./gen-intl || die
65 ./synclang || die
66 popd >/dev/null
67 fi
68
69 # error: conditional "am__fastdepCXX" was never defined (for eautoreconf)
70 sed -i \
71 -e '/AC_PROG_CXX/s:#::' \
72 -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' \
73 configure.in || die #467020
74
75 # This image file has bogus distance in IDAT information wrt #466190#c12
76 rm -f graphics/font/century_school-medium-roman-serif-vari/045e.png
77
78 # Upstream configure produced by broken autoconf-2.13. This also fixes
79 # toolchain detection.
80 eautoreconf #131440 and #103483#c23
81 }
82
83 src_configure() {
84 local myconf
85
86 if use livecd; then
87 export ac_cv_lib_gpm_Gpm_Open=yes
88 myconf+=' --with-fb --with-libjpeg'
89 else
90 export ac_cv_lib_gpm_Gpm_Open=$(usex gpm)
91 fi
92
93 if use X || use fbcon || use directfb || use svga || use livecd; then
94 myconf+=' --enable-graphics'
95 fi
96
97 econf \
98 $(use_with ssl) \
99 $(use_with zlib) \
100 $(use_with bzip2) \
101 $(use_with lzma) \
102 $(use_with svga svgalib) \
103 $(use_with X x) \
104 $(use_with fbcon fb) \
105 $(use_with directfb) \
106 $(use_with jpeg libjpeg) \
107 $(use_with tiff libtiff) \
108 ${myconf}
109 }
110
111 src_install() {
112 default
113
114 if use X; then
115 newicon Links_logo.png links.png
116 make_desktop_entry 'links -g %u' Links links 'Network;WebBrowser'
117 local d="${ED}"/usr/share/applications
118 echo 'MimeType=x-scheme-handler/http;' >> "${d}"/*.desktop
119 use ssl && sed -i -e 's:x-scheme-handler/http;:&x-scheme-handler/https;:' \
120 "${d}"/*.desktop
121 fi
122
123 nonfatal dohtml doc/links_cal/*
124 use deprecated && dosym links /usr/bin/links2
125 use suid && fperms 4755 /usr/bin/links
126 }
127
128 pkg_postinst() {
129 use X && fdo-mime_desktop_database_update
130 }
131
132 pkg_postrm() {
133 use X && fdo-mime_desktop_database_update
134 }

  ViewVC Help
Powered by ViewVC 1.1.20