aboutsummaryrefslogtreecommitdiff
blob: c7fff1106bb702fdb83494e671d35d857dc6470a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7
DESCRIPTION="A simple, lightweight C library for writing XMPP clients"
HOMEPAGE="http://strophe.im/libstrophe/"
SRC_URI="https://github.com/strophe/${PN}/releases/download/${PV}/${P}.tar.gz"
LICENSE="|| ( MIT GPL-3 )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc expat"

RDEPEND="
	expat? ( dev-libs/expat )
	!expat? ( dev-libs/libxml2:2 )
	dev-libs/openssl:0=
"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
"

DOCS=( ChangeLog )
PATCHES=( "${FILESDIR}/libstrophe-0.9.2-libressl.patch" )

src_configure() {
	# shellcheck disable=SC2207
	local myeconf=(
		--enable-tls
		$(use_with !expat libxml2)
	)
	econf "${myeconf[@]}"
}
src_compile() {
	default
	if use doc; then
		doxygen || die
		HTML_DOCS=( docs/html/* )
	fi
}

src_install() {
	default
	use doc && dodoc -r examples
	find "${D}" -name '*.la' -o -name '*.a' -delete || die
}

# Explicit src_test is there to document that the test suite is integrated and
# is expected to pass. Please do not remove.
src_test() {
	emake check
}