/[gentoo-x86]/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild
Gentoo

Contents of /app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.17 - (show annotations) (download)
Wed Apr 8 07:30:35 2015 UTC (3 years, 6 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.16: +2 -2 lines
Remove old Python implementations

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/app-text/gnome-doc-utils/gnome-doc-utils-0.20.10-r1.ebuild,v 1.16 2015/03/03 05:54:52 dlan Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7 PYTHON_COMPAT=( python2_7 )
8
9 inherit gnome2 multibuild python-r1
10
11 DESCRIPTION="A collection of documentation utilities for the Gnome project"
12 HOMEPAGE="http://live.gnome.org/GnomeDocUtils"
13
14 LICENSE="GPL-2 LGPL-2.1"
15 SLOT="0"
16 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
17
18 IUSE=""
19 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
20
21 RDEPEND="
22 ${PYTHON_DEPS}
23 >=dev-libs/libxml2-2.6.12[python,${PYTHON_USEDEP}]
24 >=dev-libs/libxslt-1.1.8
25 "
26 DEPEND="${RDEPEND}
27 app-text/docbook-xml-dtd:4.4
28 app-text/scrollkeeper-dtd
29 >=dev-util/intltool-0.35
30 sys-devel/gettext
31 virtual/awk
32 virtual/pkgconfig
33 "
34 # dev-libs/glib needed for eautofoo, bug #255114.
35
36 # If there is a need to reintroduce eautomake or eautoreconf, make sure
37 # to AT_M4DIR="tools m4", bug #224609 (m4 removes glib build time dep)
38
39 src_prepare() {
40 # Stop build from relying on installed package
41 epatch "${FILESDIR}"/${P}-fix-out-of-tree-build.patch
42
43 gnome2_src_prepare
44
45 # Leave shebang alone
46 sed -e '/s+^#!.*python.*+#/d' \
47 -i xml2po/xml2po/Makefile.{am,in} || die
48
49 python_prepare() {
50 mkdir -p "${BUILD_DIR}"
51 }
52 python_foreach_impl python_prepare
53 }
54
55 src_configure() {
56 ECONF_SOURCE="${S}" python_foreach_impl run_in_build_dir gnome2_src_configure
57 }
58
59 src_compile() {
60 python_foreach_impl run_in_build_dir gnome2_src_compile
61 }
62
63 src_test() {
64 python_foreach_impl run_in_build_dir default
65 }
66
67 src_install() {
68 dodoc AUTHORS ChangeLog NEWS README
69 python_foreach_impl run_in_build_dir gnome2_src_install
70 python_replicate_script "${ED}"/usr/bin/xml2po
71 }

  ViewVC Help
Powered by ViewVC 1.1.20