/[gentoo-x86]/app-text/apvlv/apvlv-0.1.4.ebuild
Gentoo

Contents of /app-text/apvlv/apvlv-0.1.4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Sun Mar 17 13:19:04 2013 UTC (5 years, 2 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +2 -2 lines
amd64/x86 stable

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-text/apvlv/apvlv-0.1.4.ebuild,v 1.3 2013/03/17 13:16:30 ssuominen Exp $
4
5 EAPI=5
6
7 inherit eutils cmake-utils
8
9 MY_P="${P}-Source"
10 DESCRIPTION="Alf's PDF Viewer Like Vim"
11 HOMEPAGE="http://naihe2010.github.com/apvlv/"
12 SRC_URI="mirror://github/naihe2010/${PN}/${MY_P}.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="amd64 x86"
17 IUSE="debug djvu"
18
19 RDEPEND="
20 >=app-text/poppler-0.18:=[cairo,xpdf-headers(+)]
21 >=x11-libs/gtk+-2.10.4:2
22 djvu? ( app-text/djvu:= )
23 "
24 DEPEND="${RDEPEND}
25 virtual/pkgconfig
26 "
27
28 S=${WORKDIR}/${MY_P}
29
30 src_prepare() {
31 # Webkit automagic, preserve cflags
32 epatch "${FILESDIR}/${PN}-0.1.4-cmake.patch"
33
34 # Remove prefixes so it works with the cmake-utils eclass
35 sed -i -e "s:APVLV_::" CMakeLists.txt src/CMakeLists.txt || die
36
37 # Don't install tex file
38 sed -i -e "s:Startup.tex::" CMakeLists.txt || die
39 }
40
41 src_configure() {
42 local mycmakeargs=(
43 -DSYSCONFDIR=/etc/${PN}
44 -DDOCDIR=/usr/share/${PN}
45 -DMANDIR=/usr/share/man
46 -DWITH_HTML=OFF
47 -DWITH_UMD=OFF
48 -DWITH_TXT=ON
49 $(cmake-utils_use_with djvu)
50 )
51 cmake-utils_src_configure
52 }
53
54 src_install() {
55 cmake-utils_src_install
56 dodoc AUTHORS NEWS README THANKS TODO
57 newicon icons/pdf.png ${PN}.png
58 make_desktop_entry ${PN} "Alf's PDF Viewer Like Vim" ${PN} "Office;Viewer"
59 }

  ViewVC Help
Powered by ViewVC 1.1.20