/[gentoo-x86]/xfce-base/thunar/thunar-1.4.0.ebuild
Gentoo

Contents of /xfce-base/thunar/thunar-1.4.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.12 - (show annotations) (download)
Sun May 5 17:02:44 2013 UTC (6 years, 9 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.11: +1 -1 lines
FILE REMOVED
Version bump, drop old

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/xfce-base/thunar/thunar-1.4.0.ebuild,v 1.11 2012/12/02 22:15:33 ssuominen Exp $
4
5 EAPI=5
6 inherit virtualx xfconf
7
8 MY_P=${P/t/T}
9
10 DESCRIPTION="File manager for the Xfce desktop environment"
11 HOMEPAGE="http://www.xfce.org/projects/ http://thunar.xfce.org/"
12 SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${MY_P}.tar.bz2"
13
14 LICENSE="GPL-2 LGPL-2"
15 SLOT="0"
16 KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sparc x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
17 IUSE="+dbus debug exif libnotify pcre startup-notification test +xfce_plugins_trash udev"
18
19 GVFS_DEPEND=">=gnome-base/gvfs-1.10.1"
20 COMMON_DEPEND=">=dev-lang/perl-5.6
21 >=dev-libs/glib-2.24
22 >=x11-libs/gtk+-2.20:2
23 >=xfce-base/exo-0.8
24 >=xfce-base/libxfce4ui-4.10
25 >=xfce-base/libxfce4util-4.10
26 dbus? ( >=dev-libs/dbus-glib-0.98 )
27 exif? ( >=media-libs/libexif-0.6.19 )
28 libnotify? ( >=x11-libs/libnotify-0.7 )
29 pcre? ( >=dev-libs/libpcre-6 )
30 startup-notification? ( x11-libs/startup-notification )
31 udev? ( virtual/udev[gudev] )
32 xfce_plugins_trash? ( >=xfce-base/xfce4-panel-4.10 )"
33 RDEPEND="${COMMON_DEPEND}
34 >=dev-util/desktop-file-utils-0.20-r1
35 x11-misc/shared-mime-info
36 dbus? ( ${GVFS_DEPEND} )
37 udev? ( || ( ${GVFS_DEPEND}[udisks,udev] ${GVFS_DEPEND}[gdu,udev] ) )
38 xfce_plugins_trash? ( ${GVFS_DEPEND} )"
39 DEPEND="${COMMON_DEPEND}
40 dev-util/intltool
41 sys-devel/gettext
42 virtual/pkgconfig"
43 REQUIRED_USE="xfce_plugins_trash? ( dbus )"
44
45 S=${WORKDIR}/${MY_P}
46
47 pkg_setup() {
48 XFCONF=(
49 --docdir="${EPREFIX}"/usr/share/doc/${PF}
50 $(use_enable dbus)
51 $(use_enable startup-notification)
52 $(use_enable udev gudev)
53 $(use_enable libnotify notifications)
54 $(xfconf_use_debug)
55 $(use_enable exif)
56 $(use_enable pcre)
57 --with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
58 )
59
60 use xfce_plugins_trash || XFCONF+=( --disable-tpa-plugin )
61
62 DOCS=( AUTHORS ChangeLog FAQ HACKING NEWS README THANKS TODO )
63 }
64
65 src_test() {
66 Xemake check
67 }

  ViewVC Help
Powered by ViewVC 1.1.20