/[gentoo-x86]/games-arcade/orthorobot/orthorobot-0.ebuild
Gentoo

Contents of /games-arcade/orthorobot/orthorobot-0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sat Sep 14 10:04:32 2013 UTC (6 years, 5 months ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
Stable for x86, wrt bug #482506

(Portage version: 2.2.2/cvs/Linux x86_64, RepoMan options: --include-arches="x86", signed Manifest commit with key 7194459F)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/games-arcade/orthorobot/orthorobot-0.ebuild,v 1.2 2013/08/31 09:45:29 ago Exp $
4
5 EAPI="5"
6
7 inherit eutils games
8
9 DESCRIPTION="Nice perspective based puzzle game, where you flatten the view to move across gaps"
10 HOMEPAGE="http://stabyourself.net/orthorobot/"
11 SRC_URI="http://stabyourself.net/dl.php?file=${PN}/${PN}-source.zip -> ${P}.zip"
12
13 LICENSE="CC-BY-NC-ND-3.0"
14 SLOT="0"
15 KEYWORDS="amd64 x86"
16
17 RDEPEND=">=games-engines/love-0.8.0"
18 DEPEND="${RDEPEND}
19 app-arch/unzip"
20
21 S="${WORKDIR}"
22
23 src_unpack() {
24 default
25 #it is only one .love file (but with crappy name), so we can use asterisk
26 mv *.love "${P}.zip" || die 'mv failed'
27 unpack "./${P}.zip"
28 rm "${P}.zip" || die 'rm failed'
29 }
30
31 src_prepare() {
32 # fix error on quit
33 sed -i -e 's/love.event.push("q")/love.event.push(fadegoal)/' menu.lua || die 'sed failed'
34
35 epatch_user
36 }
37
38 src_install() {
39 local dir="${GAMES_DATADIR}/love/${PN}"
40 insinto "${dir}"
41 doins -r .
42 games_make_wrapper "${PN}" "love ${dir}"
43 make_desktop_entry "${PN}"
44 prepgamesdirs
45 }
46
47 pkg_postinst() {
48 elog "${PN} savegames and configurations are stored in:"
49 elog "~/.local/share/love/${PN}/"
50 }

  ViewVC Help
Powered by ViewVC 1.1.20