media-video/vlc/vlc-9999.ebuild

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.208 2014/01/30 16:40:36 tomwij Exp $

EAPI="5"

SCM=""
if [ "${PV%9999}" != "${PV}" ] ; then
        SCM="git-r3"

        if [ "${PV%.9999}" != "${PV}" ] ; then
                EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
        else
                EGIT_REPO_URI="git://git.videolan.org/vlc.git"
        fi
fi

inherit eutils multilib autotools toolchain-funcs flag-o-matic virtualx ${SCM}

MY_PV="${PV/_/-}"
MY_PV="${MY_PV/-beta/-test}"
MY_P="${PN}-${MY_PV}"

DESCRIPTION="VLC media player - Video player and streamer"
HOMEPAGE="http://www.videolan.org/vlc/"
if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
        SRC_URI=""
elif [[ "${MY_P}" == "${P}" ]]; then
        SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
else
        SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
fi

LICENSE="LGPL-2.1 GPL-2"
SLOT="0/5-7" # vlc - vlccore

if [ "${PV%9999}" = "${PV}" ] ; then
        KEYWORDS="~amd64 ~arm ~ppc -sparc ~x86 ~amd64-fbsd ~x86-fbsd"
else
        KEYWORDS=""
fi

IUSE="a52 aalib alsa altivec atmo +audioqueue avahi +avcodec
        +avformat bidi bluray cdda cddb chromaprint dbus dc1394 debug
        directfb directx dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode faad fdk
        fluidsynth +ffmpeg flac fontconfig +gcrypt gles1 gles2 gme gnome gnutls
        growl httpd ieee1394 ios-vout jack jpeg kate kde libass libcaca libnotify
        libsamplerate libtiger linsys libtar lirc live lua +macosx
        +macosx-audio +macosx-dialog-provider +macosx-eyetv +macosx-quartztext
        +macosx-qtkit +macosx-vout matroska media-library mmx modplug mp3 mpeg
        mtp musepack ncurses neon ogg omxil opencv opengl optimisememory opus
        png +postproc projectm pulseaudio +qt4 qt5 rdp rtsp run-as-root samba
        schroedinger sdl sdl-image sftp shout sid skins speex sse svg +swscale
        taglib theora tremor truetype twolame udev upnp vaapi v4l vcdx vdpau
        vlm vnc vorbis vpx wma-fixed +X x264 +xcb xml xv zvbi"

