summaryrefslogtreecommitdiff
blob: 4fb2cae5474a92775bddc050dca41d2b18e036a2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/librelp/librelp-1.2.7-r1.ebuild,v 1.2 2014/08/10 20:37:44 slyfox Exp $

EAPI=5

inherit autotools-utils

DESCRIPTION="An easy to use library for the RELP protocol"
HOMEPAGE="http://www.librelp.com/"
SRC_URI="http://download.rsyslog.com/${PN}/${P}.tar.gz"

LICENSE="GPL-3 doc? ( FDL-1.3 )"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~sparc ~x86"
IUSE="debug doc +ssl static-libs"

RDEPEND="
	ssl? ( >=net-libs/gnutls-2.12.23-r1 )
"

DEPEND="
	>=net-libs/gnutls-2.12.23-r1
	virtual/pkgconfig
"

AUTOTOOLS_IN_SOURCE_BUILD=1

PATCHES=( "${FILESDIR}/${P}-prevent-segfault-with-keepalive.patch" )

src_configure() {
	# gnutls-headers are always required (in src/tcp.h) despite the flag, bug #513754
	local myeconfargs=(
		$(use_enable debug)
		$(use_enable ssl tls)
	)

	autotools-utils_src_configure
}

src_install() {
	use doc && HTML_DOCS=( doc/relp.html )
	autotools-utils_src_install
}