/[gentoo-x86]/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild
Gentoo

Contents of /app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.16 - (show annotations) (download)
Mon Apr 28 17:19:43 2014 UTC (6 years, 2 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.15: +2 -2 lines
Replace multilib_build_binaries with multilib_is_native_abi. The two are equivalent now, and the team has decided to use the old name as being less confusing.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.5-r1.ebuild,v 1.15 2014/01/18 01:43:51 vapier Exp $
4
5 # Remember: we cannot leverage autotools in this ebuild in order
6 # to avoid circular deps with autotools
7
8 EAPI="4"
9
10 inherit eutils multilib toolchain-funcs libtool multilib-minimal
11
12 if [[ ${PV} == "9999" ]] ; then
13 EGIT_REPO_URI="http://git.tukaani.org/xz.git"
14 inherit git-2 autotools
15 SRC_URI=""
16 EXTRA_DEPEND="sys-devel/gettext dev-vcs/cvs >=sys-devel/libtool-2" #272880 286068
17 else
18 MY_P="${PN/-utils}-${PV/_}"
19 SRC_URI="http://tukaani.org/xz/${MY_P}.tar.gz"
20 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
21 S=${WORKDIR}/${MY_P}
22 EXTRA_DEPEND=
23 fi
24
25 DESCRIPTION="utils for managing LZMA compressed files"
26 HOMEPAGE="http://tukaani.org/xz/"
27
28 # See top-level COPYING file as it outlines the various pieces and their licenses.
29 LICENSE="public-domain LGPL-2.1+ GPL-2+"
30 SLOT="0"
31 IUSE="nls static-libs +threads"
32
33 RDEPEND="!<app-arch/lzma-4.63
34 !app-arch/lzma-utils
35 !<app-arch/p7zip-4.57"
36 DEPEND="${RDEPEND}
37 ${EXTRA_DEPEND}"
38
39 src_prepare() {
40 if [[ ${PV} == "9999" ]] ; then
41 eautopoint
42 eautoreconf
43 else
44 elibtoolize # to allow building shared libs on Solaris/x64
45 fi
46 }
47
48 multilib_src_configure() {
49 ECONF_SOURCE="${S}" econf \
50 $(use_enable nls) \
51 $(use_enable threads) \
52 $(use_enable static-libs static) \
53 $(multilib_is_native_abi || echo --disable-{xz,xzdec,lzmadec,lzmainfo,lzma-links,scripts})
54 }
55
56 multilib_src_install() {
57 default
58 multilib_is_native_abi && gen_usr_ldscript -a lzma
59 }
60
61 multilib_src_install_all() {
62 prune_libtool_files --all
63 rm "${ED}"/usr/share/doc/xz/COPYING* || die
64 mv "${ED}"/usr/share/doc/{xz,${PF}} || die
65 }
66
67 pkg_preinst() {
68 preserve_old_lib /usr/$(get_libdir)/liblzma$(get_libname 0)
69 }
70
71 pkg_postinst() {
72 preserve_old_lib_notify /usr/$(get_libdir)/liblzma$(get_libname 0)
73 }

  ViewVC Help
Powered by ViewVC 1.1.20