/[gentoo-x86]/dev-python/subunit/subunit-0.0.19.ebuild
Gentoo

Contents of /dev-python/subunit/subunit-0.0.19.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Apr 8 08:04:59 2015 UTC (5 years, 3 months ago) by mgorny
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
Drop old Python implementations

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/subunit-0.0.19.ebuild,v 1.2 2015/01/04 15:41:15 dilfridge Exp $
4
5 EAPI=5
6
7 PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
8
9 inherit distutils-r1 eutils multilib-minimal
10
11 DESCRIPTION="A streaming protocol for test results"
12 HOMEPAGE="https://launchpad.net/subunit http://pypi.python.org/pypi/python-subunit"
13 SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
14
15 LICENSE="Apache-2.0 BSD"
16 SLOT="0"
17 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~x86-fbsd"
18 #need to keyword the following in =dev-python/extras-0.0.3 then readd the keywords here
19 #ia64 s390 sh sparc amd64-fbsd
20 IUSE="static-libs"
21
22 RDEPEND=">=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
23 dev-python/extras[${PYTHON_USEDEP}]"
24 # test? ( dev-python/testscenarios[${PYTHON_USEDEP}] )
25 #requires keywording first; Bug #506510
26 DEPEND="${RDEPEND}
27 dev-python/setuptools[${PYTHON_USEDEP}]
28 dev-lang/perl:=
29 >=dev-libs/check-0.9.11[${MULTILIB_USEDEP}]
30 >=dev-util/cppunit-1.13.2[${MULTILIB_USEDEP}]
31 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
32 #requires keywording first; Bug #506510
33 RESTRICT="test"
34
35 src_prepare() {
36 sed -i -e 's/os.chdir(os.path.dirname(__file__))//' setup.py || die
37 # needed for perl modules
38 multilib_copy_sources
39 distutils-r1_src_prepare
40 }
41
42 multilib_src_configure() {
43 ECONF_SOURCE=${S} \
44 econf \
45 --enable-shared \
46 $(use_enable static-libs static)
47 }
48
49 multilib_src_compile() {
50 default
51 multilib_is_native_abi && distutils-r1_src_compile
52 }
53
54 python_test() {
55 local -x PATH="${PWD}/shell/share:${PATH}"
56 local -x PYTHONPATH=python
57 "${PYTHON}" -m testtools.run all_tests.test_suite || die "Testing failed with ${EPYTHON}"
58 }
59
60 multilib_src_test() {
61 multilib_is_native_abi && distutils-r1_src_test
62 }
63
64 multilib_src_install() {
65 local targets=(
66 install-include_subunitHEADERS
67 install-pcdataDATA
68 install-exec-local
69 install-libLTLIBRARIES
70 )
71 emake DESTDIR="${D}" "${targets[@]}"
72
73 multilib_is_native_abi && distutils-r1_src_install
74 }
75
76 multilib_src_install_all() {
77 einstalldocs
78 prune_libtool_files
79 }

  ViewVC Help
Powered by ViewVC 1.1.20