RDEPEND="
                !<media-video/ffmpeg-1.2:0
                dev-libs/libgpg-error:0
                net-dns/libidn:0
                >=sys-libs/zlib-1.2.5.1-r2:0[minizip]
                virtual/libintl:0
                a52? ( >=media-libs/a52dec-0.7.4-r3:0 )
                aalib? ( media-libs/aalib:0 )
                alsa? ( >=media-libs/alsa-lib-1.0.24:0 )
                avahi? ( >=net-dns/avahi-0.6:0[dbus] )
                avcodec? ( virtual/ffmpeg:0 )
                avformat? ( virtual/ffmpeg:0 )
                bidi? ( >=dev-libs/fribidi-0.10.4:0 )
                bluray? ( >=media-libs/libbluray-0.3.0:0 )
                cddb? ( >=media-libs/libcddb-1.2.0:0 )
                chromaprint? ( >=media-libs/chromaprint-0.6:0 )
                dbus? ( >=sys-apps/dbus-1.0.2:0 )
                dc1394? ( >=sys-libs/libraw1394-2.0.1:0 >=media-libs/libdc1394-2.1.0:2 )
                directfb? ( dev-libs/DirectFB:0 sys-libs/zlib:0 )
                dts? ( media-libs/libdca:0 )
                dvbpsi? ( >=media-libs/libdvbpsi-0.2.1:0 )
                dvd? ( media-libs/libdvdread:0 >=media-libs/libdvdnav-0.1.9:0 )
                egl? ( virtual/opengl:0 )
                elibc_glibc? ( >=sys-libs/glibc-2.8:2.2 )
                faad? ( >=media-libs/faad2-2.6.1:0 )
                fdk? ( media-libs/fdk-aac:0 )
                flac? ( media-libs/libogg:0 >=media-libs/flac-1.1.2:0 )
                fluidsynth? ( >=media-sound/fluidsynth-1.1.2:0 )
                fontconfig? ( media-libs/fontconfig:1.0 )
                gcrypt? ( >=dev-libs/libgcrypt-1.2.0:0 )
                gles1? ( virtual/opengles:0 )
                gles2? ( virtual/opengles:0 )
                gme? ( media-libs/game-music-emu:0 )
                gnome? ( gnome-base/gnome-vfs:2 dev-libs/glib:2 )
                gnutls? ( >=net-libs/gnutls-3.0.20:0 )
                ieee1394? ( >=sys-libs/libraw1394-2.0.1:0 >=sys-libs/libavc1394-0.5.3:0 )
                ios-vout? ( virtual/opengl:0 )
                jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1:0 )
                jpeg? ( virtual/jpeg:0 )
                kate? ( >=media-libs/libkate-0.3.0:0 )
                libass? ( >=media-libs/libass-0.9.8:0 media-libs/fontconfig:1.0 )
                libcaca? ( >=media-libs/libcaca-0.99_beta14:0 )
                libnotify? ( x11-libs/libnotify:0 x11-libs/gtk+:2 x11-libs/gdk-pixbuf:2 dev-libs/glib:2 )
                libsamplerate? ( media-libs/libsamplerate:0 )
                libtar? ( >=dev-libs/libtar-1.2.11-r3:0 )
                libtiger? ( >=media-libs/libtiger-0.3.1:0 )
                linsys? ( >=media-libs/zvbi-0.2.28:0 )
                lirc? ( app-misc/lirc:0 )
                live? ( >=media-plugins/live-2011.12.23:0 )
                lua? ( >=dev-lang/lua-5.1:0 )
                macosx-vout? ( virtual/opengl:0 )
                matroska? (     >=dev-libs/libebml-1.0.0:0= >=media-libs/libmatroska-1.0.0:0= )
                modplug? ( >=media-libs/libmodplug-0.8.8.1:0 )
                mp3? ( media-libs/libmad:0 )
                mpeg? ( >=media-libs/libmpeg2-0.3.2:0 )
                mtp? ( >=media-libs/libmtp-1.0.0:0 )
                musepack? ( >=media-sound/musepack-tools-444:0 )
                ncurses? ( sys-libs/ncurses:5[unicode] )
                ogg? ( media-libs/libogg:0 )
                opencv? ( >media-libs/opencv-2.0:0 )
                opengl? ( virtual/opengl:0 >=x11-libs/libX11-1.3.99.901:0 )
                opus? ( >=media-libs/opus-1.0.3:0 )
                png? ( media-libs/libpng:0= sys-libs/zlib:0 )
                postproc? ( || ( >=media-video/ffmpeg-1.2:0= media-libs/libpostproc:0 ) )
                projectm? ( media-libs/libprojectm:0 media-fonts/dejavu:0 )
                pulseaudio? ( >=media-sound/pulseaudio-0.9.22:0 )
                qt4? ( >=dev-qt/qtgui-4.6.0:4 >=dev-qt/qtcore-4.6.0:4 )
                qt5? ( >=dev-qt/qtgui-5.1.0:5 >=dev-qt/qtcore-5.1.0:5 dev-qt/qtwidgets:5 )
                rdp? ( net-misc/freerdp:0= )
                samba? ( || ( >=net-fs/samba-3.4.6:0[smbclient] >=net-fs/samba-4.0.0:0[client] ) )
                schroedinger? ( >=media-libs/schroedinger-1.0.10:0 )
                sdl? ( >=media-libs/libsdl-1.2.10:0
                        sdl-image? ( >=media-libs/sdl-image-1.2.10:0 sys-libs/zlib:0 ) )
                sftp? ( net-libs/libssh2:0 )
                shout? ( media-libs/libshout:0 )
                sid? ( media-libs/libsidplay:2 )
                skins? ( x11-libs/libXext:0 x11-libs/libXpm:0 x11-libs/libXinerama:0 )
                speex? ( media-libs/speex:0 )
                svg? ( >=gnome-base/librsvg-2.9.0:2 )
                swscale? ( virtual/ffmpeg:0 )
                taglib? ( >=media-libs/taglib-1.6.1:0 sys-libs/zlib:0 )
                theora? ( >=media-libs/libtheora-1.0_beta3:0 )
                tremor? ( media-libs/tremor:0 )
                truetype? ( media-libs/freetype:2 virtual/ttf-fonts:0
                        !fontconfig? ( media-fonts/dejavu:0 ) )
                twolame? ( media-sound/twolame:0 )
                udev? ( >=virtual/udev-142:0 )
                upnp? ( net-libs/libupnp:0 )
                v4l? ( media-libs/libv4l:0 )
                vaapi? ( x11-libs/libva:0 virtual/ffmpeg[vaapi] )
                vcdx? ( >=dev-libs/libcdio-0.78.2:0 >=media-video/vcdimager-0.7.22:0 )
                vdpau? ( >=x11-libs/libvdpau-0.6:0 !<media-video/libav-9.11 )
                vnc? ( >=net-libs/libvncserver-0.9.9:0 )
                vorbis? ( media-libs/libvorbis:0 )
                vpx? ( media-libs/libvpx:0 )
                X? ( x11-libs/libX11:0 )
                x264? ( >=media-libs/x264-0.0.20090923:0= )
                xcb? ( >=x11-libs/libxcb-1.6:0 >=x11-libs/xcb-util-0.3.4:0 >=x11-libs/xcb-util-keysyms-0.3.4:0 )
                xml? ( dev-libs/libxml2:2 )
                zvbi? ( >=media-libs/zvbi-0.2.25:0 )
"

DEPEND="${RDEPEND}
        kde? ( >=kde-base/kdelibs-4:4 )
        xcb? ( x11-proto/xproto:0 )
        app-arch/xz-utils:0
        dev-lang/yasm:0
        >=sys-devel/gettext-0.18.3:0
        virtual/pkgconfig:0
"

REQUIRED_USE="
        aalib? ( X )
        bidi? ( truetype )
        cddb? ( cdda )
        dvb? ( dvbpsi )
        dxva2? ( avcodec )
        egl? ( X )
        ffmpeg? ( avcodec avformat swscale postproc )
        fontconfig? ( truetype )
        gnutls? ( gcrypt )
        httpd? ( lua )
        libcaca? ( X )
        libtar? ( skins )
        libtiger? ( kate )
        qt4? ( X !qt5 )
        qt5? ( X !qt4 )
        sdl? ( X )
        skins? ( truetype X ^^ ( qt4 qt5 ) )
        vaapi? ( avcodec X )
        vlm? ( encode )
        xv? ( xcb )
"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
        if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
                if [[ $(gcc-major-version) < 4 || ( $(gcc-major-version) == 4 && $(gcc-minor-version) < 5 ) ]] ; then
                        die "You need to have at least >=sys-devel/gcc-4.5 to build and/or have a working vlc, see bug #426754."
                fi
        fi
}

src_unpack() {
        if [ "${PV%9999}" != "${PV}" ] ; then
                git-r3_src_unpack
        else
                unpack ${A}
        fi
}

