/[gentoo-x86]/kde-base/qtruby/qtruby-4.9.0.ebuild
Gentoo

Contents of /kde-base/qtruby/qtruby-4.9.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Fri Sep 21 09:32:44 2012 UTC (7 years, 10 months ago) by johu
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Remove KDE SC 4.9.0

(Portage version: 2.2.0_alpha130/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/kde-base/qtruby/qtruby-4.9.0.ebuild,v 1.1 2012/08/01 22:17:11 johu Exp $
4
5 EAPI=4
6
7 OPENGL_REQUIRED="always"
8 DECLARATIVE_REQUIRED="optional"
9 KDE_REQUIRED="never"
10 KDE_SCM="git"
11 USE_RUBY="ruby18"
12 # No ruby19 for three reasons:
13 # 1) it does not build (yet) - will likely be solved soon
14 # 2) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
15 # 3) the ebuild can only be installed for one ruby variant, otherwise the compiled
16 # files with identical path+name will overwrite each other - difficult :(
17
18 inherit kde4-base ruby-ng
19
20 DESCRIPTION="Qt Ruby bindings"
21 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
22 IUSE="debug phonon qscintilla qwt webkit"
23
24 DEPEND="
25 $(add_kdebase_dep smokeqt 'declarative?,opengl,phonon?,qscintilla?,qwt?,webkit?')
26 "
27
28 RDEPEND="${DEPEND}
29 "
30
31 # Split from kdebindings-ruby in 4.7
32 add_blocker kdebindings-ruby
33
34 pkg_setup() {
35 ruby-ng_pkg_setup
36 kde4-base_pkg_setup
37 }
38
39 src_unpack() {
40 local S="${WORKDIR}/${P}"
41 kde4-base_src_unpack
42
43 cd "${WORKDIR}"
44 mkdir all
45 mv ${P} all/ || die "Could not move sources"
46 }
47
48 all_ruby_prepare() {
49 kde4-base_src_prepare
50 }
51
52 each_ruby_configure() {
53 local CMAKE_USE_DIR=${S}
54 mycmakeargs=(
55 -DRUBY_LIBRARY=$(ruby_get_libruby)
56 -DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
57 -DRUBY_EXECUTABLE=${RUBY}
58 $(cmake-utils_use_disable declarative QtDeclarative)
59 $(cmake-utils_use_with phonon)
60 $(cmake-utils_use_with qscintilla QScintilla)
61 $(cmake-utils_use_with qwt Qwt5)
62 $(cmake-utils_use_disable webkit QtWebKit)
63 )
64 kde4-base_src_configure
65 }
66
67 each_ruby_compile() {
68 local CMAKE_USE_DIR=${S}
69 kde4-base_src_compile
70 }
71
72 each_ruby_install() {
73 local CMAKE_USE_DIR=${S}
74 kde4-base_src_install
75 }

  ViewVC Help
Powered by ViewVC 1.1.20