/[gentoo-x86]/media-tv/tvheadend/tvheadend-3.4.27.ebuild
Gentoo

Contents of /media-tv/tvheadend/tvheadend-3.4.27.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Sun Jul 6 00:58:47 2014 UTC (6 years ago) by twitch153
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
Removes curl configure switch, bug #514796

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key A8C8FBCF)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-tv/tvheadend/tvheadend-3.4.27.ebuild,v 1.2 2014/06/22 20:05:06 prometheanfire Exp $
4
5 EAPI=5
6
7 inherit eutils linux-info systemd toolchain-funcs user
8
9 MY_PV="3.4patch1"
10
11 DESCRIPTION="Tvheadend is a TV streaming server and digital video recorder"
12 HOMEPAGE="https://tvheadend.org/"
13 SRC_URI="https://github.com/${PN}/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
14
15 LICENSE="GPL-3"
16 SLOT="0"
17 KEYWORDS="~amd64 ~x86"
18
19 IUSE="avahi +dvb +dvbscan ffmpeg imagecache inotify xmltv zlib"
20
21 REQUIRED_USE="dvbscan? ( dvb )"
22
23 DEPEND="dev-libs/openssl
24 avahi? ( net-dns/avahi )
25 dvb? ( virtual/linuxtv-dvb-headers )
26 ffmpeg? ( virtual/ffmpeg )
27 imagecache? ( net-misc/curl )
28 zlib? ( sys-libs/zlib )
29 virtual/pkgconfig"
30
31 RDEPEND="${DEPEND}
32 dvbscan? ( media-tv/linuxtv-dvb-apps )
33 xmltv? ( media-tv/xmltv )"
34
35 S="${WORKDIR}/${PN}-${MY_PV}"
36
37 CONFIG_CHECK="~INOTIFY_USER"
38
39 DOCS=( README )
40
41 pkg_setup() {
42 enewuser tvheadend -1 -1 /dev/null video
43 }
44
45 src_prepare() {
46 # set the version number
47 echo "const char *tvheadend_version = \"${PV}\";" \
48 > src/version.c || die "setting version failed!"
49
50 # remove '-Werror' wrt bug #438424
51 sed -e 's:-Werror::' -i Makefile || die 'sed failed!'
52 }
53
54 src_configure() {
55 econf --prefix="${EPREFIX}"/usr \
56 --datadir="${EPREFIX}"/usr/share \
57 --mandir="${EPREFIX}"/usr/share/man/man1 \
58 $(use_enable avahi) \
59 --disable-dvbscan \
60 $(use_enable dvb linuxdvb) \
61 $(use_enable ffmpeg libav) \
62 $(use_enable imagecache) \
63 $(use_enable inotify) \
64 $(use_enable zlib)
65 }
66
67 src_compile() {
68 emake CC="$(tc-getCC)"
69 }
70
71 src_install() {
72 default
73
74 newinitd "${FILESDIR}/tvheadend.initd" tvheadend
75 newconfd "${FILESDIR}/tvheadend.confd" tvheadend
76
77 systemd_dounit "${FILESDIR}/tvheadend.service"
78
79 dodir /etc/tvheadend
80 fperms 0700 /etc/tvheadend
81 fowners tvheadend:video /etc/tvheadend
82 }
83
84 pkg_postinst() {
85 elog "The Tvheadend web interface can be reached at:"
86 elog "http://localhost:9981/"
87 elog
88 elog "Make sure that you change the default username"
89 elog "and password via the Configuration / Access control"
90 elog "tab in the web interface."
91 }

  ViewVC Help
Powered by ViewVC 1.1.20