src_prepare() {
        # Support for Qt5.
        if use qt5 ; then
                export UIC="/usr/lib64/qt5/bin/uic"
                export MOC="/usr/lib64/qt5/bin/moc"
        fi

        # Remove unnecessary warnings about unimplemented pragmas on gcc for now.
        # Need to recheck this with gcc 4.9 and every subsequent minor bump of gcc.
        #
        # config.h:792: warning: ignoring #pragma STDC FENV_ACCESS [-Wunknown-pragmas]
        # config.h:793: warning: ignoring #pragma STDC FP_CONTRACT [-Wunknown-pragmas]
        #
        # http://gcc.gnu.org/c99status.html
        if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
                sed -i 's/ifndef __FAST_MATH__/if 0/g' configure.ac || die
        fi

        # _FORTIFY_SOURCE is set to 2 by default on Gentoo, remove redefine warnings.
        sed -i '/_FORTIFY_SOURCE.*, 2,/d' configure.ac || die

        # Bootstrap when we are on a git checkout.
        if [[ "${PV%9999}" != "${PV}" ]] ; then
                ./bootstrap
        fi

        # Make it build with libtool 1.5
        rm -f m4/lt* m4/libtool.m4 || die

        # We are not in a real git checkout due to the absence of a .git directory.
        touch src/revision.txt || die

        # Fix build system mistake.
        epatch "${FILESDIR}"/${PN}-2.1.0-fix-libtremor-libs.patch

        # Patch up incompatibilities and reconfigure autotools.
        epatch "${FILESDIR}"/${PN}-2.1.0-newer-rdp.patch
        epatch "${FILESDIR}"/${PN}-2.1.0-libva-1.2.1-compat.patch

        # Fix up broken audio when skipping using a fixed reversed bisected commit.
        epatch "${FILESDIR}"/${PN}-2.1.0-TomWij-bisected-PA-broken-underflow.patch

        # Disable avcodec checks when avcodec is not used.
        sed -i 's/^#if LIBAVCODEC_VERSION_CHECK(.*)$/#if 0/' modules/codec/avcodec/fourcc.c || die

        # Don't use --started-from-file when not using dbus.
        if ! use dbus ; then
                sed -i 's/ --started-from-file//' share/vlc.desktop.in || die
        fi

        eautoreconf

        # Disable automatic running of tests.
        find . -name 'Makefile.in' -exec sed -i 's/\(..*\)check-TESTS/\1/' {} \; || die
}

src_configure() {
        # Compatibility fix for Samba 4.
        use samba && append-cppflags "-I/usr/include/samba-4.0"

        # Needs libresid-builder from libsidplay:2 which is in another directory...
        # FIXME!
        append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"

        if use truetype || use projectm ; then
                local dejavu="/usr/share/fonts/dejavu/"
                myconf="--with-default-font=${dejavu}/DejaVuSans.ttf \
                                --with-default-font-family=Sans \
                                --with-default-monospace-font=${dejavu}/DejaVuSansMono.ttf
                                --with-default-monospace-font-family=Monospace"
        fi

        local qt_flag=""
        if use qt4 || use qt5 ; then
                qt_flag="--enable-qt"
        fi

        econf \
                ${myconf} \
                --enable-vlc \
                --docdir=/usr/share/doc/${PF} \
                --disable-dependency-tracking \
                --disable-optimizations \
                --disable-update-check \
                --enable-fast-install \
                --enable-screen \
                $(use_enable a52) \
                $(use_enable aalib aa) \
                $(use_enable alsa) \
                $(use_enable altivec) \
                $(use_enable atmo) \
                $(use_enable audioqueue) \
                $(use_enable avahi bonjour) \
                $(use_enable avcodec) \
                $(use_enable avformat) \
                $(use_enable bidi fribidi) \
                $(use_enable bluray) \
                $(use_enable cdda vcd) \
                $(use_enable cddb libcddb) \
                $(use_enable chromaprint) \
                $(use_enable dbus) \
                $(use_enable directfb) \
                $(use_enable directx) \
                $(use_enable dc1394) \
                $(use_enable debug) \
                $(use_enable dts dca) \
                $(use_enable dvbpsi) \
                $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
                $(use_enable dxva2) \
                $(use_enable egl) \
                $(use_enable encode sout) \
                $(use_enable faad) \
                $(use_enable fdk fdkaac) \
                $(use_enable flac) \
                $(use_enable fluidsynth) \
                $(use_enable fontconfig) \
                $(use_enable gcrypt libgcrypt) \
                $(use_enable gles1) \
                $(use_enable gles2) \
                $(use_enable gme) \
                $(use_enable gnome gnomevfs) \
                $(use_enable gnutls) \
                $(use_enable growl) \
                $(use_enable httpd) \
                $(use_enable ieee1394 dv1394) \
                $(use_enable ios-vout ios-vout2) \
                $(use_enable jack) \
                $(use_enable jpeg) \
                $(use_enable kate) \
                $(use_with kde kde-solid) \
                $(use_enable libass) \
                $(use_enable libcaca caca) \
                $(use_enable libnotify notify) \
                $(use_enable libsamplerate samplerate) \
                $(use_enable libtar) \
                $(use_enable libtiger tiger) \
                $(use_enable linsys) \
                $(use_enable lirc) \
                $(use_enable live live555) \
                $(use_enable lua) \
                $(use_enable macosx-audio) \
                $(use_enable macosx-dialog-provider) \
                $(use_enable macosx-eyetv) \
                $(use_enable macosx-qtkit) \
                $(use_enable macosx-quartztext) \
                $(use_enable macosx-vout) \
                $(use_enable matroska mkv) \
                $(use_enable mmx) \
                $(use_enable modplug mod) \
                $(use_enable mp3 mad) \
                $(use_enable mpeg libmpeg2) \
                $(use_enable mtp) \
                $(use_enable musepack mpc) \
                $(use_enable ncurses) \
                $(use_enable neon) \
                $(use_enable ogg) $(use_enable ogg mux_ogg) \
                $(use_enable omxil) \
                $(use_enable omxil omxil-vout) \
                $(use_enable opencv) \
                $(use_enable opengl glx) $(use_enable opengl glspectrum) \
                $(use_enable opus) \
                $(use_enable optimisememory optimize-memory) \
                $(use_enable png) \
                $(use_enable postproc) \
                $(use_enable projectm) \
                $(use_enable pulseaudio pulse) \
                ${qt_flag} \
                $(use_enable rdp freerdp) \
                $(use_enable rtsp realrtsp) \
                $(use_enable run-as-root) \
                $(use_enable samba smbclient) \
                $(use_enable schroedinger) \
                $(use_enable sdl) \
                $(use_enable sdl-image) \
                $(use_enable sid) \
                $(use_enable sftp) \
                $(use_enable shout) \
                $(use_enable skins skins2) \
                $(use_enable speex) \
                $(use_enable sse) \
                $(use_enable svg) \
                $(use_enable swscale) \
                $(use_enable taglib) \
                $(use_enable theora) \
                $(use_enable tremor) \
                $(use_enable truetype freetype) \
                $(use_enable twolame) \
                $(use_enable udev) \
                $(use_enable upnp) \
                $(use_enable v4l v4l2) \
                $(use_enable vaapi libva) \
                $(use_enable vcdx) \
                $(use_enable vdpau) \
                $(use_enable vlm) \
                $(use_enable vnc) \
                $(use_enable vorbis) \
                $(use_enable vpx) \
                $(use_enable wma-fixed) \
                $(use_with X x) \
                $(use_enable x264) \
                $(use_enable xcb) \
                $(use_enable xml libxml2) \
                $(use_enable xv xvideo) \
                $(use_enable zvbi) $(use_enable !zvbi telx) \
                --disable-asdcp \
                --disable-coregraphicslayer-vout \
                --disable-coverage \
                --disable-cprof \
                --disable-crystalhd \
                --disable-decklink \
                --disable-ios-audio \
                --disable-goom \
                --disable-kai \
                --disable-kva \
                --disable-maintainer-mode \
                --disable-merge-ffmpeg \
                --disable-mfx \
                --disable-opensles \
                --disable-oss \
                --disable-quicktime \
                --disable-rpi-omxil \
                --disable-shine \
                --disable-sndio \
                --disable-x265 \
                --disable-vda \
                --disable-vsxu \
                --disable-wasapi

                # ^ We don't have these disabled libraries in the Portage tree yet.
}

