/[gentoo-x86]/xfce-base/thunar/thunar-1.1.2.ebuild
Gentoo

Contents of /xfce-base/thunar/thunar-1.1.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sun Sep 5 20:26:24 2010 UTC (9 years, 7 months ago) by ssuominen
Branch: MAIN
Version bump.

(Portage version: 2.2_rc75/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.1.1.ebuild,v 1.6 2010/08/23 22:34:39 ssuominen Exp $
4
5 EAPI=3
6 inherit virtualx xfconf
7
8 MY_P=${P/t/T}
9
10 DESCRIPTION="File manager for Xfce4"
11 HOMEPAGE="http://thunar.xfce.org/"
12 SRC_URI="mirror://xfce/src/xfce/${PN}/1.1/${MY_P}.tar.bz2"
13
14 LICENSE="GPL-2 LGPL-2"
15 SLOT="0"
16 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
17 IUSE="dbus debug exif libnotify pcre startup-notification test xfce_plugins_trash udev"
18
19 COMMON_DEPEND=">=xfce-base/exo-0.5.3
20 >=dev-libs/glib-2.18:2
21 >=x11-libs/gtk+-2.14:2
22 >=xfce-base/libxfce4util-4.6
23 >=xfce-base/libxfce4ui-4.7.1
24 >=dev-lang/perl-5.6
25 dbus? ( dev-libs/dbus-glib )
26 exif? ( >=media-libs/libexif-0.6.19 )
27 libnotify? ( x11-libs/libnotify )
28 pcre? ( >=dev-libs/libpcre-6 )
29 startup-notification? ( x11-libs/startup-notification )
30 xfce_plugins_trash? ( dev-libs/dbus-glib
31 >=xfce-base/xfce4-panel-4.3.90 )
32 udev? ( >=sys-fs/udev-145[extras] )"
33 RDEPEND="${COMMON_DEPEND}
34 >=x11-misc/shared-mime-info-0.71
35 >=dev-util/desktop-file-utils-0.16
36 udev? ( >=gnome-base/gvfs-1.6.3[gdu,udev] )"
37 DEPEND="${COMMON_DEPEND}
38 dev-util/intltool
39 dev-util/pkgconfig
40 sys-devel/gettext"
41
42 S=${WORKDIR}/${MY_P}
43
44 pkg_setup() {
45 XFCONF="--docdir=${EPREFIX}/usr/share/doc/${PF}
46 --disable-dependency-tracking
47 $(use_enable dbus)
48 $(use_enable startup-notification)
49 $(use_enable udev gudev)
50 $(use_enable libnotify notifications)
51 $(use_enable debug)
52 $(use_enable exif)
53 $(use_enable pcre)
54 --with-html-dir=${EPREFIX}/usr/share/doc/${PF}/html"
55
56 if use xfce_plugins_trash; then
57 XFCONF="${XFCONF} --enable-dbus"
58 else
59 XFCONF="${XFCONF} --disable-tpa-plugin"
60 fi
61
62 DOCS="AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO"
63 }
64
65 src_test() {
66 Xemake check || die
67 }
68
69 pkg_postinst() {
70 xfconf_pkg_postinst
71
72 echo
73 elog "If you are seeing some odd dbus error, make sure your user is in the"
74 elog "plugdev group. See Gentoo bug #279077 for more info"
75 echo
76 }

  ViewVC Help
Powered by ViewVC 1.1.20