summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAlexys Jacob <ultrabug@gentoo.org>2015-03-23 09:02:35 +0000
committerAlexys Jacob <ultrabug@gentoo.org>2015-03-23 09:02:35 +0000
commit9d64c628afd2b531c1013eb4f79751a219e79ce1 (patch)
treee6146d34707b77a3f95974644ec4bb59d63ef668 /dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild
parentversion bump (diff)
downloadhistorical-9d64c628afd2b531c1013eb4f79751a219e79ce1.tar.gz
historical-9d64c628afd2b531c1013eb4f79751a219e79ce1.tar.bz2
historical-9d64c628afd2b531c1013eb4f79751a219e79ce1.zip
use system libbson fix #543984
Package-Manager: portage-2.2.18/cvs/Linux x86_64 Manifest-Sign-Key: 0xB658FA13
Diffstat (limited to 'dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild')
-rw-r--r--dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild65
1 files changed, 65 insertions, 0 deletions
diff --git a/dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild b/dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild
new file mode 100644
index 000000000000..b1c4e0d55be4
--- /dev/null
+++ b/dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/mongo-c-driver/mongo-c-driver-1.1.2-r1.ebuild,v 1.1 2015/03/23 09:02:26 ultrabug Exp $
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="A high-performance MongoDB driver for C"
+HOMEPAGE="https://github.com/mongodb/mongo-c-driver"
+SRC_URI="https://github.com/mongodb/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="debug examples sasl ssl static-libs test"
+
+RDEPEND=">=dev-libs/libbson-1.0
+ sasl? ( dev-libs/cyrus-sasl )
+ ssl? ( dev-libs/openssl:= )"
+DEPEND="${RDEPEND}
+ test? ( dev-db/mongodb )"
+
+DOCS=( NEWS README.rst TUTORIAL.md )
+
+src_prepare() {
+ # https://github.com/mongodb/mongo-c-driver/issues/54
+ sed -i -e "s/PTHREAD_LIBS/PTHREAD_CFLAGS/g" src/Makefile.am \
+ tests/Makefile.am || die
+ eautoreconf
+}
+
+src_configure() {
+ econf --with-libbson=system \
+ --disable-hardening \
+ --disable-optimizations \
+ --disable-examples \
+ $(use_enable sasl) \
+ $(use_enable ssl) \
+ $(use_enable debug) \
+ $(use_enable static-libs static)
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ doman doc/*.3
+
+ use static-libs || find "${D}" -name '*.la' -delete
+
+ if use examples; then
+ insinto /usr/share/${PF}/examples
+ doins -r examples/*.c examples/aggregation examples/bulk
+ fi
+}
+
+src_test() {
+ # Avoid allocating too much disk space by using server.smallFiles = 1
+ echo -e "storage:\n smallFiles: true" > "${T}/mongod.conf"
+ local PORT=27099
+ mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
+ -f "${T}/mongod.conf" --dbpath="${T}" \
+ --logpath="${T}/mongod.log" || die
+ MONGOC_TEST_HOST="127.0.0.1:${PORT}" emake test
+ kill `cat "${T}/mongod.lock"`
+}