src_test() {
        Xemake check-TESTS
}

DOCS="AUTHORS THANKS NEWS README doc/fortunes.txt doc/intf-vcd.txt"

src_install() {
        default

        # Punt useless libtool's .la files
        find "${D}" -name '*.la' -delete
}

pkg_postinst() {
        if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
                einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
                "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
        else
                ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
                ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
                ewarn "If you do not do it, vlc will take a long time to load."
        fi
}
1	tomwij	1.208	# Copyright 1999-2014 Gentoo Foundation
2	aballier	1.1	# Distributed under the terms of the GNU General Public License v2
3	tomwij	1.209	# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.208 2014/01/30 16:40:36 tomwij Exp $
4	aballier	1.1
5	vincent	1.186	EAPI="5"
6	aballier	1.1
7			SCM=""
8			if [ "${PV%9999}" != "${PV}" ] ; then
9	tomwij	1.192	SCM="git-r3"
10
11	aballier	1.1	if [ "${PV%.9999}" != "${PV}" ] ; then
12	aballier	1.52	EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
13	aballier	1.1	else
14	aballier	1.52	EGIT_REPO_URI="git://git.videolan.org/vlc.git"
15	aballier	1.1	fi
16			fi
17
18	tomwij	1.193	inherit eutils multilib autotools toolchain-funcs flag-o-matic virtualx ${SCM}
19	aballier	1.1
20			MY_PV="${PV/_/-}"
21			MY_PV="${MY_PV/-beta/-test}"
22			MY_P="${PN}-${MY_PV}"
23
24			DESCRIPTION="VLC media player - Video player and streamer"
25			HOMEPAGE="http://www.videolan.org/vlc/"
26			if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
27			SRC_URI=""
28			elif [[ "${MY_P}" == "${P}" ]]; then
29	aballier	1.151	SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
30	aballier	1.1	else
31	aballier	1.151	SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
32	aballier	1.1	fi
33
34	aballier	1.161	LICENSE="LGPL-2.1 GPL-2"
35	tomwij	1.206	SLOT="0/5-7" # vlc - vlccore
36	aballier	1.1
37	aballier	1.89	if [ "${PV%9999}" = "${PV}" ] ; then
38	tomwij	1.206	KEYWORDS="~amd64 ~arm ~ppc -sparc ~x86 ~amd64-fbsd ~x86-fbsd"
39	aballier	1.89	else
40			KEYWORDS=""
41			fi
42	tomwij	1.193
43	tomwij	1.197	IUSE="a52 aalib alsa altivec atmo +audioqueue avahi +avcodec
44	tomwij	1.209	+avformat bidi bluray cdda cddb chromaprint dbus dc1394 debug
45	tomwij	1.197	directfb directx dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode faad fdk
46	tomwij	1.209	fluidsynth +ffmpeg flac fontconfig +gcrypt gles1 gles2 gme gnome gnutls
47			growl httpd ieee1394 ios-vout jack jpeg kate kde libass libcaca libnotify
48	scarabeus	1.185	libsamplerate libtiger linsys libtar lirc live lua +macosx
49	aballier	1.147	+macosx-audio +macosx-dialog-provider +macosx-eyetv +macosx-quartztext
50	aballier	1.154	+macosx-qtkit +macosx-vout matroska media-library mmx modplug mp3 mpeg
51	tomwij	1.193	mtp musepack ncurses neon ogg omxil opencv opengl optimisememory opus
52			png +postproc projectm pulseaudio +qt4 qt5 rdp rtsp run-as-root samba
53			schroedinger sdl sdl-image sftp shout sid skins speex sse svg +swscale
54			taglib theora tremor truetype twolame udev upnp vaapi v4l vcdx vdpau
55	tomwij	1.206	vlm vnc vorbis vpx wma-fixed +X x264 +xcb xml xv zvbi"
56	aballier	1.1
57			RDEPEND="
58	tomwij	1.201	!<media-video/ffmpeg-1.2:0
59	tomwij	1.193	dev-libs/libgpg-error:0
60			net-dns/libidn:0
61			>=sys-libs/zlib-1.2.5.1-r2:0[minizip]
62	tomwij	1.208	virtual/libintl:0
63	tomwij	1.193	a52? ( >=media-libs/a52dec-0.7.4-r3:0 )
64			aalib? ( media-libs/aalib:0 )
65	tomwij	1.202	alsa? ( >=media-libs/alsa-lib-1.0.24:0 )
66	tomwij	1.193	avahi? ( >=net-dns/avahi-0.6:0[dbus] )
67			avcodec? ( virtual/ffmpeg:0 )
68			avformat? ( virtual/ffmpeg:0 )
69			bidi? ( >=dev-libs/fribidi-0.10.4:0 )
70	tomwij	1.209	bluray? ( >=media-libs/libbluray-0.3.0:0 )
71	tomwij	1.193	cddb? ( >=media-libs/libcddb-1.2.0:0 )
72			chromaprint? ( >=media-libs/chromaprint-0.6:0 )
73			dbus? ( >=sys-apps/dbus-1.0.2:0 )
74	tomwij	1.202	dc1394? ( >=sys-libs/libraw1394-2.0.1:0 >=media-libs/libdc1394-2.1.0:2 )
75	tomwij	1.193	directfb? ( dev-libs/DirectFB:0 sys-libs/zlib:0 )
76			dts? ( media-libs/libdca:0 )
77			dvbpsi? ( >=media-libs/libdvbpsi-0.2.1:0 )
78			dvd? ( media-libs/libdvdread:0 >=media-libs/libdvdnav-0.1.9:0 )
79			egl? ( virtual/opengl:0 )
80			elibc_glibc? ( >=sys-libs/glibc-2.8:2.2 )
81	tomwij	1.197	faad? ( >=media-libs/faad2-2.6.1:0 )
82	tomwij	1.193	fdk? ( media-libs/fdk-aac:0 )
83			flac? ( media-libs/libogg:0 >=media-libs/flac-1.1.2:0 )
84	tomwij	1.202	fluidsynth? ( >=media-sound/fluidsynth-1.1.2:0 )
85	tomwij	1.193	fontconfig? ( media-libs/fontconfig:1.0 )
86			gcrypt? ( >=dev-libs/libgcrypt-1.2.0:0 )
87	tomwij	1.209	gles1? ( virtual/opengles:0 )
88			gles2? ( virtual/opengles:0 )
89	tomwij	1.193	gme? ( media-libs/game-music-emu:0 )
90			gnome? ( gnome-base/gnome-vfs:2 dev-libs/glib:2 )
91	tomwij	1.202	gnutls? ( >=net-libs/gnutls-3.0.20:0 )
92	tomwij	1.193	ieee1394? ( >=sys-libs/libraw1394-2.0.1:0 >=sys-libs/libavc1394-0.5.3:0 )
93			ios-vout? ( virtual/opengl:0 )
94			jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1:0 )
95	tomwij	1.209	jpeg? ( virtual/jpeg:0 )
96	tomwij	1.202	kate? ( >=media-libs/libkate-0.3.0:0 )
97	tomwij	1.193	libass? ( >=media-libs/libass-0.9.8:0 media-libs/fontconfig:1.0 )
98			libcaca? ( >=media-libs/libcaca-0.99_beta14:0 )
99			libnotify? ( x11-libs/libnotify:0 x11-libs/gtk+:2 x11-libs/gdk-pixbuf:2 dev-libs/glib:2 )
100			libsamplerate? ( media-libs/libsamplerate:0 )
101			libtar? ( >=dev-libs/libtar-1.2.11-r3:0 )
102	tomwij	1.202	libtiger? ( >=media-libs/libtiger-0.3.1:0 )
103	tomwij	1.193	linsys? ( >=media-libs/zvbi-0.2.28:0 )
104			lirc? ( app-misc/lirc:0 )
105			live? ( >=media-plugins/live-2011.12.23:0 )
106			lua? ( >=dev-lang/lua-5.1:0 )
107			macosx-vout? ( virtual/opengl:0 )
108			matroska? ( >=dev-libs/libebml-1.0.0:0= >=media-libs/libmatroska-1.0.0:0= )
109			modplug? ( >=media-libs/libmodplug-0.8.8.1:0 )
110			mp3? ( media-libs/libmad:0 )
111			mpeg? ( >=media-libs/libmpeg2-0.3.2:0 )
112			mtp? ( >=media-libs/libmtp-1.0.0:0 )
113			musepack? ( >=media-sound/musepack-tools-444:0 )
114			ncurses? ( sys-libs/ncurses:5[unicode] )
115			ogg? ( media-libs/libogg:0 )
116	tomwij	1.202	opencv? ( >media-libs/opencv-2.0:0 )
117	tomwij	1.193	opengl? ( virtual/opengl:0 >=x11-libs/libX11-1.3.99.901:0 )
118			opus? ( >=media-libs/opus-1.0.3:0 )
119			png? ( media-libs/libpng:0= sys-libs/zlib:0 )
120	tomwij	1.201	postproc? ( \|\| ( >=media-video/ffmpeg-1.2:0= media-libs/libpostproc:0 ) )
121	tomwij	1.193	projectm? ( media-libs/libprojectm:0 media-fonts/dejavu:0 )
122			pulseaudio? ( >=media-sound/pulseaudio-0.9.22:0 )
123	tomwij	1.202	qt4? ( >=dev-qt/qtgui-4.6.0:4 >=dev-qt/qtcore-4.6.0:4 )
124	tomwij	1.205	qt5? ( >=dev-qt/qtgui-5.1.0:5 >=dev-qt/qtcore-5.1.0:5 dev-qt/qtwidgets:5 )
125	tomwij	1.198	rdp? ( net-misc/freerdp:0= )
126	tomwij	1.196	samba? ( \|\| ( >=net-fs/samba-3.4.6:0[smbclient] >=net-fs/samba-4.0.0:0[client] ) )
127	tomwij	1.193	schroedinger? ( >=media-libs/schroedinger-1.0.10:0 )
128	tomwij	1.202	sdl? ( >=media-libs/libsdl-1.2.10:0
129			sdl-image? ( >=media-libs/sdl-image-1.2.10:0 sys-libs/zlib:0 ) )
130	tomwij	1.193	sftp? ( net-libs/libssh2:0 )
131			shout? ( media-libs/libshout:0 )
132	aballier	1.101	sid? ( media-libs/libsidplay:2 )
133	tomwij	1.193	skins? ( x11-libs/libXext:0 x11-libs/libXpm:0 x11-libs/libXinerama:0 )
134			speex? ( media-libs/speex:0 )
135			svg? ( >=gnome-base/librsvg-2.9.0:2 )
136			swscale? ( virtual/ffmpeg:0 )
137	tomwij	1.202	taglib? ( >=media-libs/taglib-1.6.1:0 sys-libs/zlib:0 )
138	tomwij	1.193	theora? ( >=media-libs/libtheora-1.0_beta3:0 )
139			tremor? ( media-libs/tremor:0 )
140			truetype? ( media-libs/freetype:2 virtual/ttf-fonts:0
141			!fontconfig? ( media-fonts/dejavu:0 ) )
142			twolame? ( media-sound/twolame:0 )
143	tomwij	1.202	udev? ( >=virtual/udev-142:0 )
144	tomwij	1.193	upnp? ( net-libs/libupnp:0 )
145			v4l? ( media-libs/libv4l:0 )
146	tomwij	1.204	vaapi? ( x11-libs/libva:0 virtual/ffmpeg[vaapi] )
147	tomwij	1.193	vcdx? ( >=dev-libs/libcdio-0.78.2:0 >=media-video/vcdimager-0.7.22:0 )
148	tomwij	1.203	vdpau? ( >=x11-libs/libvdpau-0.6:0 !<media-video/libav-9.11 )
149	tomwij	1.193	vnc? ( >=net-libs/libvncserver-0.9.9:0 )
150			vorbis? ( media-libs/libvorbis:0 )
151			vpx? ( media-libs/libvpx:0 )
152			X? ( x11-libs/libX11:0 )
153			x264? ( >=media-libs/x264-0.0.20090923:0= )
154	tomwij	1.202	xcb? ( >=x11-libs/libxcb-1.6:0 >=x11-libs/xcb-util-0.3.4:0 >=x11-libs/xcb-util-keysyms-0.3.4:0 )
155	tomwij	1.193	xml? ( dev-libs/libxml2:2 )
156			zvbi? ( >=media-libs/zvbi-0.2.25:0 )
157			"
158	aballier	1.1
159			DEPEND="${RDEPEND}
160	tomwij	1.193	kde? ( >=kde-base/kdelibs-4:4 )
161			xcb? ( x11-proto/xproto:0 )
162			app-arch/xz-utils:0
163	tomwij	1.209	dev-lang/yasm:0
164	tomwij	1.208	>=sys-devel/gettext-0.18.3:0
165	tomwij	1.193	virtual/pkgconfig:0
166			"
167	aballier	1.1
168	aballier	1.104	REQUIRED_USE="
169	aballier	1.127	aalib? ( X )
170	aballier	1.104	bidi? ( truetype )
171			cddb? ( cdda )
172	aballier	1.162	dvb? ( dvbpsi )
173	aballier	1.120	dxva2? ( avcodec )
174	aballier	1.126	egl? ( X )
175	aballier	1.177	ffmpeg? ( avcodec avformat swscale postproc )
176	aballier	1.104	fontconfig? ( truetype )
177			gnutls? ( gcrypt )
178	aballier	1.180	httpd? ( lua )
179	aballier	1.167	libcaca? ( X )
180	aballier	1.123	libtar? ( skins )
181	aballier	1.104	libtiger? ( kate )
182	tomwij	1.193	qt4? ( X !qt5 )
183			qt5? ( X !qt4 )
184	aballier	1.127	sdl? ( X )
185	tomwij	1.193	skins? ( truetype X ^^ ( qt4 qt5 ) )
186	aballier	1.127	vaapi? ( avcodec X )
187	aballier	1.106	vlm? ( encode )
188	aballier	1.104	xv? ( xcb )
189			"
190
191	aballier	1.1	S="${WORKDIR}/${MY_P}"
192
193	tomwij	1.195	pkg_setup() {
194			if [[ "$(tc-getCC)" == "gcc" ]] ; then
195			if [[ $(gcc-major-version) < 4 \|\| ( $(gcc-major-version) == 4 && $(gcc-minor-version) < 5 ) ]] ; then
196			die "You need to have at least >=sys-devel/gcc-4.5 to build and/or have a working vlc, see bug #426754."
197			fi
198			fi
199			}
200
201	aballier	1.1	src_unpack() {
202			if [ "${PV%9999}" != "${PV}" ] ; then
203	tomwij	1.192	git-r3_src_unpack
204			else
205			unpack ${A}
206	aballier	1.1	fi
207	aballier	1.22	}
208	aballier	1.1
209	aballier	1.22	src_prepare() {
210	tomwij	1.193	# Support for Qt5.
211			if use qt5 ; then
212			export UIC="/usr/lib64/qt5/bin/uic"
213			export MOC="/usr/lib64/qt5/bin/moc"
214			fi
215
216	tomwij	1.192	# Remove unnecessary warnings about unimplemented pragmas on gcc for now.
217			# Need to recheck this with gcc 4.9 and every subsequent minor bump of gcc.
218			#
219			# config.h:792: warning: ignoring #pragma STDC FENV_ACCESS [-Wunknown-pragmas]
220			# config.h:793: warning: ignoring #pragma STDC FP_CONTRACT [-Wunknown-pragmas]
221			#
222			# http://gcc.gnu.org/c99status.html
223			if [[ "$(tc-getCC)" == "gcc" ]] ; then
224			sed -i 's/ifndef __FAST_MATH__/if 0/g' configure.ac \|\| die
225			fi
226
227	tomwij	1.193	# _FORTIFY_SOURCE is set to 2 by default on Gentoo, remove redefine warnings.
228			sed -i '/_FORTIFY_SOURCE.*, 2,/d' configure.ac \|\| die
229
230	tomwij	1.192	# Bootstrap when we are on a git checkout.
231			if [[ "${PV%9999}" != "${PV}" ]] ; then
232			./bootstrap
233			fi
234
235	aballier	1.1	# Make it build with libtool 1.5
236	tomwij	1.192	rm -f m4/lt* m4/libtool.m4 \|\| die
237
238			# We are not in a real git checkout due to the absence of a .git directory.
239			touch src/revision.txt \|\| die
240
241	tomwij	1.198	# Fix build system mistake.
242	tomwij	1.194	epatch "${FILESDIR}"/${PN}-2.1.0-fix-libtremor-libs.patch
243
244	tomwij	1.193	# Patch up incompatibilities and reconfigure autotools.
245	tomwij	1.192	epatch "${FILESDIR}"/${PN}-2.1.0-newer-rdp.patch
246			epatch "${FILESDIR}"/${PN}-2.1.0-libva-1.2.1-compat.patch
247	aballier	1.1
248	tomwij	1.198	# Fix up broken audio when skipping using a fixed reversed bisected commit.
249			epatch "${FILESDIR}"/${PN}-2.1.0-TomWij-bisected-PA-broken-underflow.patch
250
251	tomwij	1.206	# Disable avcodec checks when avcodec is not used.
252			sed -i 's/^#if LIBAVCODEC_VERSION_CHECK(.*)$/#if 0/' modules/codec/avcodec/fourcc.c \|\| die
253
254	tomwij	1.207	# Don't use --started-from-file when not using dbus.
255			if ! use dbus ; then
256			sed -i 's/ --started-from-file//' share/vlc.desktop.in \|\| die
257			fi
258
259	aballier	1.47	eautoreconf
260	tomwij	1.193
261			# Disable automatic running of tests.
262			find . -name 'Makefile.in' -exec sed -i 's/\(..*\)check-TESTS/\1/' {} \; \|\| die
263	aballier	1.1	}
264
265	aballier	1.22	src_configure() {
266	tomwij	1.196	# Compatibility fix for Samba 4.
267			use samba && append-cppflags "-I/usr/include/samba-4.0"
268
269	tomwij	1.192	# Needs libresid-builder from libsidplay:2 which is in another directory...
270	aballier	1.101	# FIXME!
271	tomwij	1.193	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
272	aballier	1.101
273	tomwij	1.192	if use truetype \|\| use projectm ; then
274	lu_zero	1.184	local dejavu="/usr/share/fonts/dejavu/"
275			myconf="--with-default-font=${dejavu}/DejaVuSans.ttf \
276	ulm	1.188	--with-default-font-family=Sans \
277			--with-default-monospace-font=${dejavu}/DejaVuSansMono.ttf
278	lu_zero	1.184	--with-default-monospace-font-family=Monospace"
279			fi
280
281	tomwij	1.194	local qt_flag=""
282			if use qt4 \|\| use qt5 ; then
283			qt_flag="--enable-qt"
284			fi
285
286	aballier	1.1	econf \
287	lu_zero	1.184	${myconf} \
288	tomwij	1.194	--enable-vlc \
289	aballier	1.97	--docdir=/usr/share/doc/${PF} \
290	tomwij	1.193	--disable-dependency-tracking \
291			--disable-optimizations \
292			--disable-update-check \
293			--enable-fast-install \
294			--enable-screen \
295	aballier	1.1	$(use_enable a52) \
296			$(use_enable aalib aa) \
297			$(use_enable alsa) \
298			$(use_enable altivec) \
299			$(use_enable atmo) \
300	aballier	1.119	$(use_enable audioqueue) \
301	aballier	1.1	$(use_enable avahi bonjour) \
302	aballier	1.120	$(use_enable avcodec) \
303			$(use_enable avformat) \
304	aballier	1.1	$(use_enable bidi fribidi) \
305	aballier	1.111	$(use_enable bluray) \
306	aballier	1.1	$(use_enable cdda vcd) \
307			$(use_enable cddb libcddb) \
308	tomwij	1.192	$(use_enable chromaprint) \
309	lu_zero	1.184	$(use_enable dbus) \
310	aballier	1.1	$(use_enable directfb) \
311	aballier	1.117	$(use_enable directx) \
312	aballier	1.1	$(use_enable dc1394) \
313			$(use_enable debug) \
314			$(use_enable dts dca) \
315	aballier	1.162	$(use_enable dvbpsi) \
316	aballier	1.1	$(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
317	aballier	1.114	$(use_enable dxva2) \
318	aballier	1.116	$(use_enable egl) \
319	aballier	1.106	$(use_enable encode sout) \
320	tomwij	1.197	$(use_enable faad) \
321	tomwij	1.194	$(use_enable fdk fdkaac) \
322	aballier	1.1	$(use_enable flac) \
323			$(use_enable fluidsynth) \
324			$(use_enable fontconfig) \
325	aballier	1.147	$(use_enable gcrypt libgcrypt) \
326	tomwij	1.209	$(use_enable gles1) \
327			$(use_enable gles2) \
328	aballier	1.99	$(use_enable gme) \
329	aballier	1.1	$(use_enable gnome gnomevfs) \
330			$(use_enable gnutls) \
331	aballier	1.108	$(use_enable growl) \
332	aballier	1.1	$(use_enable httpd) \
333	aballier	1.168	$(use_enable ieee1394 dv1394) \
334	tomwij	1.209	$(use_enable ios-vout ios-vout2) \
335	aballier	1.1	$(use_enable jack) \
336	tomwij	1.209	$(use_enable jpeg) \
337	aballier	1.1	$(use_enable kate) \
338	aballier	1.68	$(use_with kde kde-solid) \
339	aballier	1.1	$(use_enable libass) \
340			$(use_enable libcaca caca) \
341			$(use_enable libnotify notify) \
342	aballier	1.147	$(use_enable libsamplerate samplerate) \
343	aballier	1.123	$(use_enable libtar) \
344	aballier	1.17	$(use_enable libtiger tiger) \
345	aballier	1.109	$(use_enable linsys) \
346	aballier	1.1	$(use_enable lirc) \
347			$(use_enable live live555) \
348			$(use_enable lua) \
349	aballier	1.119	$(use_enable macosx-audio) \
350			$(use_enable macosx-dialog-provider) \
351			$(use_enable macosx-eyetv) \
352	aballier	1.154	$(use_enable macosx-qtkit) \
353	aballier	1.119	$(use_enable macosx-quartztext) \
354			$(use_enable macosx-vout) \
355	aballier	1.1	$(use_enable matroska mkv) \
356			$(use_enable mmx) \
357			$(use_enable modplug mod) \
358			$(use_enable mp3 mad) \
359			$(use_enable mpeg libmpeg2) \
360			$(use_enable mtp) \
361			$(use_enable musepack mpc) \
362			$(use_enable ncurses) \
363	aballier	1.124	$(use_enable neon) \
364	aballier	1.179	$(use_enable ogg) $(use_enable ogg mux_ogg) \
365	aballier	1.113	$(use_enable omxil) \
366	tomwij	1.209	$(use_enable omxil omxil-vout) \
367	tomwij	1.192	$(use_enable opencv) \
368	tomwij	1.193	$(use_enable opengl glx) $(use_enable opengl glspectrum) \
369	tomwij	1.194	$(use_enable opus) \
370	aballier	1.1	$(use_enable optimisememory optimize-memory) \
371			$(use_enable png) \
372	aballier	1.120	$(use_enable postproc) \
373	aballier	1.21	$(use_enable projectm) \
374	aballier	1.1	$(use_enable pulseaudio pulse) \
375	tomwij	1.194	${qt_flag} \
376	tomwij	1.200	$(use_enable rdp freerdp) \
377	aballier	1.1	$(use_enable rtsp realrtsp) \
378			$(use_enable run-as-root) \
379	lu_zero	1.184	$(use_enable samba smbclient) \
380	aballier	1.1	$(use_enable schroedinger) \
381			$(use_enable sdl) \
382			$(use_enable sdl-image) \
383	aballier	1.101	$(use_enable sid) \
384	tomwij	1.193	$(use_enable sftp) \
385	aballier	1.1	$(use_enable shout) \
386			$(use_enable skins skins2) \
387			$(use_enable speex) \
388			$(use_enable sse) \
389			$(use_enable svg) \
390	aballier	1.120	$(use_enable swscale) \
391	aballier	1.1	$(use_enable taglib) \
392			$(use_enable theora) \
393	tomwij	1.193	$(use_enable tremor) \
394	aballier	1.1	$(use_enable truetype freetype) \
395			$(use_enable twolame) \
396	aballier	1.43	$(use_enable udev) \
397	aballier	1.1	$(use_enable upnp) \
398	aballier	1.158	$(use_enable v4l v4l2) \
399			$(use_enable vaapi libva) \
400	aballier	1.1	$(use_enable vcdx) \
401	tomwij	1.193	$(use_enable vdpau) \
402	aballier	1.69	$(use_enable vlm) \
403	tomwij	1.192	$(use_enable vnc) \
404	aballier	1.1	$(use_enable vorbis) \
405	tomwij	1.193	$(use_enable vpx) \
406	aballier	1.1	$(use_enable wma-fixed) \
407	aballier	1.74	$(use_with X x) \
408	aballier	1.1	$(use_enable x264) \
409	aballier	1.2	$(use_enable xcb) \
410	aballier	1.1	$(use_enable xml libxml2) \
411			$(use_enable xv xvideo) \
412	aballier	1.26	$(use_enable zvbi) $(use_enable !zvbi telx) \
413	tomwij	1.209	--disable-asdcp \
414			--disable-coregraphicslayer-vout \
415			--disable-coverage \
416			--disable-cprof \
417	tomwij	1.193	--disable-crystalhd \
418	tomwij	1.192	--disable-decklink \
419	tomwij	1.209	--disable-ios-audio \
420	tomwij	1.192	--disable-goom \
421	tomwij	1.193	--disable-kai \
422			--disable-kva \
423	tomwij	1.209	--disable-maintainer-mode \
424			--disable-merge-ffmpeg \
425	tomwij	1.192	--disable-mfx \
426	tomwij	1.209	--disable-opensles \
427	tomwij	1.193	--disable-oss \
428	tomwij	1.209	--disable-quicktime \
429			--disable-rpi-omxil \
430	tomwij	1.193	--disable-shine \
431			--disable-sndio \
432			--disable-x265 \
433			--disable-vda \
434	tomwij	1.209	--disable-vsxu \
435			--disable-wasapi
436	tomwij	1.192
437	tomwij	1.209	# ^ We don't have these disabled libraries in the Portage tree yet.
438	aballier	1.1	}
439
440	tomwij	1.193	src_test() {
441			Xemake check-TESTS
442			}
443
444			DOCS="AUTHORS THANKS NEWS README doc/fortunes.txt doc/intf-vcd.txt"
445
446	aballier	1.1	src_install() {
447	tomwij	1.193	default
448	aballier	1.1
449	aballier	1.86	# Punt useless libtool's .la files
450			find "${D}" -name '*.la' -delete
451	aballier	1.1	}
452	aballier	1.61
453			pkg_postinst() {
454			if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
455	aballier	1.67	einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
456	aballier	1.75	"/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
457	aballier	1.61	else
458			ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
459			ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
460			ewarn "If you do not do it, vlc will take a long time to load."
461			fi
462			}