summaryrefslogtreecommitdiff
blob: e02e2718216a86cd553f978d3ab30f25507e4c51 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-filter/libdkim/libdkim-1.0.21-r2.ebuild,v 1.3 2014/03/03 23:49:17 pacho Exp $

EAPI="5"

AUTOTOOLS_AUTORECONF=1
AUTOTOOLS_IN_SOURCE_BUILD=1

inherit autotools-utils eutils toolchain-funcs

DESCRIPTION="DomainKeys Identified Mail library from Alt-N Inc."
HOMEPAGE="http://libdkim.sourceforge.net"
SRC_URI="mirror://sourceforge/${PN}/${P}.zip"

LICENSE="Apache-2.0 yahoo-patent-license-1.2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="static-libs"

DEPEND="dev-libs/openssl
	app-arch/unzip"
RDEPEND="!mail-filter/libdkim-exim
	dev-libs/openssl"

S="${WORKDIR}/${PN}/src"

src_prepare() {
	ecvs_clean
	cp  "${FILESDIR}"/debianize/* "${S}"
	epatch "${FILESDIR}"/patches/*.patch
	epatch "${FILESDIR}"/libdkim-extra-options.patch

	# Bug 476772
	if ! use static-libs; then
		 sed -i \
			-e '/^TARGETS/s/libdkim.a//' \
			-e '/install -m 644 libdkim.a/d' \
			Makefile.in || die 'sed on Makefile.in failed'
	fi

	# Bug 476770
	tc-export AR

	autotools-utils_src_prepare
}

src_install() {
	autotools-utils_src_install
	dodoc ../README
}