aboutsummaryrefslogtreecommitdiff
blob: c3501b22becd7fb56c7cf743a15c9e8fecb44c01 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit mate

if [[ ${PV} != 9999 ]]; then
	KEYWORDS="~amd64 ~arm ~x86"
fi

DESCRIPTION="A session daemon for MATE that makes it easy to manage your laptop or desktop"
LICENSE="GPL-2"
SLOT="0"

IUSE="+applet gnome-keyring pm-utils policykit systemd test"

# Interactive testsuite.
RESTRICT="test"

COMMON_DEPEND=">=dev-libs/dbus-glib-0.70:0
	>=dev-libs/glib-2.36:2
	>=media-libs/libcanberra-0.10:0[gtk3]
	>=sys-apps/dbus-1:0
	>=x11-apps/xrandr-1.3:0
	>=x11-libs/cairo-1:0
	>=x11-libs/gdk-pixbuf-2.11:2
	>=x11-libs/gtk+-3.14:3
	x11-libs/libX11:0
	x11-libs/libXext:0
	x11-libs/libXrandr:0
	>=x11-libs/libnotify-0.7:0
	x11-libs/pango:0
	applet? ( >=mate-base/mate-panel-1.17.0 )
	gnome-keyring? ( >=gnome-base/libgnome-keyring-3:0 )
	pm-utils? ( >=sys-power/upower-pm-utils-0.9.23 )
	!pm-utils? ( >=sys-power/upower-0.9.23:= )
	systemd? ( sys-apps/systemd )
	!systemd? ( >=sys-auth/consolekit-0.9.2 )"

RDEPEND="${COMMON_DEPEND}
	policykit? ( >=mate-extra/mate-polkit-1.6 )"

DEPEND="${COMMON_DEPEND}
	app-text/docbook-xml-dtd:4.3
	app-text/rarian:0
	>=app-text/scrollkeeper-dtd-1:1.0
	app-text/yelp-tools:0
	>=dev-util/intltool-0.50.1:*
	sys-devel/gettext:*
	virtual/pkgconfig:*
	x11-base/xorg-proto"

src_prepare() {
	eapply "${FILESDIR}/musl-fix-compile-execinfo.patch"
	eapply "${FILESDIR}/musl-fix-remove-backtrace.patch"
	eapply_user
}

src_configure() {
	mate_src_configure \
		--enable-compile-warnings=minimum \
		$(use_with gnome-keyring keyring) \
		$(use_enable applet applets) \
		$(use_enable test tests)
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS

	dbus-launch Xemake check || die "Test phase failed"
}