/[gentoo-x86]/dev-python/fabric/fabric-1.10.0-r1.ebuild
Gentoo

Contents of /dev-python/fabric/fabric-1.10.0-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Mon Feb 16 14:01:36 2015 UTC (4 years, 11 months ago) by pacho
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
amd64/x86 stable, bug #530324

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.10.0-r1.ebuild,v 1.2 2015/02/07 06:20:19 idella4 Exp $
4
5 EAPI=5
6 PYTHON_COMPAT=( python2_7 )
7
8 inherit distutils-r1
9
10 MY_PN="Fabric"
11 MY_P="${MY_PN}-${PV}"
12
13 DESCRIPTION="A simple pythonic tool for remote execution and deployment"
14 HOMEPAGE="http://fabfile.org http://pypi.python.org/pypi/Fabric"
15 SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
16
17 LICENSE="GPL-2"
18 SLOT="0"
19 KEYWORDS="amd64 x86"
20 IUSE="doc test"
21
22 RDEPEND="
23 >=dev-python/paramiko-1.10[${PYTHON_USEDEP}]"
24 DEPEND="${RDEPEND}
25 dev-python/setuptools[${PYTHON_USEDEP}]
26 doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
27 >=dev-python/python-docs-2.7.6-r1:2.7
28 dev-python/alabaster[${PYTHON_USEDEP}] )
29 test? ( dev-python/nose[${PYTHON_USEDEP}]
30 <dev-python/fudge-1.0[${PYTHON_USEDEP}]
31 dev-python/jinja[${PYTHON_USEDEP}] )"
32
33 S="${WORKDIR}/${MY_P}"
34
35 python_prepare_all() {
36 # Re-set intersphinx_mapping for doc build
37 if use doc; then
38 local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
39 local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
40 local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
41 local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
42 sed -e "s|'http://docs.python.org/2.6', None|'${PYTHON_DOC}', '${PYTHON_DOC_INVENTORY}'|" \
43 -e "s| 'www'| #'www'|" \
44 -i sites/docs/conf.py || die
45 fi
46 distutils-r1_python_prepare_all
47 }
48
49 python_compile_all() {
50 if use doc; then
51 sphinx-build -b html -c sites/docs/ sites/docs/ sites/docs/html || die
52 fi
53 }
54
55 src_test() {
56 local DISTUTILS_NO_PARALLEL_BUILD=1
57 distutils-r1_src_test
58 }
59
60 python_test() {
61 nosetests tests || die "Tests failed under ${EPYTHON}"
62 }
63
64 python_install_all() {
65 use doc && local HTML_DOCS=( sites/docs/html/. )
66 distutils-r1_python_install_all
67 }

  ViewVC Help
Powered by ViewVC 1.1.20