summaryrefslogtreecommitdiff
blob: 524454d74feb2d1087989349dfab747f65c36d9a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/nanomsg/nanomsg-0.5-r1.ebuild,v 1.1 2015/01/30 08:38:10 pinkbyte Exp $

EAPI=5

AUTOTOOLS_AUTORECONF=1
inherit autotools-multilib

DESCRIPTION="High-performance messaging interface for distributed applications"
HOMEPAGE="http://nanomsg.org/"
SRC_URI="http://download.nanomsg.org/${P}-beta.tar.gz"

LICENSE="MIT"
SLOT="0/0.2.1"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~s390 ~x86"
IUSE="doc static-libs"

DEPEND="doc? (
		app-text/asciidoc
		app-text/xmlto
	)"
RDEPEND=""

S="${WORKDIR}/${P}-beta"

src_prepare() {
	sed -i -e 's/doc_DATA/html_DATA/' Makefile.am || die

	autotools-multilib_src_prepare
}

multilib_src_configure() {
	local myeconfargs=(
		--htmldir "/usr/share/doc/${PF}/html"
	)
	if multilib_is_native_abi; then
		myeconfargs+=(
			$(use_enable doc)
		)
	else
		myeconfargs+=(
			--disable-doc
			--disable-nanocat
			--disable-symlinks
		)
	fi
	autotools-utils_src_configure
}