summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorIonen Wolkens <ionen@gentoo.org>2021-06-09 09:39:02 -0400
committerIonen Wolkens <ionen@gentoo.org>2021-06-10 07:51:42 -0400
commitdfffb12847f492c5e489ae5457890b8fc7c45d79 (patch)
tree4936f463df03d811643c9ed4a6a4ae71455d3906 /games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild
parentdev-games/t4k-common: svg, text, and build fix (diff)
downloadgentoo-dfffb12847f492c5e489ae5457890b8fc7c45d79.tar.gz
gentoo-dfffb12847f492c5e489ae5457890b8fc7c45d79.tar.bz2
gentoo-dfffb12847f492c5e489ae5457890b8fc7c45d79.zip
games-kids/tuxmath: EAPI-7, -fno-common, and crash fix
Two causes of crashes, mismatch with t4k-common is exposed by gcc10+ (blits-to-tmblits patch), and bug #763591 is fixed in >=t4k-common-0.1.1-r1 which now depend on. Thanks to Samuel Bauer for pointing out -fno-common fix Closes: https://bugs.gentoo.org/763591 Closes: https://bugs.gentoo.org/795069 Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
Diffstat (limited to 'games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild')
-rw-r--r--games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild62
1 files changed, 62 insertions, 0 deletions
diff --git a/games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild b/games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild
new file mode 100644
index 000000000000..fb3e676b0cf5
--- /dev/null
+++ b/games-kids/tuxmath/tuxmath-2.0.3-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop optfeature
+
+DESCRIPTION="Educational arcade game where you have to solve maths problems"
+HOMEPAGE="https://www.tux4kids.com/"
+SRC_URI="mirror://debian/pool/main/t/${PN}/${PN}_${PV}.orig.tar.gz"
+S="${WORKDIR}/${PN}_w_fonts-${PV}"
+
+LICENSE="CC-BY-SA-3.0 CC-PD GPL-3+ public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls svg"
+
+RDEPEND="
+ >=dev-games/t4k-common-0.1.1-r1[svg?]
+ dev-libs/libxml2:2
+ media-libs/libsdl[video]
+ media-libs/sdl-image[jpeg,png]
+ media-libs/sdl-mixer
+ media-libs/sdl-net
+ nls? ( virtual/libintl )"
+DEPEND="
+ ${RDEPEND}
+ svg? (
+ gnome-base/librsvg:2
+ x11-libs/cairo
+ )"
+BDEPEND="
+ virtual/pkgconfig
+ nls? ( sys-devel/gettext )"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-blits-to-tmblits.patch
+ "${FILESDIR}"/${P}-fno-common.patch
+)
+
+src_configure() {
+ local econfargs=(
+ $(use_enable nls)
+ $(usex svg '' --without-rsvg)
+ )
+ econf "${econfargs[@]}"
+}
+
+src_install() {
+ default
+
+ doicon data/images/icons/${PN}.svg
+ domenu ${PN}.desktop
+
+ # bundled fonts are unused if t4k-common uses pango
+ rm -r "${ED}"/usr/share/${PN}/fonts || die
+ rm "${ED}"/usr/share/doc/${PF}/{COPYING_GPL3,GPL_VERSIONS,INSTALL,OFL,README_DATA_LICENSES} || die
+}
+
+pkg_postinst() {
+ optfeature "music support" "media-libs/sdl-mixer[mod,vorbis]"
+}