/[gentoo-x86]/media-libs/mediastreamer/mediastreamer-2.2.3-r1.ebuild
Gentoo

Contents of /media-libs/mediastreamer/mediastreamer-2.2.3-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Sun Jul 19 17:55:17 2009 UTC (9 years ago) by volkmar
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +1 -1 lines
FILE REMOVED
removing old ebuilds and patches
(Portage version: 13823-svn/cvs/Linux ppc)

1 # Copyright 1999-2009 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-libs/mediastreamer/mediastreamer-2.2.3-r1.ebuild,v 1.3 2009/06/12 19:28:32 volkmar Exp $
4
5 EAPI="2"
6
7 inherit eutils autotools multilib
8
9 DESCRIPTION="Mediastreaming library for telephony application"
10 HOMEPAGE="http://www.linphone.org/index.php/eng/code_review/mediastreamer2"
11 SRC_URI="http://download.savannah.nongnu.org/releases/linphone/${PN}/${P}.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~amd64 ~ppc"
16 IUSE="+alsa arts debug doc examples gsm ilbc ipv6 jack oss portaudio +speex
17 theora video x264 X"
18
19 RDEPEND=">=net-libs/ortp-0.15.0
20 alsa? ( media-libs/alsa-lib )
21 arts? ( kde-base/arts )
22 gsm? ( media-sound/gsm )
23 jack? ( media-libs/libsamplerate
24 media-sound/jack-audio-connection-kit )
25 portaudio? ( media-libs/portaudio )
26 speex? ( >=media-libs/speex-1.1.12 )
27 video? ( media-libs/libsdl[video,X]
28 media-video/ffmpeg
29 theora? ( media-libs/libtheora )
30 X? ( x11-libs/libX11 ) )"
31 DEPEND="${RDEPEND}
32 dev-util/pkgconfig
33 doc? ( app-doc/doxygen )"
34
35 PDEPEND="ilbc? ( media-plugins/mediastreamer-ilbc )
36 video? ( x264? ( media-plugins/mediastreamer-x264 ) )"
37
38 # TODO:
39 # run-time test for arts support
40 # run-time test for ipv6 : does it need ortp[ipv6] ?
41
42 # NOTES:
43 # in some way, v4l support is auto-magic but keeping it like that atm
44
45 pkg_setup() {
46 if ! use oss && ! use alsa && ! use arts && ! use jack && ! use portaudio;
47 then
48 eerror "You must enable at least oss, alsa, arts, jack or portaudio"
49 eerror "Please, re-emerge ${PN} with one of this USE flag enabled"
50 die
51 fi
52
53 if ! use video && ( use theora || use X ); then
54 ewarn "X and theora support are enabled if video USE flag is enabled"
55 ewarn "If you want X or theora support, consider re-emerge with USE=\"video\""
56 fi
57 }
58
59 src_prepare() {
60 # fixing oss, jack, gsm, speex, theora and X auto-magic deps
61 epatch "${FILESDIR}"/${P}-autodeps.patch
62
63 # fix arts detection for gentoo
64 epatch "${FILESDIR}"/${P}-arts.patch
65
66 # too hard to have a flexible lib dir in a clean way
67 sed -i -e "s:\(/usr/kde/3.5/\)lib:\1$(get_libdir):" configure.ac \
68 || die "patching configure.ac failed"
69
70 # respect user's CFLAGS
71 sed -i -e "s:-O2::" configure.ac || die "patching configure.ac failed"
72
73 # change default paths
74 sed -i -e "s:\(\${prefix}/\)lib:\1$(get_libdir):" \
75 -e "s:\(prefix/share\):\1/${PN}:" configure.ac \
76 || die "patching configure.ac failed"
77
78 eautoreconf
79
80 # fix arts include
81 sed -i -e "s:kde/\(artsc/artsc.h\):\1:" src/arts.c \
82 || die "patching src/arts.c failed"
83
84 # don't build examples in tests/
85 sed -i -e "s:\(SUBDIRS = .*\) tests \(.*\):\1 \2:" Makefile.in \
86 || die "patching Makefile.in failed"
87 }
88
89 src_configure() {
90 # strict: don't want -Werror
91 # macsnd and macaqsnd: macosx related
92 # external-ortp: don't use bundled libs
93 econf \
94 --datadir=/usr/share/${PN} \
95 --libdir=/usr/$(get_libdir) \
96 --disable-strict \
97 --disable-macsnd \
98 --disable-macaqsnd \
99 --enable-external-ortp \
100 --disable-dependency-tracking \
101 $(use_enable alsa) \
102 $(use_enable arts artsc) \
103 $(use_enable debug) \
104 $(use_enable gsm) \
105 $(use_enable ipv6) \
106 $(use_enable jack) \
107 $(use_enable oss) \
108 $(use_enable portaudio) \
109 $(use_enable speex) \
110 $(use_enable theora) \
111 $(use_enable video) \
112 $(use_enable X x11)
113 }
114
115 src_compile() {
116 default_src_compile
117
118 if use doc; then
119 doxygen help/DoxyFile || die "building doc failed"
120 fi
121 }
122
123 src_install() {
124 emake DESTDIR="${D}" install || die "emake install failed"
125
126 dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"
127
128 if use doc; then
129 dohtml -r help/doc/html/* || die "dohtml failed"
130 newman help/doc/man/man3/${PN}2.3 ${PN}.3 || die "newman failed"
131 fi
132
133 if use examples; then
134 insinto /usr/share/doc/${PF}/examples
135 doins tests/*.c || die "doins failed"
136 fi
137 }

  ViewVC Help
Powered by ViewVC 1.1.20