summaryrefslogtreecommitdiff
blob: 84e8276683349bcab53b9e90aa37187e471b1a5d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
AC_INIT([eselect-php], [0.9.7])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([-Wall foreign no-dist-gzip dist-xz tar-ustar])

AC_PROG_LN_S
AC_PROG_MKDIR_P
AC_PROG_SED
AC_PATH_PROG(SORT,sort)
AC_PATH_PROG(UNIQ,uniq)


# --enable-apache2 flag, disabled by default, that decides whether or
# not we install the apache2 module configuration file.
AC_ARG_ENABLE(
	[apache2],
	[  --enable-apache2    install the apache2 conf file [[default=no]]],
	[case "${enableval}" in
    yes) apache2=true ;;
    no)  apache2=false ;;
    *) AC_MSG_ERROR([bad value ${enableval} for --enable-apache2]) ;;
  esac],[apache2=false])
  AM_CONDITIONAL([APACHE2], [test x$apache2 = xtrue])

# --enable-fpm flag, disabled by default, that decides whether or
# not we install the php-fpm init script and config file.
AC_ARG_ENABLE(
	[fpm],
	[  --enable-fpm    install the php-fpm init script [[default=no]]],
	[case "${enableval}" in
    yes) fpm=true ;;
    no)  fpm=false ;;
    *) AC_MSG_ERROR([bad value ${enableval} for --enable-fpm]) ;;
  esac],[fpm=false])
  AM_CONDITIONAL([FPM], [test x$fpm = xtrue])

piddir=${piddir="@LOCALSTATEDIR@"}
AC_ARG_WITH(piddir, AC_HELP_STRING([--with-piddir=DIR],
	[where php-fpm PID files are placed [LOCALSTATEDIR]]),
	if test x$withval != x -a x$withval != xno -a x$withval != xyes; then
		piddir="$withval"
	fi)
AC_SUBST(piddir)

# List of output files.
AC_CONFIG_FILES([
  Makefile
  src/Makefile
  src/php.eselect.in
  openrc/conf.d/Makefile
  openrc/init.d/Makefile
  openrc/init.d/php-fpm.in
])

AC_OUTPUT