/[gentoo-x86]/media-gfx/pixie/pixie-2.2.6-r1.ebuild
Gentoo

Contents of /media-gfx/pixie/pixie-2.2.6-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations) (download)
Sat Mar 10 09:19:20 2012 UTC (8 years, 5 months ago) by ssuominen
Branch: MAIN
CVS Tags: HEAD
Changes since 1.9: +3 -2 lines
Fix building with sys-libs/zlib >= 1.2.5.2 wrt #406899 by Helmut Jarausch

(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-gfx/pixie/pixie-2.2.6-r1.ebuild,v 1.9 2012/02/29 02:21:04 jer Exp $
4
5 EAPI="2"
6
7 WANT_AUTOMAKE="1.10"
8
9 inherit eutils multilib autotools
10
11 MY_PN="Pixie"
12 S="${WORKDIR}/${MY_PN}"
13
14 DESCRIPTION="RenderMan like photorealistic renderer"
15 HOMEPAGE="http://pixie.sourceforge.net/"
16 SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-src-${PV}.tgz"
17
18 LICENSE="GPL-2"
19 IUSE="X static-libs"
20 SLOT="0"
21 KEYWORDS="amd64 ~ppc sparc x86"
22
23 RDEPEND="virtual/jpeg
24 media-libs/tiff
25 media-libs/libpng
26 x11-libs/fltk:1[opengl]
27 media-libs/openexr
28 virtual/opengl
29 sys-libs/zlib
30 X? (
31 x11-libs/libXext
32 x11-libs/libICE
33 x11-libs/libSM
34 x11-libs/libX11
35 x11-libs/libXau
36 x11-libs/libxcb
37 x11-libs/libXdmcp
38 x11-libs/libXi
39 x11-libs/libXmu
40 x11-libs/libXt
41 )"
42 DEPEND="${RDEPEND}
43 sys-devel/flex
44 sys-devel/bison"
45
46 src_prepare() {
47 epatch "${FILESDIR}"/${P}-zlib-1.2.5.2.patch
48 # FIX: missing @includedir@
49 # https://sf.net/tracker/?func=detail&aid=2923415&group_id=59462&atid=491094
50 epatch "${FILESDIR}"/${P}-autotools.patch
51 eautoreconf
52
53 # FIX: removing pre-compiled shaders
54 # shaders must be removed before of their compilation or make
55 # parallelism can break the regeneration process, with resulting
56 # missing shaders.
57 rm "${S}"/shaders/*.sdr
58 }
59
60 src_configure() {
61 # NOTE: the option program-transform-name is used to avoid binary name
62 # conflict with package: mail-client/nmh (see #295996)
63 econf \
64 $(use_with X x) \
65 $(use_enable static-libs static) \
66 --includedir=/usr/include/pixie \
67 --libdir=/usr/$(get_libdir)/pixie \
68 --with-docdir=/usr/share/doc/${PF}/html \
69 --with-shaderdir=/usr/share/Pixie/shaders \
70 --with-ribdir=/usr/share/Pixie/ribs \
71 --with-texturedir=/usr/share/Pixie/textures \
72 --with-displaysdir=/usr/$(get_libdir)/pixie/displays \
73 --with-modulesdir=/usr/$(get_libdir)/pixie/modules \
74 --enable-openexr-threads \
75 --disable-static-fltk \
76 --mandir=/usr/share/man \
77 --bindir=/usr/bin \
78 --program-transform-name="s/show/pixie-show/"
79 }
80
81 src_compile() {
82 emake || die "emake failed"
83
84 # regenerating Pixie shaders - see upstream bug report:
85 # https://sf.net/tracker/?func=detail&aid=2923407&group_id=59462&atid=491094
86 einfo "Re-building Pixie Shaders for v${PV} format"
87 emake -f "${FILESDIR}/Makefile.shaders" -C "${S}/shaders" || die "shaders rebuild failed"
88 }
89
90 src_install() {
91 emake DESTDIR="${D}" install || die "installation failed."
92
93 insinto /usr/share/Pixie/textures
94 doins "${S}"/textures/*
95
96 # remove useless .la files
97 find "${D}" -name '*.la' -delete || die "removal of libtool archive files failed"
98
99 dodoc README AUTHORS ChangeLog || die
100 }

  ViewVC Help
Powered by ViewVC 1.1.20