/[gentoo-x86]/gnome-base/librsvg/librsvg-2.34.2.ebuild
Gentoo

Contents of /gnome-base/librsvg/librsvg-2.34.2.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Wed Nov 23 23:06:13 2011 UTC (6 years, 6 months ago) by tetromino
Branch: MAIN
Changes since 1.3: +4 -1 lines
Add patch to fix parallel make failure when USE=introspection; many thanks to Rafał Mużyło <galtgendo@o2.pl> for the solution (bug #391215). Should also fix bug #391213. Thanks to all for reporting.

(Portage version: 2.2.0_alpha77/cvs/Linux x86_64)

1 # Copyright 1999-2011 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/gnome-base/librsvg/librsvg-2.34.2.ebuild,v 1.3 2011/11/21 22:26:35 pacho Exp $
4
5 EAPI="4"
6 GNOME2_LA_PUNT="yes"
7 GCONF_DEBUG="no"
8
9 inherit gnome2 multilib eutils autotools
10
11 DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
12 HOMEPAGE="http://librsvg.sourceforge.net/"
13 SRC_URI="${SRC_URI} mirror://gentoo/introspection.m4.bz2"
14
15 LICENSE="LGPL-2"
16 SLOT="2"
17 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
18 IUSE="doc +gtk gtk3 +introspection tools"
19
20 RDEPEND=">=media-libs/fontconfig-1.0.1
21 >=media-libs/freetype-2
22 >=dev-libs/glib-2.24:2
23 >=x11-libs/cairo-1.2
24 >=x11-libs/pango-1.10
25 >=dev-libs/libxml2-2.4.7:2
26 >=dev-libs/libcroco-0.6.1
27 || ( x11-libs/gdk-pixbuf:2
28 x11-libs/gtk+:2 )
29 gtk? ( >=x11-libs/gtk+-2.16:2 )
30 gtk3? ( >=x11-libs/gtk+-2.90.0:3 )
31 introspection? ( >=dev-libs/gobject-introspection-0.10.8 )"
32 DEPEND="${RDEPEND}
33 >=dev-util/pkgconfig-0.12
34 doc? ( >=dev-util/gtk-doc-1.13 )
35
36 >=dev-util/gtk-doc-am-1.13"
37 # >=dev-util/gtk-doc-am-1.13 and gobject-introspection needed by eautoreconf
38
39 pkg_setup() {
40 # croco is forced on to respect SVG specification
41 G2CONF="${G2CONF}
42 --disable-static
43 $(use_enable tools)
44 $(use_enable gtk gtk-theme)
45 $(use_enable introspection)
46 --with-croco
47 --enable-pixbuf-loader"
48 use gtk && ! use gtk3 && G2CONF+=" --with-gtk=2.0"
49 use gtk && use gtk3 && G2CONF+=" --with-gtk=both"
50 ! use gtk && use gtk3 && G2CONF+=" --with-gtk=3.0 --enable-gtk-theme"
51
52 DOCS="AUTHORS ChangeLog README NEWS TODO"
53 }
54
55 src_prepare() {
56 # Fix automagic gtk+ dependency, bug #371290
57 epatch "${FILESDIR}/${PN}-2.34.0-automagic-gtk.patch"
58
59 # bug #391215, https://bugzilla.gnome.org/show_bug.cgi?id=664684
60 epatch "${FILESDIR}/${PN}-2.34.2-gir-filename.patch"
61
62 # introspection.m4 needed for eautoreconf
63 mv "${WORKDIR}/introspection.m4" "${S}"/ || die
64
65 AT_M4DIR="." eautoreconf
66
67 gnome2_src_prepare
68 }
69
70 pkg_postinst() {
71 # causes segfault if set, see bug 375615
72 unset __GL_NO_DSO_FINALIZER
73
74 tmp_file=$(mktemp --suffix=gdk_pixbuf_ebuild)
75 # be atomic!
76 gdk-pixbuf-query-loaders > "${tmp_file}"
77 if [ "${?}" = "0" ]; then
78 cat "${tmp_file}" > "${EROOT}usr/$(get_libdir)/gdk-pixbuf-2.0/2.10.0/loaders.cache"
79 else
80 ewarn "Cannot update loaders.cache, gdk-pixbuf-query-loaders failed to run"
81 fi
82 rm "${tmp_file}"
83 }
84
85 pkg_postrm() {
86 # causes segfault if set, see bug 375615
87 unset __GL_NO_DSO_FINALIZER
88
89 tmp_file=$(mktemp --suffix=gdk_pixbuf_ebuild)
90 # be atomic!
91 gdk-pixbuf-query-loaders > "${tmp_file}"
92 if [ "${?}" = "0" ]; then
93 cat "${tmp_file}" > "${EROOT}usr/$(get_libdir)/gdk-pixbuf-2.0/2.10.0/loaders.cache"
94 else
95 ewarn "Cannot update loaders.cache, gdk-pixbuf-query-loaders failed to run"
96 fi
97 rm "${tmp_file}"
98 }

  ViewVC Help
Powered by ViewVC 1.1.20